t/op/magic.t

   1 #!./perl
   2
   3 BEGIN {
   4     $| = 1;
   5     chdir 't' if -d 't';
   6     @INC = '../lib';
   7     $SIG{__WARN__} = sub { die "Dying on warning: ", @_ };
   8 }
   9
  10 use warnings;
  11 use Config;
  12
  13 my $test = 1;
  14 sub ok {
  15     my($ok, $info, $todo) = @_;
  16
  17     # You have to do it this way or VMS will get confused.
  18     printf "%s $test%s\n", $ok ? "ok" : "not ok",
  19                            $todo ? " # TODO $todo" : '';
  20
  21     unless( $ok ) {
  22         printf "# Failed test at line %d\n", (caller)[2];
  23         print  "# $info" if defined $info;
  24     }
  25
  26     $test++;
  27     return $ok;
  28 }
  29
  30 sub skip {
  31     my($reason) = @_;
  32
  33     printf "ok $test # skipped%s\n", defined $reason ? ": $reason" : '';
  34
  35     $test++;
  36     return 1;
  37 }
  38
  39 print "1..43\n";
  40
  41 $Is_MSWin32 = $^O eq 'MSWin32';
  42 $Is_NetWare = $^O eq 'NetWare';
  43 $Is_VMS     = $^O eq 'VMS';
  44 $Is_Dos     = $^O eq 'dos';
  45 $Is_os2     = $^O eq 'os2';
  46 $Is_Cygwin  = $^O eq 'cygwin';
  47 $Is_MacOS   = $^O eq 'MacOS';
  48 $Is_MPE     = $^O eq 'mpeix';
  49
  50 $PERL = ($Is_NetWare            ? 'perl'   :
  51          ($Is_MacOS || $Is_VMS) ? $^X      :
  52          $Is_MSWin32            ? '.\perl' :
  53          './perl');
  54
  55 eval '$ENV{"FOO"} = "hi there";';       # check that ENV is inited inside eval
  56 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
  57 # -- Nikola Knezevic
  58 if ($Is_MSWin32)  { ok `set FOO` =~ /^(FOO=)?hi there$/; }
  59 elsif ($Is_MacOS) { ok "1 # skipped", 1; }
  60 elsif ($Is_VMS)   { ok `write sys\$output f\$trnlnm("FOO")` eq "hi there\n"; }
  61 else              { ok `echo \$FOO` eq "hi there\n"; }
  62
  63 unlink 'ajslkdfpqjsjfk';
  64 $! = 0;
  65 open(FOO,'ajslkdfpqjsjfk');
  66 ok $!, $!;
  67 close FOO; # just mention it, squelch used-only-once
  68
  69 if ($Is_MSWin32 || $Is_NetWare || $Is_Dos || $Is_MPE || $Is_MacOS) {
  70     skip('SIGINT not safe on this platform') for 1..2;
  71 }
  72 else {
  73   # the next tests are done in a subprocess because sh spits out a
  74   # newline onto stderr when a child process kills itself with SIGINT.
  75   # We use a pipe rather than system() because the VMS command buffer
  76   # would overflow with a command that long.
  77
  78     open( CMDPIPE, "| $PERL");
  79
  80     print CMDPIPE <<'END';
  81
  82     $| = 1;             # command buffering
  83
  84     $SIG{"INT"} = "ok3";     kill "INT",$$; sleep 1;
  85     $SIG{"INT"} = "IGNORE";  kill "INT",$$; sleep 1; print "ok 4\n";
  86     $SIG{"INT"} = "DEFAULT"; kill "INT",$$; sleep 1; print "not ok 4\n";
  87
  88     sub ok3 {
  89         if (($x = pop(@_)) eq "INT") {
  90             print "ok 3\n";
  91         }
  92         else {
  93             print "not ok 3 ($x @_)\n";
  94         }
  95     }
  96
  97 END
  98
  99     close CMDPIPE;
 100
 101     $test += 2;
 102 }
 103
 104 # can we slice ENV?
 105 @val1 = @ENV{keys(%ENV)};
 106 @val2 = values(%ENV);
 107 ok join(':',@val1) eq join(':',@val2);
 108 ok @val1 > 1;
 109
 110 # regex vars
 111 'foobarbaz' =~ /b(a)r/;
 112 ok $` eq 'foo', $`;
 113 ok $& eq 'bar', $&;
 114 ok $' eq 'baz', $';
 115 ok $+ eq 'a', $+;
 116
 117 # $"
 118 @a = qw(foo bar baz);
 119 ok "@a" eq "foo bar baz", "@a";
 120 {
 121     local $" = ',';
 122     ok "@a" eq "foo,bar,baz", "@a";
 123 }
 124
 125 # $;
 126 %h = ();
 127 $h{'foo', 'bar'} = 1;
 128 ok((keys %h)[0] eq "foo\034bar", (keys %h)[0]);
 129 {
 130     local $; = 'x';
 131     %h = ();
 132     $h{'foo', 'bar'} = 1;
 133     ok((keys %h)[0] eq 'fooxbar', (keys %h)[0]);
 134 }
 135
 136 # $?, $@, $$
 137 system qq[$PERL -e "exit(0)"];
 138 ok $? == 0, $?;
 139 system qq[$PERL -e "exit(1)"];
 140 ok $? != 0, $?;
 141
 142 eval { die "foo\n" };
 143 ok $@ eq "foo\n", $@;
 144
 145 ok $$ > 0, $$;
 146
 147 # $^X and $0
 148 {
 149     if ($^O eq 'qnx') {
 150         chomp($wd = `/usr/bin/fullpath -t`);
 151     }
 152     elsif($Is_Cygwin || $Config{'d_procselfexe'}) {
 153        # Cygwin turns the symlink into the real file
 154        chomp($wd = `pwd`);
 155        $wd =~ s#/t$##;
 156     }
 157     elsif($Is_os2) {
 158        $wd = Cwd::sys_cwd();
 159     }
 160     elsif($Is_MacOS) {
 161        $wd = ':';
 162     }
 163     else {
 164         $wd = '.';
 165     }
 166     my $perl = ($Is_MacOS || $Is_VMS) ? $^X : "$wd/perl";
 167     my $headmaybe = '';
 168     my $tailmaybe = '';
 169     $script = "$wd/show-shebang";
 170     if ($Is_MSWin32) {
 171         chomp($wd = `cd`);
 172         $wd =~ s|\\|/|g;
 173         $perl = "$wd/perl.exe";
 174         $script = "$wd/show-shebang.bat";
 175         $headmaybe = <<EOH ;
 176 \@rem ='
 177 \@echo off
 178 $perl -x \%0
 179 goto endofperl
 180 \@rem ';
 181 EOH
 182         $tailmaybe = <<EOT ;
 183
 184 __END__
 185 :endofperl
 186 EOT
 187     }
 188     elsif ($Is_os2) {
 189       $script = "./show-shebang";
 190     }
 191     elsif ($Is_MacOS) {
 192       $script = ":show-shebang";
 193     }
 194     elsif ($Is_VMS) {
 195       $script = "[]show-shebang";
 196     }
 197     if ($^O eq 'os390' or $^O eq 'posix-bc' or $^O eq 'vmesa') {  # no shebang
 198         $headmaybe = <<EOH ;
 199     eval 'exec ./perl -S \$0 \${1+"\$\@"}'
 200         if 0;
 201 EOH
 202     }
 203     $s1 = "\$^X is $perl, \$0 is $script\n";
 204     ok open(SCRIPT, ">$script"), $!;
 205     ok print(SCRIPT $headmaybe . <<EOB . <<'EOF' . $tailmaybe), $!;
 206 #!$wd/perl
 207 EOB
 208 print "\$^X is $^X, \$0 is $0\n";
 209 EOF
 210     ok close(SCRIPT), $!;
 211     ok chmod(0755, $script), $!;
 212     $_ = ($Is_MacOS || $Is_VMS) ? `$perl $script` : `$script`;
 213     s/\.exe//i if $Is_Dos or $Is_Cygwin or $Is_os2;
 214     s{\bminiperl\b}{perl}; # so that test doesn't fail with miniperl
 215     s{is perl}{is $perl}; # for systems where $^X is only a basename
 216     s{\\}{/}g;
 217     ok((($Is_MSWin32 || $Is_os2) ? uc($_) eq uc($s1) : $_ eq $s1), " :$_:!=:$s1:");
 218     $_ = `$perl $script`;
 219     s/\.exe//i if $Is_Dos or $Is_os2;
 220     s{\\}{/}g;
 221     ok((($Is_MSWin32 || $Is_os2) ? uc($_) eq uc($s1) : $_ eq $s1), " :$_:!=:$s1: after `$perl $script`");
 222     ok unlink($script), $!;
 223 }
 224
 225 # $], $^O, $^T
 226 ok $] >= 5.00319, $];
 227 ok $^O;
 228 ok $^T > 850000000, $^T;
 229
 230 if ($Is_VMS || $Is_Dos || $Is_MacOS) {
 231     skip("%ENV manipulations fail or aren't safe on $^O") for 1..2;
 232 }
 233 else {
 234         $PATH = $ENV{PATH};
 235         $PDL = $ENV{PERL_DESTRUCT_LEVEL} || 0;
 236         $ENV{foo} = "bar";
 237         %ENV = ();
 238         $ENV{PATH} = $PATH;
 239         $ENV{PERL_DESTRUCT_LEVEL} = $PDL || 0;
 240         ok ($Is_MSWin32 ? (`set foo 2>NUL` eq "")
 241                                 : (`echo \$foo` eq "\n") );
 242
 243         $ENV{__NoNeSuCh} = "foo";
 244         $0 = "bar";
 245 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
 246 # -- Nikola Knezevic
 247         ok ($Is_MSWin32 ? (`set __NoNeSuCh` =~ /^(__NoNeSuCh=)?foo$/)
 248                             : (`echo \$__NoNeSuCh` eq "foo\n") );
 249 }
 250
 251 if ($Is_VMS) {
 252     ok(1,0,"'\$!=undef' does throw a warning");
 253 }
 254 else {
 255     local $SIG{'__WARN__'} = sub { print "# @_\nnot " };
 256     $! = undef;
 257     ok 1;
 258 }
 259
 260 # test case-insignificance of %ENV (these tests must be enabled only
 261 # when perl is compiled with -DENV_IS_CASELESS)
 262 if ($Is_MSWin32 || $Is_NetWare) {
 263     %ENV = ();
 264     $ENV{'Foo'} = 'bar';
 265     $ENV{'fOo'} = 'baz';
 266     ok (scalar(keys(%ENV)) == 1);
 267     ok exists($ENV{'FOo'});
 268     ok (delete($ENV{'foO'}) eq 'baz');
 269     ok (scalar(keys(%ENV)) == 0);
 270 }
 271 else {
 272     skip('no caseless %ENV support') for 1..4;
 273 }
 274
 275 # Make sure Errno hasn't been prematurely autoloaded
 276
 277 ok !defined %Errno::;
 278
 279 # Test auto-loading of Errno when %! is used
 280
 281 ok scalar eval q{
 282    my $errs = %!;
 283    defined %Errno::;
 284 }, $@;
 285
 286
 287 # Make sure that Errno loading doesn't clobber $!
 288
 289 undef %Errno::;
 290 delete $INC{"Errno.pm"};
 291
 292 open(FOO, "nonesuch"); # Generate ENOENT
 293 my %errs = %{"!"}; # Cause Errno.pm to be loaded at run-time
 294 ok ${"!"}{ENOENT};
 295
 296 ok $^S == 0;
 297 eval { ok $^S == 1 };
 298 ok $^S == 0;
 299
 300 ok ${^TAINT} == 0;
 301 eval { ${^TAINT} = 1 };
 302 ok ${^TAINT} == 0;