t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 use Config;
  10 use File::Spec;
  11
  12 plan tests => 69;
  13
  14 my $Perl = which_perl;
  15
  16 $Is_Amiga   = $^O eq 'amigaos';
  17 $Is_Cygwin  = $^O eq 'cygwin';
  18 $Is_Dos     = $^O eq 'dos';
  19 $Is_MPE     = $^O eq 'mpeix';
  20 $Is_MSWin32 = $^O eq 'MSWin32';
  21 $Is_NetWare = $^O eq 'NetWare';
  22 $Is_OS2     = $^O eq 'os2';
  23 $Is_Solaris = $^O eq 'solaris';
  24 $Is_VMS     = $^O eq 'VMS';
  25
  26 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
  27
  28 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  29    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  30
  31 my $Curdir = File::Spec->curdir;
  32
  33
  34 my $tmpfile = 'Op_stat.tmp';
  35 my $tmpfile_link = $tmpfile.'2';
  36
  37
  38 unlink $tmpfile;
  39 open(FOO, ">$tmpfile") || BAILOUT("Can't open temp test file: $!");
  40 close FOO;
  41
  42 open(FOO, ">$tmpfile") || BAILOUT("Can't open temp test file: $!");
  43
  44 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  45 SKIP: {
  46     skip "No link count", 1 if $Is_VMS;
  47
  48     is($nlink, 1, 'nlink on regular file');
  49 }
  50
  51 SKIP: {
  52   skip "mtime and ctime not reliable", 2
  53     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos;
  54
  55   ok( $mtime,           'mtime' );
  56   is( $mtime, $ctime,   'mtime == ctime' );
  57 }
  58
  59
  60 # Cygwin seems to have a 3 second granularity on its timestamps.
  61 my $funky_FAT_timestamps = $Is_Cygwin;
  62 sleep 3 if $funky_FAT_timestamps;
  63
  64 print FOO "Now is the time for all good men to come to.\n";
  65 close(FOO);
  66
  67 sleep 2 unless $funky_FAT_timestamps;
  68
  69
  70 SKIP: {
  71     unlink $tmpfile_link;
  72     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  73     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
  74
  75     is( $@, '',         'link() implemented' );
  76     ok( $lnk_result,    'linked tmp testfile' );
  77     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
  78
  79     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
  80
  81     SKIP: {
  82         skip "No link count", 1 if $Config{dont_use_nlink};
  83         is($nlink, 2,     'Link count on hard linked file' );
  84     }
  85
  86     SKIP: {
  87         my $cwd = File::Spec->rel2abs($Curdir);
  88         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
  89                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
  90                                         $mtime && $mtime == $ctime;
  91         skip "AFS has different mtime/ctime link semantics", 2
  92                                      if $cwd =~ m#$Config{'afsroot'}/#;
  93         skip "AmigaOS has different mtime/ctime link semantics", 2
  94                                      if $Is_Amiga;
  95
  96         if( !ok($mtime, 'hard link mtime') ||
  97             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
  98             print <<DIAG;
  99 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 100 # has this problem.  Also building on the ClearCase VOBS filesystem may
 101 # cause this failure.
 102 DIAG
 103         }
 104     }
 105
 106 }
 107
 108 # truncate and touch $tmpfile.
 109 open(F, ">$tmpfile") || BAILOUT("Can't open temp test file: $!");
 110 close F;
 111
 112 ok(-z $tmpfile,     '-z on empty file');
 113 ok(! -s $tmpfile,   '   and -s');
 114
 115 open(F, ">$tmpfile") || BAILOUT("Can't open temp test file: $!");
 116 print F "hi\n";
 117 close F;
 118
 119 ok(! -z $tmpfile,   '-z on non-empty file');
 120 ok(-s $tmpfile,     '   and -s');
 121
 122
 123 # Strip all access rights from the file.
 124 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 125
 126 SKIP: {
 127     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 128
 129     SKIP: {
 130         # Going to try to switch away from root.  Might not work.
 131         my $olduid = $>;
 132         eval { $> = 1; };
 133         skip "Can't test -r or -w meaningfully if you're superuser", 2
 134           if $> == 0;
 135
 136         SKIP: {
 137             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
 138             ok(!-r $tmpfile,    "   -r");
 139         }
 140
 141         ok(!-w $tmpfile,    "   -w");
 142
 143         # switch uid back (may not be implemented)
 144         eval { $> = $olduid; };
 145     }
 146
 147     ok(! -x $tmpfile,   '   -x');
 148 }
 149
 150
 151
 152
 153 # in ms windows, $tmpfile inherits owner uid from directory
 154 # not sure about os/2, but chown is harmless anyway
 155 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
 156
 157 ok(chmod(0700,$tmpfile),    'chmod 0700');
 158 ok(-r $tmpfile,     '   -r');
 159 ok(-w $tmpfile,     '   -w');
 160
 161 SKIP: {
 162     skip "-x simply determins if a file ends in an executable suffix", 1
 163       if $Is_Dosish;
 164
 165     ok(-x $tmpfile,     '   -x');
 166 }
 167
 168 ok(  -f $tmpfile,   '   -f');
 169 ok(! -d $tmpfile,   '   !-d');
 170
 171 # Is this portable?
 172 ok(  -d $Curdir,          '-d cwd' );
 173 ok(! -f $Curdir,          '!-f cwd' );
 174
 175
 176 SKIP: {
 177     unlink($tmpfile_link);
 178     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 179     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 180
 181     is( $@, '',     'symlink() implemented' );
 182     ok( $symlink_rslt,      'symlink() ok' );
 183     ok(-l $tmpfile_link,    '-l');
 184 }
 185
 186 ok(-o $tmpfile,     '-o');
 187
 188 ok(-e $tmpfile,     '-e');
 189
 190 unlink($tmpfile_link);
 191 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 192
 193 SKIP: {
 194     skip "No character, socket or block special files", 3
 195       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 196     skip "/dev isn't available to test against", 3
 197       unless -d '/dev' && -r '/dev' && -x '/dev';
 198
 199     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 200     my $CMD = "$LS /dev";
 201     my $DEV = qx($CMD);
 202
 203     skip "$CMD failed", 3 if $DEV eq '';
 204
 205     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 206
 207     skip "opendir failed: $!", 3 if @DEV == 0;
 208
 209     my $try = sub {
 210         my @c1 = eval qq[\$DEV =~ /^$_[0]/mg];
 211         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 212         my $c1 = scalar @c1;
 213         my $c2 = scalar @c2;
 214         is($c1, $c2, "ls and $_[1] agree on /dev ($c1 $c2)");
 215     };
 216
 217     $try->('b', '-b');
 218     $try->('c', '-c');
 219     $try->('s', '-S');
 220 }
 221
 222 ok(! -b $Curdir,    '!-b cwd');
 223 ok(! -c $Curdir,    '!-c cwd');
 224 ok(! -S $Curdir,    '!-S cwd');
 225
 226 SKIP: {
 227     skip "No setuid", 3 if $Is_MPE or $Is_Amiga or $Is_Dosish or $Is_Cygwin;
 228
 229     my($cnt, $uid);
 230     $cnt = $uid = 0;
 231
 232     # Find a set of directories that's very likely to have setuid files
 233     # but not likely to be *all* setuid files.
 234     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 235     skip "Can't find a setuid file to test with", 3 unless @bin;
 236
 237     for my $bin (@bin) {
 238         opendir BIN, $bin or die "Can't opendir $bin: $!";
 239         while (defined($_ = readdir BIN)) {
 240             $_ = "$bin/$_";
 241             $cnt++;
 242             $uid++ if -u;
 243             last if $uid && $uid < $cnt;
 244         }
 245     }
 246     closedir BIN;
 247
 248     if( !isnt($cnt, 0,    'found some programs') ||
 249         !isnt($uid, 0,    'found some setuid programs') ||
 250         !ok($uid < $cnt,  "  they're not all setuid") )
 251     {
 252         print <<DIAG;
 253 # The above two tests assume that at least one of these directories
 254 # are readable, executable and contain at least one setuid file
 255 # (but aren't all setuid).
 256 #   @bin
 257 DIAG
 258     }
 259 }
 260
 261
 262 # To assist in automated testing when a controlling terminal (/dev/tty)
 263 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 264 # can be set to skip the tests that need a tty.
 265 SKIP: {
 266     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 267
 268     my $TTY = $^O eq 'rhapsody' ? "/dev/ttyp0" : "/dev/tty";
 269
 270     SKIP: {
 271         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 272         skip "No TTY to test -t with", 2 unless -e $TTY;
 273
 274         open(TTY, $TTY) ||
 275           warn "Can't open $TTY--run t/TEST outside of make.\n";
 276         ok(-t TTY,  '-t');
 277         ok(-c TTY,  'tty is -c');
 278         close(TTY);
 279     }
 280     ok(! -t TTY,    '!-t on closed TTY filehandle');
 281     ok(-t,          '-t on STDIN');
 282 }
 283
 284 my $Null = File::Spec->devnull;
 285 SKIP: {
 286     skip "No null device to test with", 1 unless -e $Null;
 287
 288     open(NULL, $Null) or BAIL_OUT("Can't open $Null: $!");
 289     ok(! -t NULL,   'null device is not a TTY');
 290     close(NULL);
 291 }
 292
 293
 294 # These aren't strictly "stat" calls, but so what?
 295
 296 ok(-T 'op/stat.t',      '-T');
 297 ok(! -B 'op/stat.t',    '!-B');
 298
 299 ok(-B $Perl,      '-B');
 300 ok(! -T $Perl,    '!-T');
 301
 302 open(FOO,'op/stat.t');
 303 SKIP: {
 304     eval { -T FOO; };
 305     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 306
 307     is( $@, '',     '-T on filehandle causes no errors' );
 308
 309     ok(-T FOO,      '   -T');
 310     ok(! -B FOO,    '   !-B');
 311
 312     $_ = <FOO>;
 313     ok(/perl/,      'after readline');
 314     ok(-T FOO,      '   still -T');
 315     ok(! -B FOO,    '   still -B');
 316     close(FOO);
 317
 318     open(FOO,'op/stat.t');
 319     $_ = <FOO>;
 320     ok(/perl/,      'reopened and after readline');
 321     ok(-T FOO,      '   still -T');
 322     ok(! -B FOO,    '   still !-B');
 323
 324     ok(seek(FOO,0,0),   'after seek');
 325     ok(-T FOO,          '   still -T');
 326     ok(! -B FOO,        '   still !-B');
 327
 328     # It's documented this way in perlfunc *shrug*
 329     () = <FOO>;
 330     ok(eof FOO,         'at EOF');
 331     ok(-T FOO,          '   still -T');
 332     ok(-B FOO,          '   now -B');
 333 }
 334 close(FOO);
 335
 336
 337 SKIP: {
 338     skip "No null device to test with", 2 unless -e $Null;
 339
 340     ok(-T $Null,  'null device is -T');
 341     ok(-B $Null,  '    and -B');
 342 }
 343
 344
 345 # and now, a few parsing tests:
 346 $_ = $tmpfile;
 347 ok(-f,      'bare -f   uses $_');
 348 ok(-f(),    '     -f() "');
 349
 350 unlink $tmpfile or print "# unlink failed: $!\n";
 351
 352 # bug id 20011101.069
 353 my @r = \stat(".");
 354 is(scalar @r, 13,   'stat returns full 13 elements');
 355