t/op/pack.t

   1 #!./perl -Tw
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6 }
   7
   8 use Config;
   9
  10 $Is_EBCDIC = (defined $Config{ebcdic} && $Config{ebcdic} eq 'define');
  11
  12 my $test = 1;
  13 sub ok {
  14     my($ok) = @_;
  15     print "not " unless $ok;
  16     print "ok $test\n";
  17     $test++;
  18     return $ok;
  19 }
  20
  21 print "1..161\n";
  22
  23 # Note: All test numbers in comments are off by 1 after the comment below..
  24
  25 $format = "c2 x5 C C x s d i l a6";
  26 # Need the expression in here to force ary[5] to be numeric.  This avoids
  27 # test2 failing because ary2 goes str->numeric->str and ary doesn't.
  28 @ary = (1,-100,127,128,32767,987.654321098 / 100.0,12345,123456,"abcdef");
  29 $foo = pack($format,@ary);
  30 @ary2 = unpack($format,$foo);
  31
  32 ok($#ary == $#ary2);
  33
  34 $out1=join(':',@ary);
  35 $out2=join(':',@ary2);
  36 # Using long double NVs may introduce greater accuracy than wanted.
  37 $out1 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
  38 $out2 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
  39 ok($out1 eq $out2);
  40
  41 ok($foo =~ /def/);
  42
  43 # How about counting bits?
  44
  45 ok( ($x = unpack("%32B*", "\001\002\004\010\020\040\100\200\377")) == 16 );
  46
  47 ok( ($x = unpack("%32b69", "\001\002\004\010\020\040\100\200\017")) == 12 );
  48
  49 ok( ($x = unpack("%32B69", "\001\002\004\010\020\040\100\200\017")) == 9 );
  50
  51 my $sum = 129; # ASCII
  52 $sum = 103 if $Is_EBCDIC;
  53
  54 ok( ($x = unpack("%32B*", "Now is the time for all good blurfl")) == $sum );
  55
  56 open(BIN, "./perl") || open(BIN, "./perl.exe") || open(BIN, $^X)
  57     || die "Can't open ../perl or ../perl.exe: $!\n";
  58 sysread BIN, $foo, 8192;
  59 close BIN;
  60
  61 $sum = unpack("%32b*", $foo);
  62 $longway = unpack("b*", $foo);
  63 ok( $sum == $longway =~ tr/1/1/ );
  64
  65 ok( ($x = unpack("I",pack("I", 0xFFFFFFFF))) == 0xFFFFFFFF );
  66
  67 # check 'w'
  68 my @x = (5,130,256,560,32000,3097152,268435455,1073741844, 2**33,
  69          '4503599627365785','23728385234614992549757750638446');
  70 my $x = pack('w*', @x);
  71 my $y = pack 'H*', '0581028200843081fa0081bd8440ffffff7f8480808014A08080800087ffffffffffdb19caefe8e1eeeea0c2e1e3e8ede1ee6e';
  72
  73 if ($x eq $y) {
  74   print "ok $test\n";
  75 } else {
  76   printf "not ok $test # %s\n", unpack 'H*', $x;
  77 }
  78 $test++;
  79
  80 @y = unpack('w*', $y);
  81 my $a;
  82 while ($a = pop @x) {
  83   my $b = pop @y;
  84   print $a eq $b ? "ok $test\n" : "not ok $test\n$a\n$b\n"; $test++;
  85 }
  86
  87 # XXX All test numbers in comments are off by 1 after this point.
  88
  89 @y = unpack('w2', $x);
  90
  91 print scalar(@y) == 2 ? "ok $test\n" : "not ok $test\n"; $test++;
  92 print $y[1] == 130 ? "ok $test\n" : "not ok $test # $y[1]\n"; $test++;
  93
  94 # test exeptions
  95 eval { $x = unpack 'w', pack 'C*', 0xff, 0xff};
  96 print $@ ne '' ? "ok $test\n" : "not ok $test\n"; $test++;
  97
  98 eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff};
  99 print $@ ne '' ? "ok $test\n" : "not ok $test\n"; $test++;
 100
 101 eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff};
 102 print $@ ne '' ? "ok $test\n" : "not ok $test\n"; $test++;
 103
 104 #
 105 # test the "p" template
 106
 107 # literals
 108 print((unpack("p",pack("p","foo")) eq "foo" ? "ok " : "not ok "),$test++,"\n");
 109
 110 # scalars
 111 print((unpack("p",pack("p",$test)) == $test ? "ok " : "not ok "),$test++,"\n");
 112
 113 # temps
 114 sub foo { my $a = "a"; return $a . $a++ . $a++ }
 115 {
 116   use warnings;
 117   my $last = $test;
 118   local $SIG{__WARN__} = sub {
 119         print "ok ",$test++,"\n" if $_[0] =~ /temporary val/
 120   };
 121   my $junk = pack("p", &foo);
 122   print "not ok ", $test++, "\n" if $last == $test;
 123 }
 124
 125 # undef should give null pointer
 126 print((pack("p", undef) =~ /^\0+/ ? "ok " : "not ok "),$test++,"\n");
 127
 128 # Check for optimizer bug (e.g.  Digital Unix GEM cc with -O4 on DU V4.0B gives
 129 #                                4294967295 instead of -1)
 130 #                                see #ifdef __osf__ in pp.c pp_unpack
 131 # Test 30:
 132 print( ((unpack("i",pack("i",-1))) == -1 ? "ok " : "not ok "),$test++,"\n");
 133
 134 # 31..36: test the pack lengths of s S i I l L
 135 print "not " unless length(pack("s", 0)) == 2;
 136 print "ok ", $test++, "\n";
 137
 138 print "not " unless length(pack("S", 0)) == 2;
 139 print "ok ", $test++, "\n";
 140
 141 print "not " unless length(pack("i", 0)) >= 4;
 142 print "ok ", $test++, "\n";
 143
 144 print "not " unless length(pack("I", 0)) >= 4;
 145 print "ok ", $test++, "\n";
 146
 147 print "not " unless length(pack("l", 0)) == 4;
 148 print "ok ", $test++, "\n";
 149
 150 print "not " unless length(pack("L", 0)) == 4;
 151 print "ok ", $test++, "\n";
 152
 153 # 37..40: test the pack lengths of n N v V
 154
 155 print "not " unless length(pack("n", 0)) == 2;
 156 print "ok ", $test++, "\n";
 157
 158 print "not " unless length(pack("N", 0)) == 4;
 159 print "ok ", $test++, "\n";
 160
 161 print "not " unless length(pack("v", 0)) == 2;
 162 print "ok ", $test++, "\n";
 163
 164 print "not " unless length(pack("V", 0)) == 4;
 165 print "ok ", $test++, "\n";
 166
 167 # 41..56: test unpack-pack lengths
 168
 169 my @templates = qw(c C i I s S l L n N v V f d);
 170
 171 # quads not supported everywhere: if not, retest floats/doubles
 172 # to preserve the test count...
 173 eval { my $q = pack("q",0) };
 174 push @templates, $@ !~ /Invalid type in pack/ ? qw(q Q) : qw(f d);
 175
 176 foreach my $t (@templates) {
 177     my @t = unpack("$t*", pack("$t*", 12, 34));
 178     print "not "
 179       unless @t == 2 and (($t[0] == 12 and $t[1] == 34) or ($t =~ /[nv]/i));
 180     print "ok ", $test++, "\n";
 181 }
 182
 183 # 57..60: uuencode/decode
 184
 185 # Note that first uuencoding known 'text' data and then checking the
 186 # binary values of the uuencoded version would not be portable between
 187 # character sets.  Uuencoding is meant for encoding binary data, not
 188 # text data.
 189
 190 $in = pack 'C*', 0 .. 255;
 191
 192 # just to be anal, we do some random tr/`/ /
 193 $uu = <<'EOUU';
 194 M` $"`P0%!@<("0H+# T.#Q`1$A,4%187&!D:&QP='A\@(2(C)"4F)R@I*BLL
 195 M+2XO,#$R,S0U-C<X.3H[/#T^/T!!0D-$149'2$E*2TQ-3D]045)35%565UA9
 196 M6EM<75Y?8&%B8V1E9F=H:6IK;&UN;W!Q<G-T=79W>'EZ>WQ]?G^`@8*#A(6&
 197 MAXB)BHN,C8Z/D)&2DY25EI>8F9J;G)V>GZ"AHJ.DI::GJ*FJJZRMKJ^PL;*S
 198 MM+6VM[BYNKN\O;Z_P,'"P\3%QL?(R<K+S,W.S]#1TM/4U=;7V-G:V]S=WM_@
 199 ?X>+CY.7FY^CIZNOL[>[O\/'R\_3U]O?X^?K[_/W^_P `
 200 EOUU
 201
 202 $_ = $uu;
 203 tr/ /`/;
 204 print "not " unless pack('u', $in) eq $_;
 205 print "ok ", $test++, "\n";
 206
 207 print "not " unless unpack('u', $uu) eq $in;
 208 print "ok ", $test++, "\n";
 209
 210 $in = "\x1f\x8b\x08\x08\x58\xdc\xc4\x35\x02\x03\x4a\x41\x50\x55\x00\xf3\x2a\x2d\x2e\x51\x48\xcc\xcb\x2f\xc9\x48\x2d\x52\x08\x48\x2d\xca\x51\x28\x2d\x4d\xce\x4f\x49\x2d\xe2\x02\x00\x64\x66\x60\x5c\x1a\x00\x00\x00";
 211 $uu = <<'EOUU';
 212 M'XL("%C<Q#4"`TI!4%4`\RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>("`&1F
 213 &8%P:````
 214 EOUU
 215
 216 print "not " unless unpack('u', $uu) eq $in;
 217 print "ok ", $test++, "\n";
 218
 219 # 60 identical to 59 except that backquotes have been changed to spaces
 220
 221 $uu = <<'EOUU';
 222 M'XL("%C<Q#4" TI!4%4 \RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>(" &1F
 223 &8%P:
 224 EOUU
 225
 226 print "not " unless unpack('u', $uu) eq $in;
 227 print "ok ", $test++, "\n";
 228
 229 # 61..73: test the ascii template types (A, a, Z)
 230
 231 print "not " unless pack('A*', "foo\0bar\0 ") eq "foo\0bar\0 ";
 232 print "ok ", $test++, "\n";
 233
 234 print "not " unless pack('A11', "foo\0bar\0 ") eq "foo\0bar\0   ";
 235 print "ok ", $test++, "\n";
 236
 237 print "not " unless unpack('A*', "foo\0bar \0") eq "foo\0bar";
 238 print "ok ", $test++, "\n";
 239
 240 print "not " unless unpack('A8', "foo\0bar \0") eq "foo\0bar";
 241 print "ok ", $test++, "\n";
 242
 243 print "not " unless pack('a*', "foo\0bar\0 ") eq "foo\0bar\0 ";
 244 print "ok ", $test++, "\n";
 245
 246 print "not " unless pack('a11', "foo\0bar\0 ") eq "foo\0bar\0 \0\0";
 247 print "ok ", $test++, "\n";
 248
 249 print "not " unless unpack('a*', "foo\0bar \0") eq "foo\0bar \0";
 250 print "ok ", $test++, "\n";
 251
 252 print "not " unless unpack('a8', "foo\0bar \0") eq "foo\0bar ";
 253 print "ok ", $test++, "\n";
 254
 255 print "not " unless pack('Z*', "foo\0bar\0 ") eq "foo\0bar\0 \0";
 256 print "ok ", $test++, "\n";
 257
 258 print "not " unless pack('Z11', "foo\0bar\0 ") eq "foo\0bar\0 \0\0";
 259 print "ok ", $test++, "\n";
 260
 261 print "not " unless pack('Z3', "foo") eq "fo\0";
 262 print "ok ", $test++, "\n";
 263
 264 print "not " unless unpack('Z*', "foo\0bar \0") eq "foo";
 265 print "ok ", $test++, "\n";
 266
 267 print "not " unless unpack('Z8', "foo\0bar \0") eq "foo";
 268 print "ok ", $test++, "\n";
 269
 270 # 74..79: packing native shorts/ints/longs
 271
 272 print "not " unless length(pack("s!", 0)) == $Config{shortsize};
 273 print "ok ", $test++, "\n";
 274
 275 print "not " unless length(pack("i!", 0)) == $Config{intsize};
 276 print "ok ", $test++, "\n";
 277
 278 print "not " unless length(pack("l!", 0)) == $Config{longsize};
 279 print "ok ", $test++, "\n";
 280
 281 print "not " unless length(pack("s!", 0)) <= length(pack("i!", 0));
 282 print "ok ", $test++, "\n";
 283
 284 print "not " unless length(pack("i!", 0)) <= length(pack("l!", 0));
 285 print "ok ", $test++, "\n";
 286
 287 print "not " unless length(pack("i!", 0)) == length(pack("i", 0));
 288 print "ok ", $test++, "\n";
 289
 290 # 80..139: pack <-> unpack bijectionism
 291
 292 #  80.. 84 c
 293 foreach my $c (-128, -1, 0, 1, 127) {
 294     print "not " unless unpack("c", pack("c", $c)) == $c;
 295     print "ok ", $test++, "\n";
 296 }
 297
 298 #  85.. 89: C
 299 foreach my $C (0, 1, 127, 128, 255) {
 300     print "not " unless unpack("C", pack("C", $C)) == $C;
 301     print "ok ", $test++, "\n";
 302 }
 303
 304 #  90.. 94: s
 305 foreach my $s (-32768, -1, 0, 1, 32767) {
 306     print "not " unless unpack("s", pack("s", $s)) == $s;
 307     print "ok ", $test++, "\n";
 308 }
 309
 310 #  95.. 99: S
 311 foreach my $S (0, 1, 32767, 32768, 65535) {
 312     print "not " unless unpack("S", pack("S", $S)) == $S;
 313     print "ok ", $test++, "\n";
 314 }
 315
 316 #  100..104: i
 317 foreach my $i (-2147483648, -1, 0, 1, 2147483647) {
 318     print "not " unless unpack("i", pack("i", $i)) == $i;
 319     print "ok ", $test++, "\n";
 320 }
 321
 322 # 105..109: I
 323 foreach my $I (0, 1, 2147483647, 2147483648, 4294967295) {
 324     print "not " unless unpack("I", pack("I", $I)) == $I;
 325     print "ok ", $test++, "\n";
 326 }
 327
 328 # 110..114: l
 329 foreach my $l (-2147483648, -1, 0, 1, 2147483647) {
 330     print "not " unless unpack("l", pack("l", $l)) == $l;
 331     print "ok ", $test++, "\n";
 332 }
 333
 334 # 115..119: L
 335 foreach my $L (0, 1, 2147483647, 2147483648, 4294967295) {
 336     print "not " unless unpack("L", pack("L", $L)) == $L;
 337     print "ok ", $test++, "\n";
 338 }
 339
 340 # 120..124: n
 341 foreach my $n (0, 1, 32767, 32768, 65535) {
 342     print "not " unless unpack("n", pack("n", $n)) == $n;
 343     print "ok ", $test++, "\n";
 344 }
 345
 346 # 125..129: v
 347 foreach my $v (0, 1, 32767, 32768, 65535) {
 348     print "not " unless unpack("v", pack("v", $v)) == $v;
 349     print "ok ", $test++, "\n";
 350 }
 351
 352 # 130..134: N
 353 foreach my $N (0, 1, 2147483647, 2147483648, 4294967295) {
 354     print "not " unless unpack("N", pack("N", $N)) == $N;
 355     print "ok ", $test++, "\n";
 356 }
 357
 358 # 135..139: V
 359 foreach my $V (0, 1, 2147483647, 2147483648, 4294967295) {
 360     print "not " unless unpack("V", pack("V", $V)) == $V;
 361     print "ok ", $test++, "\n";
 362 }
 363
 364 # 140..143: pack nvNV byteorders
 365
 366 print "not " unless pack("n", 0xdead) eq "\xde\xad";
 367 print "ok ", $test++, "\n";
 368
 369 print "not " unless pack("v", 0xdead) eq "\xad\xde";
 370 print "ok ", $test++, "\n";
 371
 372 print "not " unless pack("N", 0xdeadbeef) eq "\xde\xad\xbe\xef";
 373 print "ok ", $test++, "\n";
 374
 375 print "not " unless pack("V", 0xdeadbeef) eq "\xef\xbe\xad\xde";
 376 print "ok ", $test++, "\n";
 377
 378 # 144..152: /
 379
 380 # Using Test considered bad plan in op/*.t ?
 381
 382 sub report {
 383   my ($pass, $test, $err, $wrong) = @_;
 384   if ($pass) {
 385     print "ok $test\n"
 386   } else {
 387     if ($err) {
 388       chomp $err;
 389       print "not ok $test # \$\@ = $err\n";
 390     } else {
 391       $wrong =~ s/([[:cntrl:]\177 ])/sprintf "\\%03o", ord $1/ge;
 392       print "not ok $test # got $wrong\n";
 393     }
 394   }
 395 }
 396
 397 my $z;
 398 eval { ($x) = unpack '/a*','hello' };
 399 print 'not ' unless $@; print "ok $test\n"; $test++;
 400 eval { ($z,$x,$y) = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
 401 print $@ eq '' && $z eq 'ok' ? "ok $test\n" : "not ok $test\n"; $test++;
 402 print $@ eq '' && $x eq 'yes' ? "ok $test\n" : "not ok $test\n"; $test++;
 403 print $@ eq '' && $y eq 'z' ? "ok $test\n" : "not ok $test\n"; $test++;
 404
 405 eval { ($x) = pack '/a*','hello' };
 406 print 'not ' unless $@; print "ok $test\n"; $test++;
 407 $z = pack 'n/a* N/Z* w/A*','string','hi there ','etc';
 408 my $expect = "\000\006string\0\0\0\012hi there \000\003etc";
 409 report ($z eq $expect, $test++, '', $z);
 410
 411 eval { ($x) = unpack 'a/a*/a*', '212ab345678901234567' };
 412 print $@ eq '' && $x eq 'ab3456789012' ? "ok $test\n" : "#$x,$@\nnot ok $test\n";
 413 $test++;
 414
 415 eval { ($x) = unpack 'a/a*/a*', '3012ab345678901234567' };
 416 print $@ eq '' && $x eq 'ab3456789012' ? "ok $test\n" : "not ok $test\n";
 417 $test++;
 418
 419 eval { ($x) = unpack 'a/a*/b*', '212ab' };
 420 my $expected_x = '100001100100';
 421 if ($Is_EBCDIC) { $expected_x = '100000010100'; }
 422 print $@ eq '' && $x eq $expected_x ? "ok $test\n" : "#$x,$@\nnot ok $test\n";
 423 $test++;
 424
 425 # 153..156: / with #
 426
 427 eval { ($z,$x,$y) = unpack <<EOU, "003ok \003yes\004z\000abc" };
 428  a3/A                   # Count in ASCII
 429  C/a*                   # Count in a C char
 430  C/Z                    # Count in a C char but skip after \0
 431 EOU
 432 print $@ eq '' && $z eq 'ok' ? "ok $test\n" : "not ok $test\n"; $test++;
 433 print $@ eq '' && $x eq 'yes' ? "ok $test\n" : "not ok $test\n"; $test++;
 434 print $@ eq '' && $y eq 'z' ? "ok $test\n" : "not ok $test\n"; $test++;
 435
 436 $z = pack <<EOP,'string','etc';
 437   n/a*                  # Count as network short
 438   w/A*                  # Count a  BER integer
 439 EOP
 440 $expect = "\000\006string\003etc";
 441 report ($z eq $expect, $test++, '', $z);
 442
 443 print 'not ' unless "1.20.300.4000" eq sprintf "%vd", pack("U*",1,20,300,4000);
 444 print "ok $test\n"; $test++;
 445 print 'not ' unless "1.20.300.4000" eq
 446                     sprintf "%vd", pack("  U*",1,20,300,4000);
 447 print "ok $test\n"; $test++;
 448 print 'not ' unless v1.20.300.4000 ne
 449                     sprintf "%vd", pack("C0U*",1,20,300,4000);
 450 print "ok $test\n"; $test++;
 451
 452 # 160
 453 print "not " unless join(" ", unpack("C*", chr(0x1e2)))
 454         eq ((ord(A) == 193) ? "156 67" : "199 162");
 455 print "ok $test\n"; $test++;