t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 78;
  13
  14 my $Perl = which_perl();
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Darwin  = $^O eq 'darwin';
  19 $Is_Dos     = $^O eq 'dos';
  20 $Is_MacOS   = $^O eq 'MacOS';
  21 $Is_MPE     = $^O eq 'mpeix';
  22 $Is_MSWin32 = $^O eq 'MSWin32';
  23 $Is_NetWare = $^O eq 'NetWare';
  24 $Is_OS2     = $^O eq 'os2';
  25 $Is_Solaris = $^O eq 'solaris';
  26 $Is_VMS     = $^O eq 'VMS';
  27 $Is_DGUX    = $^O eq 'dgux';
  28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  29
  30 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  31
  32 $Is_UFS     = $Is_Darwin && (() = `df -t ufs .`) == 2;
  33
  34 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  35    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  36
  37 my $Curdir = File::Spec->curdir;
  38
  39
  40 my $tmpfile = 'Op_stat.tmp';
  41 my $tmpfile_link = $tmpfile.'2';
  42
  43
  44 1 while unlink $tmpfile;
  45 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  46 close FOO;
  47
  48 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  49
  50 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  51 SKIP: {
  52     skip "No link count", 1 if $Is_VMS;
  53
  54     is($nlink, 1, 'nlink on regular file');
  55 }
  56
  57 SKIP: {
  58   skip "mtime and ctime not reliable", 2
  59     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS;
  60
  61   ok( $mtime,           'mtime' );
  62   is( $mtime, $ctime,   'mtime == ctime' );
  63 }
  64
  65
  66 # Cygwin seems to have a 3 second granularity on its timestamps.
  67 my $funky_FAT_timestamps = $Is_Cygwin;
  68 sleep 3 if $funky_FAT_timestamps;
  69
  70 print FOO "Now is the time for all good men to come to.\n";
  71 close(FOO);
  72
  73 sleep 2 unless $funky_FAT_timestamps;
  74
  75
  76 SKIP: {
  77     unlink $tmpfile_link;
  78     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  79     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  80
  81     is( $@, '',         'link() implemented' );
  82     ok( $lnk_result,    'linked tmp testfile' );
  83     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  84
  85     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  86
  87     SKIP: {
  88         skip "No link count", 1 if $Config{dont_use_nlink};
  89         skip "Cygwin9X fakes hard links by copying", 1
  90           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
  91
  92         is($nlink, 2,     'Link count on hard linked file' );
  93     }
  94
  95     SKIP: {
  96         my $cwd = File::Spec->rel2abs($Curdir);
  97         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  98                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  99                                         $mtime && $mtime == $ctime;
 100         skip "AFS has different mtime/ctime link semantics", 2
 101                                      if $cwd =~ m#$Config{'afsroot'}/#;
 102         skip "AmigaOS has different mtime/ctime link semantics", 2
 103                                      if $Is_Amiga;
 104         # Win32 could pass $mtime test but as FAT and NTFS have
 105         # no ctime concept $ctime is ALWAYS == $mtime
 106         # expect netware to be the same ...
 107         skip "No ctime concept on this OS", 2
 108                                      if $Is_MSWin32 ||
 109                                         ($Is_Darwin && $Is_UFS);
 110
 111         if( !ok($mtime, 'hard link mtime') ||
 112             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 113             print STDERR <<DIAG;
 114 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 115 # has this problem.  Also building on the ClearCase VOBS filesystem may
 116 # cause this failure.
 117 # Darwins UFS doesn't have a ctime concept, and thus is
 118 # expected to fail this test.
 119 DIAG
 120         }
 121     }
 122
 123 }
 124
 125 # truncate and touch $tmpfile.
 126 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 127 close F;
 128
 129 ok(-z $tmpfile,     '-z on empty file');
 130 ok(! -s $tmpfile,   '   and -s');
 131
 132 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 133 print F "hi\n";
 134 close F;
 135
 136 ok(! -z $tmpfile,   '-z on non-empty file');
 137 ok(-s $tmpfile,     '   and -s');
 138
 139
 140 # Strip all access rights from the file.
 141 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 142
 143 SKIP: {
 144     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 145
 146     SKIP: {
 147         # Going to try to switch away from root.  Might not work.
 148         my $olduid = $>;
 149         eval { $> = 1; };
 150         skip "Can't test -r or -w meaningfully if you're superuser", 2
 151           if $> == 0;
 152
 153         SKIP: {
 154             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 155             ok(!-r $tmpfile,    "   -r");
 156         }
 157
 158         ok(!-w $tmpfile,    "   -w");
 159
 160         # switch uid back (may not be implemented)
 161         eval { $> = $olduid; };
 162     }
 163
 164     ok(! -x $tmpfile,   '   -x');
 165 }
 166
 167
 168
 169
 170 # in ms windows, $tmpfile inherits owner uid from directory
 171 # not sure about os/2, but chown is harmless anyway
 172 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 173
 174 ok(chmod(0700,$tmpfile),    'chmod 0700');
 175 ok(-r $tmpfile,     '   -r');
 176 ok(-w $tmpfile,     '   -w');
 177
 178 SKIP: {
 179     skip "-x simply determins if a file ends in an executable suffix", 1
 180       if $Is_Dosish || $Is_MacOS;
 181
 182     ok(-x $tmpfile,     '   -x');
 183 }
 184
 185 ok(  -f $tmpfile,   '   -f');
 186 ok(! -d $tmpfile,   '   !-d');
 187
 188 # Is this portable?
 189 ok(  -d $Curdir,          '-d cwd' );
 190 ok(! -f $Curdir,          '!-f cwd' );
 191
 192
 193 SKIP: {
 194     unlink($tmpfile_link);
 195     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 196     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 197
 198     is( $@, '',     'symlink() implemented' );
 199     ok( $symlink_rslt,      'symlink() ok' );
 200     ok(-l $tmpfile_link,    '-l');
 201 }
 202
 203 ok(-o $tmpfile,     '-o');
 204
 205 ok(-e $tmpfile,     '-e');
 206
 207 unlink($tmpfile_link);
 208 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 209
 210 SKIP: {
 211     skip "No character, socket or block special files", 6
 212       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 213     skip "/dev isn't available to test against", 6
 214       unless -d '/dev' && -r '/dev' && -x '/dev';
 215     skip "Skipping; unexpected ls output in MP-RAS", 6
 216       if $Is_MPRAS;
 217
 218     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 219     my $CMD = "$LS /dev 2>/dev/null";
 220     my $DEV = qx($CMD);
 221
 222     skip "$CMD failed", 6 if $DEV eq '';
 223
 224     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 225
 226     skip "opendir failed: $!", 6 if @DEV == 0;
 227
 228     # /dev/stdout might be either character special or a named pipe,
 229     # or a symlink, or a socket, depending on which OS and how are
 230     # you running the test, so let's censor that one away.
 231     # Similar remarks hold for stderr.
 232     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 233     @DEV =  grep { $_ ne 'stdout' } @DEV;
 234     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 235     @DEV =  grep { $_ ne 'stderr' } @DEV;
 236
 237     # /dev/printer is also naughty: in IRIX it shows up as
 238     # Srwx-----, not srwx------.
 239     $DEV =~ s{^.+?\sprinter$}{}m;
 240     @DEV =  grep { $_ ne 'printer' } @DEV;
 241
 242     # If running as root, we will see .files in the ls result,
 243     # and readdir() will see them always.  Potential for conflict,
 244     # so let's weed them out.
 245     $DEV =~ s{^.+?\s\..+?$}{}m;
 246     @DEV =  grep { ! m{^\..+$} } @DEV;
 247
 248     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 249     if ($^O eq 'irix') {
 250         $DEV =~ s{^S(.+?)}{s$1}mg;
 251     }
 252
 253     my $try = sub {
 254         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 255         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 256         my $c1 = scalar @c1;
 257         my $c2 = scalar @c2;
 258         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 259     };
 260
 261 SKIP: {
 262     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 263
 264     $try->('b', '-b');
 265     $try->('c', '-c');
 266     $try->('s', '-S');
 267
 268 }
 269
 270 ok(! -b $Curdir,    '!-b cwd');
 271 ok(! -c $Curdir,    '!-c cwd');
 272 ok(! -S $Curdir,    '!-S cwd');
 273
 274 }
 275
 276 SKIP: {
 277     my($cnt, $uid);
 278     $cnt = $uid = 0;
 279
 280     # Find a set of directories that's very likely to have setuid files
 281     # but not likely to be *all* setuid files.
 282     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 283     skip "Can't find a setuid file to test with", 3 unless @bin;
 284
 285     for my $bin (@bin) {
 286         opendir BIN, $bin or die "Can't opendir $bin: $!";
 287         while (defined($_ = readdir BIN)) {
 288             $_ = "$bin/$_";
 289             $cnt++;
 290             $uid++ if -u;
 291             last if $uid && $uid < $cnt;
 292         }
 293     }
 294     closedir BIN;
 295
 296     skip "No setuid programs", 3 if $uid == 0;
 297
 298     isnt($cnt, 0,    'found some programs');
 299     isnt($uid, 0,    '  found some setuid programs');
 300     ok($uid < $cnt,  "    they're not all setuid");
 301 }
 302
 303
 304 # To assist in automated testing when a controlling terminal (/dev/tty)
 305 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 306 # can be set to skip the tests that need a tty.
 307 SKIP: {
 308     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 309
 310     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 311
 312     SKIP: {
 313         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 314         skip "No TTY to test -t with", 2 unless -e $TTY;
 315
 316         open(TTY, $TTY) ||
 317           warn "Can't open $TTY--run t/TEST outside of make.\n";
 318         ok(-t TTY,  '-t');
 319         ok(-c TTY,  'tty is -c');
 320         close(TTY);
 321     }
 322     ok(! -t TTY,    '!-t on closed TTY filehandle');
 323
 324     {
 325         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 326         ok(-t,          '-t on STDIN');
 327     }
 328 }
 329
 330 my $Null = File::Spec->devnull;
 331 SKIP: {
 332     skip "No null device to test with", 1 unless -e $Null;
 333     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 334
 335     open(NULL, $Null) or DIE("Can't open $Null: $!");
 336     ok(! -t NULL,   'null device is not a TTY');
 337     close(NULL);
 338 }
 339
 340
 341 # These aren't strictly "stat" calls, but so what?
 342 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
 343 ok(  -T $statfile,    '-T');
 344 ok(! -B $statfile,    '!-B');
 345
 346 SKIP: {
 347      skip("DG/UX", 1) if $Is_DGUX;
 348 ok(-B $Perl,      '-B');
 349 }
 350
 351 ok(! -T $Perl,    '!-T');
 352
 353 open(FOO,$statfile);
 354 SKIP: {
 355     eval { -T FOO; };
 356     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 357
 358     is( $@, '',     '-T on filehandle causes no errors' );
 359
 360     ok(-T FOO,      '   -T');
 361     ok(! -B FOO,    '   !-B');
 362
 363     $_ = <FOO>;
 364     like($_, qr/perl/, 'after readline');
 365     ok(-T FOO,      '   still -T');
 366     ok(! -B FOO,    '   still -B');
 367     close(FOO);
 368
 369     open(FOO,$statfile);
 370     $_ = <FOO>;
 371     like($_, qr/perl/,      'reopened and after readline');
 372     ok(-T FOO,      '   still -T');
 373     ok(! -B FOO,    '   still !-B');
 374
 375     ok(seek(FOO,0,0),   'after seek');
 376     ok(-T FOO,          '   still -T');
 377     ok(! -B FOO,        '   still !-B');
 378
 379     # It's documented this way in perlfunc *shrug*
 380     () = <FOO>;
 381     ok(eof FOO,         'at EOF');
 382     ok(-T FOO,          '   still -T');
 383     ok(-B FOO,          '   now -B');
 384 }
 385 close(FOO);
 386
 387
 388 SKIP: {
 389     skip "No null device to test with", 2 unless -e $Null;
 390
 391     ok(-T $Null,  'null device is -T');
 392     ok(-B $Null,  '    and -B');
 393 }
 394
 395
 396 # and now, a few parsing tests:
 397 $_ = $tmpfile;
 398 ok(-f,      'bare -f   uses $_');
 399 ok(-f(),    '     -f() "');
 400
 401 unlink $tmpfile or print "# unlink failed: $!\n";
 402
 403 # bug id 20011101.069
 404 my @r = \stat($Curdir);
 405 is(scalar @r, 13,   'stat returns full 13 elements');
 406
 407 SKIP: {
 408     skip "No lstat", 4 unless $Config{d_lstat};
 409
 410     stat $0;
 411     eval { lstat _ };
 412     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 413         'lstat _ croaks after stat' );
 414     eval { -l _ };
 415     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 416         '-l _ croaks after stat' );
 417
 418     # bug id 20020124.004
 419     # If we have d_lstat, we should have symlink()
 420     my $linkname = 'dolzero';
 421     symlink $0, $linkname or die "# Can't symlink $0: $!";
 422     lstat $linkname;
 423     -T _;
 424     eval { lstat _ };
 425     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 426         'lstat croaks after -T _' );
 427     eval { -l _ };
 428     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 429         '-l _ croaks after -T _' );
 430     unlink $linkname or print "# unlink $linkname failed: $!\n";
 431 }
 432
 433 print "# Zzz...\n";
 434 sleep(3);
 435 my $f = 'tstamp.tmp';
 436 unlink $f;
 437 ok (open(S, "> $f"), 'can create tmp file');
 438 close S or die;
 439 my @a = stat $f;
 440 print "# time=$^T, stat=(@a)\n";
 441 my @b = (-M _, -A _, -C _);
 442 print "# -MAC=(@b)\n";
 443 ok( (-M _) < 0, 'negative -M works');
 444 ok( (-A _) < 0, 'negative -A works');
 445 ok( (-C _) < 0, 'negative -C works');
 446 ok(unlink($f), 'unlink tmp file');
 447
 448 END {
 449     1 while unlink $tmpfile;
 450 }