t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 107;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Darwin  = $^O eq 'darwin';
  19 $Is_Dos     = $^O eq 'dos';
  20 $Is_MacOS   = $^O eq 'MacOS';
  21 $Is_MPE     = $^O eq 'mpeix';
  22 $Is_MSWin32 = $^O eq 'MSWin32';
  23 $Is_NetWare = $^O eq 'NetWare';
  24 $Is_OS2     = $^O eq 'os2';
  25 $Is_Solaris = $^O eq 'solaris';
  26 $Is_VMS     = $^O eq 'VMS';
  27 $Is_DGUX    = $^O eq 'dgux';
  28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  29 $Is_Rhapsody= $^O eq 'rhapsody';
  30
  31 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  32
  33 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  34
  35 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  36    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  37
  38 my $Curdir = File::Spec->curdir;
  39
  40
  41 my $tmpfile = 'Op_stat.tmp';
  42 my $tmpfile_link = $tmpfile.'2';
  43
  44 chmod 0666, $tmpfile;
  45 1 while unlink $tmpfile;
  46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  47 close FOO;
  48
  49 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  50
  51 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  52
  53 #VMS Fix-me: nlink should work on VMS if applicable link support configured.
  54 SKIP: {
  55     skip "No link count", 1 if $Is_VMS;
  56
  57     is($nlink, 1, 'nlink on regular file');
  58 }
  59
  60 SKIP: {
  61   skip "mtime and ctime not reliable", 2
  62     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS or $Is_Darwin;
  63
  64   ok( $mtime,           'mtime' );
  65   is( $mtime, $ctime,   'mtime == ctime' );
  66 }
  67
  68
  69 # Cygwin seems to have a 3 second granularity on its timestamps.
  70 my $funky_FAT_timestamps = $Is_Cygwin;
  71 sleep 3 if $funky_FAT_timestamps;
  72
  73 print FOO "Now is the time for all good men to come to.\n";
  74 close(FOO);
  75
  76 sleep 2;
  77
  78
  79 SKIP: {
  80     unlink $tmpfile_link;
  81     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  82     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  83
  84     is( $@, '',         'link() implemented' );
  85     ok( $lnk_result,    'linked tmp testfile' );
  86     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  87
  88     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  89
  90     SKIP: {
  91         skip "No link count", 1 if $Config{dont_use_nlink};
  92         skip "Cygwin9X fakes hard links by copying", 1
  93           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  94
  95         is($nlink, 2,     'Link count on hard linked file' );
  96     }
  97
  98     SKIP: {
  99         my $cwd = File::Spec->rel2abs($Curdir);
 100         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 101                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 102                                         $mtime && $mtime == $ctime;
 103         skip "AFS has different mtime/ctime link semantics", 2
 104                                      if $cwd =~ m#$Config{'afsroot'}/#;
 105         skip "AmigaOS has different mtime/ctime link semantics", 2
 106                                      if $Is_Amiga;
 107         # Win32 could pass $mtime test but as FAT and NTFS have
 108         # no ctime concept $ctime is ALWAYS == $mtime
 109         # expect netware to be the same ...
 110         skip "No ctime concept on this OS", 2
 111                                      if $Is_MSWin32 ||
 112                                         ($Is_Darwin && $Is_UFS);
 113
 114         if( !ok($mtime, 'hard link mtime') ||
 115             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 116             print STDERR <<DIAG;
 117 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 118 # has this problem.  Building on the ClearCase VOBS filesystem may also
 119 # cause this failure.
 120 #
 121 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 122 # this test.
 123 DIAG
 124         }
 125     }
 126
 127 }
 128
 129 # truncate and touch $tmpfile.
 130 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 131 ok(-z \*F,     '-z on empty filehandle');
 132 ok(! -s \*F,   '   and -s');
 133 close F;
 134
 135 ok(-z $tmpfile,     '-z on empty file');
 136 ok(! -s $tmpfile,   '   and -s');
 137
 138 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 139 print F "hi\n";
 140 close F;
 141
 142 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 143 ok(!-z *F,     '-z on empty filehandle');
 144 ok( -s *F,   '   and -s');
 145 close F;
 146
 147 ok(! -z $tmpfile,   '-z on non-empty file');
 148 ok(-s $tmpfile,     '   and -s');
 149
 150
 151 # Strip all access rights from the file.
 152 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 153
 154 SKIP: {
 155     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 156
 157     SKIP: {
 158         # Going to try to switch away from root.  Might not work.
 159         my $olduid = $>;
 160         eval { $> = 1; };
 161         skip "Can't test -r or -w meaningfully if you're superuser", 2
 162           if $> == 0;
 163
 164         SKIP: {
 165             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 166             ok(!-r $tmpfile,    "   -r");
 167         }
 168
 169         ok(!-w $tmpfile,    "   -w");
 170
 171         # switch uid back (may not be implemented)
 172         eval { $> = $olduid; };
 173     }
 174
 175     ok(! -x $tmpfile,   '   -x');
 176 }
 177
 178
 179
 180 ok(chmod(0700,$tmpfile),    'chmod 0700');
 181 ok(-r $tmpfile,     '   -r');
 182 ok(-w $tmpfile,     '   -w');
 183
 184 SKIP: {
 185     skip "-x simply determines if a file ends in an executable suffix", 1
 186       if $Is_Dosish || $Is_MacOS;
 187
 188     ok(-x $tmpfile,     '   -x');
 189 }
 190
 191 ok(  -f $tmpfile,   '   -f');
 192 ok(! -d $tmpfile,   '   !-d');
 193
 194 # Is this portable?
 195 ok(  -d $Curdir,          '-d cwd' );
 196 ok(! -f $Curdir,          '!-f cwd' );
 197
 198
 199 SKIP: {
 200     unlink($tmpfile_link);
 201     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 202     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 203
 204     is( $@, '',     'symlink() implemented' );
 205     ok( $symlink_rslt,      'symlink() ok' );
 206     ok(-l $tmpfile_link,    '-l');
 207 }
 208
 209 ok(-o $tmpfile,     '-o');
 210
 211 ok(-e $tmpfile,     '-e');
 212
 213 unlink($tmpfile_link);
 214 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 215
 216 SKIP: {
 217     skip "No character, socket or block special files", 6
 218       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 219     skip "/dev isn't available to test against", 6
 220       unless -d '/dev' && -r '/dev' && -x '/dev';
 221     skip "Skipping: unexpected ls output in MP-RAS", 6
 222       if $Is_MPRAS;
 223
 224     # VMS problem:  If GNV or other UNIX like tool is installed, then
 225     # sometimes Perl will find /bin/ls, and will try to run it.
 226     # But since Perl on VMS does not know to run it under Bash, it will
 227     # try to run the DCL verb LS.  And if the VMS product Language
 228     # Sensitive Editor is installed, or some other LS verb, that will
 229     # be run instead.  So do not do this until we can teach Perl
 230     # when to use BASH on VMS.
 231     skip "ls command not available to Perl in OpenVMS right now.", 6
 232       if $Is_VMS;
 233
 234     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 235     my $CMD = "$LS /dev 2>/dev/null";
 236     my $DEV = qx($CMD);
 237
 238     skip "$CMD failed", 6 if $DEV eq '';
 239
 240     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 241
 242     skip "opendir failed: $!", 6 if @DEV == 0;
 243
 244     # /dev/stdout might be either character special or a named pipe,
 245     # or a symlink, or a socket, depending on which OS and how are
 246     # you running the test, so let's censor that one away.
 247     # Similar remarks hold for stderr.
 248     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 249     @DEV =  grep { $_ ne 'stdout' } @DEV;
 250     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 251     @DEV =  grep { $_ ne 'stderr' } @DEV;
 252
 253     # /dev/printer is also naughty: in IRIX it shows up as
 254     # Srwx-----, not srwx------.
 255     $DEV =~ s{^.+?\sprinter$}{}m;
 256     @DEV =  grep { $_ ne 'printer' } @DEV;
 257
 258     # If running as root, we will see .files in the ls result,
 259     # and readdir() will see them always.  Potential for conflict,
 260     # so let's weed them out.
 261     $DEV =~ s{^.+?\s\..+?$}{}m;
 262     @DEV =  grep { ! m{^\..+$} } @DEV;
 263
 264     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 265     if ($^O eq 'irix') {
 266         $DEV =~ s{^S(.+?)}{s$1}mg;
 267     }
 268
 269     my $try = sub {
 270         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 271         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 272         my $c1 = scalar @c1;
 273         my $c2 = scalar @c2;
 274         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 275     };
 276
 277 SKIP: {
 278     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 279
 280     $try->('b', '-b');
 281     $try->('c', '-c');
 282     $try->('s', '-S');
 283
 284 }
 285
 286 ok(! -b $Curdir,    '!-b cwd');
 287 ok(! -c $Curdir,    '!-c cwd');
 288 ok(! -S $Curdir,    '!-S cwd');
 289
 290 }
 291
 292 SKIP: {
 293     my($cnt, $uid);
 294     $cnt = $uid = 0;
 295
 296     # Find a set of directories that's very likely to have setuid files
 297     # but not likely to be *all* setuid files.
 298     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 299     skip "Can't find a setuid file to test with", 3 unless @bin;
 300
 301     for my $bin (@bin) {
 302         opendir BIN, $bin or die "Can't opendir $bin: $!";
 303         while (defined($_ = readdir BIN)) {
 304             $_ = "$bin/$_";
 305             $cnt++;
 306             $uid++ if -u;
 307             last if $uid && $uid < $cnt;
 308         }
 309     }
 310     closedir BIN;
 311
 312     skip "No setuid programs", 3 if $uid == 0;
 313
 314     isnt($cnt, 0,    'found some programs');
 315     isnt($uid, 0,    '  found some setuid programs');
 316     ok($uid < $cnt,  "    they're not all setuid");
 317 }
 318
 319
 320 # To assist in automated testing when a controlling terminal (/dev/tty)
 321 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 322 # can be set to skip the tests that need a tty.
 323 SKIP: {
 324     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 325
 326     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
 327
 328     SKIP: {
 329         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 330         skip "No TTY to test -t with", 2 unless -e $TTY;
 331
 332         open(TTY, $TTY) ||
 333           warn "Can't open $TTY--run t/TEST outside of make.\n";
 334         ok(-t TTY,  '-t');
 335         ok(-c TTY,  'tty is -c');
 336         close(TTY);
 337     }
 338     ok(! -t TTY,    '!-t on closed TTY filehandle');
 339
 340     {
 341         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 342         ok(-t,          '-t on STDIN');
 343     }
 344 }
 345
 346 my $Null = File::Spec->devnull;
 347 SKIP: {
 348     skip "No null device to test with", 1 unless -e $Null;
 349     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 350
 351     open(NULL, $Null) or DIE("Can't open $Null: $!");
 352     ok(! -t NULL,   'null device is not a TTY');
 353     close(NULL);
 354 }
 355
 356
 357 # These aren't strictly "stat" calls, but so what?
 358 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
 359 ok(  -T $statfile,    '-T');
 360 ok(! -B $statfile,    '!-B');
 361
 362 SKIP: {
 363      skip("DG/UX", 1) if $Is_DGUX;
 364 ok(-B $Perl,      '-B');
 365 }
 366
 367 ok(! -T $Perl,    '!-T');
 368
 369 open(FOO,$statfile);
 370 SKIP: {
 371     eval { -T FOO; };
 372     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 373
 374     is( $@, '',     '-T on filehandle causes no errors' );
 375
 376     ok(-T FOO,      '   -T');
 377     ok(! -B FOO,    '   !-B');
 378
 379     $_ = <FOO>;
 380     like($_, qr/perl/, 'after readline');
 381     ok(-T FOO,      '   still -T');
 382     ok(! -B FOO,    '   still -B');
 383     close(FOO);
 384
 385     open(FOO,$statfile);
 386     $_ = <FOO>;
 387     like($_, qr/perl/,      'reopened and after readline');
 388     ok(-T FOO,      '   still -T');
 389     ok(! -B FOO,    '   still !-B');
 390
 391     ok(seek(FOO,0,0),   'after seek');
 392     ok(-T FOO,          '   still -T');
 393     ok(! -B FOO,        '   still !-B');
 394
 395     # It's documented this way in perlfunc *shrug*
 396     () = <FOO>;
 397     ok(eof FOO,         'at EOF');
 398     ok(-T FOO,          '   still -T');
 399     ok(-B FOO,          '   now -B');
 400 }
 401 close(FOO);
 402
 403
 404 SKIP: {
 405     skip "No null device to test with", 2 unless -e $Null;
 406
 407     ok(-T $Null,  'null device is -T');
 408     ok(-B $Null,  '    and -B');
 409 }
 410
 411
 412 # and now, a few parsing tests:
 413 $_ = $tmpfile;
 414 ok(-f,      'bare -f   uses $_');
 415 ok(-f(),    '     -f() "');
 416
 417 unlink $tmpfile or print "# unlink failed: $!\n";
 418
 419 # bug id 20011101.069
 420 my @r = \stat($Curdir);
 421 is(scalar @r, 13,   'stat returns full 13 elements');
 422
 423 stat $0;
 424 eval { lstat _ };
 425 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 426     'lstat _ croaks after stat' );
 427 eval { -l _ };
 428 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 429     '-l _ croaks after stat' );
 430
 431 lstat $0;
 432 eval { lstat _ };
 433 is( "$@", "", "lstat _ ok after lstat" );
 434 eval { -l _ };
 435 is( "$@", "", "-l _ ok after lstat" );
 436
 437 SKIP: {
 438     skip "No lstat", 2 unless $Config{d_lstat};
 439
 440     # bug id 20020124.004
 441     # If we have d_lstat, we should have symlink()
 442     my $linkname = 'dolzero';
 443     symlink $0, $linkname or die "# Can't symlink $0: $!";
 444     lstat $linkname;
 445     -T _;
 446     eval { lstat _ };
 447     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 448         'lstat croaks after -T _' );
 449     eval { -l _ };
 450     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 451         '-l _ croaks after -T _' );
 452     unlink $linkname or print "# unlink $linkname failed: $!\n";
 453 }
 454
 455 print "# Zzz...\n";
 456 sleep(3);
 457 my $f = 'tstamp.tmp';
 458 unlink $f;
 459 ok (open(S, "> $f"), 'can create tmp file');
 460 close S or die;
 461 my @a = stat $f;
 462 print "# time=$^T, stat=(@a)\n";
 463 my @b = (-M _, -A _, -C _);
 464 print "# -MAC=(@b)\n";
 465 ok( (-M _) < 0, 'negative -M works');
 466 ok( (-A _) < 0, 'negative -A works');
 467 ok( (-C _) < 0, 'negative -C works');
 468 ok(unlink($f), 'unlink tmp file');
 469
 470 {
 471     ok(open(F, ">", $tmpfile), 'can create temp file');
 472     close F;
 473     chmod 0077, $tmpfile;
 474     my @a = stat($tmpfile);
 475     my $s1 = -s _;
 476     -T _;
 477     my $s2 = -s _;
 478     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 479     unlink $tmpfile;
 480 }
 481
 482 SKIP: {
 483     skip "No dirfd()", 9 unless $Config{d_dirfd};
 484     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 485     ok(stat(DIR), "stat() on dirhandle works");
 486     ok(-d -r _ , "chained -x's on dirhandle");
 487     ok(-d DIR, "-d on a dirhandle works");
 488
 489     # And now for the ambigious bareword case
 490     ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 491         || diag "Can't open 'TEST':  $!";
 492     my $size = (stat(DIR))[7];
 493     ok(defined $size, "stat() on bareword works");
 494     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 495     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 496     ok(-f DIR);
 497     closedir DIR or die $!;
 498     close DIR or die $!;
 499 }
 500
 501 {
 502     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 503     ok(open(F, ">", $tmpfile), 'can create temp file');
 504     my @thwap = stat *F{IO};
 505     ok(@thwap, "stat(*F{IO}) works");
 506     ok( -f *F{IO} , "single file tests work with *F{IO}");
 507     close F;
 508     unlink $tmpfile;
 509
 510     #PVIO's hold dirhandle information, so let's test them too.
 511
 512     SKIP: {
 513         skip "No dirfd()", 9 unless $Config{d_dirfd};
 514         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 515         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 516         ok(-d _ , "The special file handle _ is set correctly");
 517         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 518
 519         # And now for the ambigious bareword case
 520         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 521             || diag "Can't open 'TEST':  $!";
 522         my $size = (stat(*DIR{IO}))[7];
 523         ok(defined $size, "stat() on *THINGY{IO} works");
 524         is($size, -s "TEST",
 525            "size returned by stat of *THINGY{IO} is for the file");
 526         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 527         ok(-f *DIR{IO});
 528         closedir DIR or die $!;
 529         close DIR or die $!;
 530     }
 531 }
 532
 533 END {
 534     chmod 0666, $tmpfile;
 535     1 while unlink $tmpfile;
 536 }