t/op/lfs.t

   1 # NOTE: this file tests how large files (>2GB) work with perlio (stdio/sfio).
   2 # sysopen(), sysseek(), syswrite(), sysread() are tested in t/lib/syslfs.t.
   3 # If you modify/add tests here, remember to update also ext/Fcntl/t/syslfs.t.
   4
   5 BEGIN {
   6         chdir 't' if -d 't';
   7         @INC = '../lib';
   8         # Don't bother if there are no quad offsets.
   9         require Config; import Config;
  10         if ($Config{lseeksize} < 8) {
  11                 print "1..0 # Skip: no 64-bit file offsets\n";
  12                 exit(0);
  13         }
  14         require './test.pl';
  15 }
  16
  17 use strict;
  18
  19 our @s;
  20 our $fail;
  21
  22 my $big0 = tempfile();
  23 my $big1 = tempfile();
  24 my $big2 = tempfile();
  25
  26 sub zap {
  27     close(BIG);
  28 }
  29
  30 sub bye {
  31     zap();
  32     exit(0);
  33 }
  34
  35 my $explained;
  36
  37 sub explain {
  38     unless ($explained++) {
  39         print <<EOM;
  40 #
  41 # If the lfs (large file support: large meaning larger than two
  42 # gigabytes) tests are skipped or fail, it may mean either that your
  43 # process (or process group) is not allowed to write large files
  44 # (resource limits) or that the file system (the network filesystem?)
  45 # you are running the tests on doesn't let your user/group have large
  46 # files (quota) or the filesystem simply doesn't support large files.
  47 # You may even need to reconfigure your kernel.  (This is all very
  48 # operating system and site-dependent.)
  49 #
  50 # Perl may still be able to support large files, once you have
  51 # such a process, enough quota, and such a (file) system.
  52 # It is just that the test failed now.
  53 #
  54 EOM
  55     }
  56     print "1..0 # Skip: @_\n" if @_;
  57 }
  58
  59 $| = 1;
  60
  61 print "# checking whether we have sparse files...\n";
  62
  63 # Known have-nots.
  64 if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
  65     print "1..0 # Skip: no sparse files in $^O\n";
  66     bye();
  67 }
  68
  69 # Known haves that have problems running this test
  70 # (for example because they do not support sparse files, like UNICOS)
  71 if ($^O eq 'unicos') {
  72     print "1..0 # Skip: no sparse files in $^O, unable to test large files\n";
  73     bye();
  74 }
  75
  76 # Then try to heuristically deduce whether we have sparse files.
  77
  78 # Let's not depend on Fcntl or any other extension.
  79
  80 my ($SEEK_SET, $SEEK_CUR, $SEEK_END) = (0, 1, 2);
  81
  82 # We'll start off by creating a one megabyte file which has
  83 # only three "true" bytes.  If we have sparseness, we should
  84 # consume less blocks than one megabyte (assuming nobody has
  85 # one megabyte blocks...)
  86
  87 open(BIG, ">$big1") or
  88     do { warn "open $big1 failed: $!\n"; bye };
  89 binmode(BIG) or
  90     do { warn "binmode $big1 failed: $!\n"; bye };
  91 seek(BIG, 1_000_000, $SEEK_SET) or
  92     do { warn "seek $big1 failed: $!\n"; bye };
  93 print BIG "big" or
  94     do { warn "print $big1 failed: $!\n"; bye };
  95 close(BIG) or
  96     do { warn "close $big1 failed: $!\n"; bye };
  97
  98 my @s1 = stat($big1);
  99
 100 print "# s1 = @s1\n";
 101
 102 open(BIG, ">$big2") or
 103     do { warn "open $big2 failed: $!\n"; bye };
 104 binmode(BIG) or
 105     do { warn "binmode $big2 failed: $!\n"; bye };
 106 seek(BIG, 2_000_000, $SEEK_SET) or
 107     do { warn "seek $big2 failed; $!\n"; bye };
 108 print BIG "big" or
 109     do { warn "print $big2 failed; $!\n"; bye };
 110 close(BIG) or
 111     do { warn "close $big2 failed; $!\n"; bye };
 112
 113 my @s2 = stat($big2);
 114
 115 print "# s2 = @s2\n";
 116
 117 zap();
 118
 119 unless ($s1[7] == 1_000_003 && $s2[7] == 2_000_003 &&
 120         $s1[11] == $s2[11] && $s1[12] == $s2[12]) {
 121         print "1..0 # Skip: no sparse files?\n";
 122         bye;
 123 }
 124
 125 print "# we seem to have sparse files...\n";
 126
 127 # By now we better be sure that we do have sparse files:
 128 # if we are not, the following will hog 5 gigabytes of disk.  Ooops.
 129 # This may fail by producing some signal; run in a subprocess first for safety
 130
 131 $ENV{LC_ALL} = "C";
 132
 133 my $r = system '../perl', '-e', <<'EOF';
 134 open(BIG, ">$big0");
 135 seek(BIG, 5_000_000_000, 0);
 136 print BIG $big0;
 137 exit 0;
 138 EOF
 139
 140 open(BIG, ">$big0") or do { warn "open failed: $!\n"; bye };
 141 binmode BIG;
 142 if ($r or not seek(BIG, 5_000_000_000, $SEEK_SET)) {
 143     my $err = $r ? 'signal '.($r & 0x7f) : $!;
 144     explain("seeking past 2GB failed: $err");
 145     bye();
 146 }
 147
 148 # Either the print or (more likely, thanks to buffering) the close will
 149 # fail if there are are filesize limitations (process or fs).
 150 my $print = print BIG "big";
 151 print "# print failed: $!\n" unless $print;
 152 my $close = close BIG;
 153 print "# close failed: $!\n" unless $close;
 154 unless ($print && $close) {
 155     if ($! =~/too large/i) {
 156         explain("writing past 2GB failed: process limits?");
 157     } elsif ($! =~ /quota/i) {
 158         explain("filesystem quota limits?");
 159     } else {
 160         explain("error: $!");
 161     }
 162     bye();
 163 }
 164
 165 @s = stat($big0);
 166
 167 print "# @s\n";
 168
 169 unless ($s[7] == 5_000_000_003) {
 170     explain("kernel/fs not configured to use large files?");
 171     bye();
 172 }
 173
 174 sub fail {
 175     print "not ";
 176     $fail++;
 177 }
 178
 179 sub offset ($$) {
 180     my ($offset_will_be, $offset_want) = @_;
 181     my $offset_is = eval $offset_will_be;
 182     unless ($offset_is == $offset_want) {
 183         print "# bad offset $offset_is, want $offset_want\n";
 184         my ($offset_func) = ($offset_will_be =~ /^(\w+)/);
 185         if (unpack("L", pack("L", $offset_want)) == $offset_is) {
 186             print "# 32-bit wraparound suspected in $offset_func() since\n";
 187             print "# $offset_want cast into 32 bits equals $offset_is.\n";
 188         } elsif ($offset_want - unpack("L", pack("L", $offset_want)) - 1
 189                  == $offset_is) {
 190             print "# 32-bit wraparound suspected in $offset_func() since\n";
 191             printf "# %s - unpack('L', pack('L', %s)) - 1 equals %s.\n",
 192                 $offset_want,
 193                 $offset_want,
 194                 $offset_is;
 195         }
 196         fail;
 197     }
 198 }
 199
 200 print "1..17\n";
 201
 202 $fail = 0;
 203
 204 fail unless $s[7] == 5_000_000_003;     # exercizes pp_stat
 205 print "ok 1\n";
 206
 207 fail unless -s $big0 == 5_000_000_003;  # exercizes pp_ftsize
 208 print "ok 2\n";
 209
 210 fail unless -e $big0;
 211 print "ok 3\n";
 212
 213 fail unless -f $big0;
 214 print "ok 4\n";
 215
 216 open(BIG, $big0) or do { warn "open failed: $!\n"; bye };
 217 binmode BIG;
 218
 219 fail unless seek(BIG, 4_500_000_000, $SEEK_SET);
 220 print "ok 5\n";
 221
 222 offset('tell(BIG)', 4_500_000_000);
 223 print "ok 6\n";
 224
 225 fail unless seek(BIG, 1, $SEEK_CUR);
 226 print "ok 7\n";
 227
 228 # If you get 205_032_705 from here it means that
 229 # your tell() is returning 32-bit values since (I32)4_500_000_001
 230 # is exactly 205_032_705.
 231 offset('tell(BIG)', 4_500_000_001);
 232 print "ok 8\n";
 233
 234 fail unless seek(BIG, -1, $SEEK_CUR);
 235 print "ok 9\n";
 236
 237 offset('tell(BIG)', 4_500_000_000);
 238 print "ok 10\n";
 239
 240 fail unless seek(BIG, -3, $SEEK_END);
 241 print "ok 11\n";
 242
 243 offset('tell(BIG)', 5_000_000_000);
 244 print "ok 12\n";
 245
 246 my $big;
 247
 248 fail unless read(BIG, $big, 3) == 3;
 249 print "ok 13\n";
 250
 251 fail unless $big eq "big";
 252 print "ok 14\n";
 253
 254 # 705_032_704 = (I32)5_000_000_000
 255 # See that we don't have "big" in the 705_... spot:
 256 # that would mean that we have a wraparound.
 257 fail unless seek(BIG, 705_032_704, $SEEK_SET);
 258 print "ok 15\n";
 259
 260 my $zero;
 261
 262 fail unless read(BIG, $zero, 3) == 3;
 263 print "ok 16\n";
 264
 265 fail unless $zero eq "\0\0\0";
 266 print "ok 17\n";
 267
 268 explain() if $fail;
 269
 270 bye(); # does the necessary cleanup
 271
 272 END {
 273     # unlink may fail if applied directly to a large file
 274     # be paranoid about leaving 5 gig files lying around
 275     open(BIG, ">$big0"); # truncate
 276     close(BIG);
 277 }
 278
 279 # eof