t/op/inccode.t

   1 #!./perl -w
   2
   3 # Tests for the coderef-in-@INC feature
   4
   5 my $can_fork = 0;
   6 my $minitest = $ENV{PERL_CORE_MINITEST};
   7
   8 BEGIN {
   9     chdir 't' if -d 't';
  10     @INC = qw(. ../lib);
  11 }
  12
  13 if (!$minitest) {
  14     use Config;
  15     if (PerlIO::Layer->find('perlio') && $Config{d_fork} &&
  16         eval 'require POSIX; 1') {
  17         $can_fork = 1;
  18     }
  19 }
  20
  21 use strict;
  22 use File::Spec;
  23
  24 require "test.pl";
  25 plan(tests => 45 + !$minitest * (3 + 14 * $can_fork));
  26
  27 my @tempfiles = ();
  28
  29 sub get_temp_fh {
  30     my $f = "DummyModule0000";
  31     1 while -e ++$f;
  32     push @tempfiles, $f;
  33     open my $fh, ">$f" or die "Can't create $f: $!";
  34     print $fh "package ".substr($_[0],0,-3).";\n1;\n";
  35     print $fh $_[1] if @_ > 1;
  36     close $fh or die "Couldn't close: $!";
  37     open $fh, $f or die "Can't open $f: $!";
  38     return $fh;
  39 }
  40
  41 END { 1 while unlink @tempfiles }
  42
  43 sub fooinc {
  44     my ($self, $filename) = @_;
  45     if (substr($filename,0,3) eq 'Foo') {
  46         return get_temp_fh($filename);
  47     }
  48     else {
  49         return undef;
  50     }
  51 }
  52
  53 push @INC, \&fooinc;
  54
  55 my $evalret = eval { require Bar; 1 };
  56 ok( !$evalret,      'Trying non-magic package' );
  57
  58 $evalret = eval { require Foo; 1 };
  59 die $@ if $@;
  60 ok( $evalret,                      'require Foo; magic via code ref'  );
  61 ok( exists $INC{'Foo.pm'},         '  %INC sees Foo.pm' );
  62 is( ref $INC{'Foo.pm'}, 'CODE',    '  val Foo.pm is a coderef in %INC' );
  63 is( $INC{'Foo.pm'}, \&fooinc,      '  val Foo.pm is correct in %INC' );
  64
  65 $evalret = eval "use Foo1; 1;";
  66 die $@ if $@;
  67 ok( $evalret,                      'use Foo1' );
  68 ok( exists $INC{'Foo1.pm'},        '  %INC sees Foo1.pm' );
  69 is( ref $INC{'Foo1.pm'}, 'CODE',   '  val Foo1.pm is a coderef in %INC' );
  70 is( $INC{'Foo1.pm'}, \&fooinc,     '  val Foo1.pm is correct in %INC' );
  71
  72 $evalret = eval { do 'Foo2.pl'; 1 };
  73 die $@ if $@;
  74 ok( $evalret,                      'do "Foo2.pl"' );
  75 ok( exists $INC{'Foo2.pl'},        '  %INC sees Foo2.pl' );
  76 is( ref $INC{'Foo2.pl'}, 'CODE',   '  val Foo2.pl is a coderef in %INC' );
  77 is( $INC{'Foo2.pl'}, \&fooinc,     '  val Foo2.pl is correct in %INC' );
  78
  79 pop @INC;
  80
  81
  82 sub fooinc2 {
  83     my ($self, $filename) = @_;
  84     if (substr($filename, 0, length($self->[1])) eq $self->[1]) {
  85         return get_temp_fh($filename);
  86     }
  87     else {
  88         return undef;
  89     }
  90 }
  91
  92 my $arrayref = [ \&fooinc2, 'Bar' ];
  93 push @INC, $arrayref;
  94
  95 $evalret = eval { require Foo; 1; };
  96 die $@ if $@;
  97 ok( $evalret,                     'Originally loaded packages preserved' );
  98 $evalret = eval { require Foo3; 1; };
  99 ok( !$evalret,                    'Original magic INC purged' );
 100
 101 $evalret = eval { require Bar; 1 };
 102 die $@ if $@;
 103 ok( $evalret,                     'require Bar; magic via array ref' );
 104 ok( exists $INC{'Bar.pm'},        '  %INC sees Bar.pm' );
 105 is( ref $INC{'Bar.pm'}, 'ARRAY',  '  val Bar.pm is an arrayref in %INC' );
 106 is( $INC{'Bar.pm'}, $arrayref,    '  val Bar.pm is correct in %INC' );
 107
 108 ok( eval "use Bar1; 1;",          'use Bar1' );
 109 ok( exists $INC{'Bar1.pm'},       '  %INC sees Bar1.pm' );
 110 is( ref $INC{'Bar1.pm'}, 'ARRAY', '  val Bar1.pm is an arrayref in %INC' );
 111 is( $INC{'Bar1.pm'}, $arrayref,   '  val Bar1.pm is correct in %INC' );
 112
 113 ok( eval { do 'Bar2.pl'; 1 },     'do "Bar2.pl"' );
 114 ok( exists $INC{'Bar2.pl'},       '  %INC sees Bar2.pl' );
 115 is( ref $INC{'Bar2.pl'}, 'ARRAY', '  val Bar2.pl is an arrayref in %INC' );
 116 is( $INC{'Bar2.pl'}, $arrayref,   '  val Bar2.pl is correct in %INC' );
 117
 118 pop @INC;
 119
 120 sub FooLoader::INC {
 121     my ($self, $filename) = @_;
 122     if (substr($filename,0,4) eq 'Quux') {
 123         return get_temp_fh($filename);
 124     }
 125     else {
 126         return undef;
 127     }
 128 }
 129
 130 my $href = bless( {}, 'FooLoader' );
 131 push @INC, $href;
 132
 133 $evalret = eval { require Quux; 1 };
 134 die $@ if $@;
 135 ok( $evalret,                      'require Quux; magic via hash object' );
 136 ok( exists $INC{'Quux.pm'},        '  %INC sees Quux.pm' );
 137 is( ref $INC{'Quux.pm'}, 'FooLoader',
 138                                    '  val Quux.pm is an object in %INC' );
 139 is( $INC{'Quux.pm'}, $href,        '  val Quux.pm is correct in %INC' );
 140
 141 pop @INC;
 142
 143 my $aref = bless( [], 'FooLoader' );
 144 push @INC, $aref;
 145
 146 $evalret = eval { require Quux1; 1 };
 147 die $@ if $@;
 148 ok( $evalret,                      'require Quux1; magic via array object' );
 149 ok( exists $INC{'Quux1.pm'},       '  %INC sees Quux1.pm' );
 150 is( ref $INC{'Quux1.pm'}, 'FooLoader',
 151                                    '  val Quux1.pm is an object in %INC' );
 152 is( $INC{'Quux1.pm'}, $aref,       '  val Quux1.pm  is correct in %INC' );
 153
 154 pop @INC;
 155
 156 my $sref = bless( \(my $x = 1), 'FooLoader' );
 157 push @INC, $sref;
 158
 159 $evalret = eval { require Quux2; 1 };
 160 die $@ if $@;
 161 ok( $evalret,                      'require Quux2; magic via scalar object' );
 162 ok( exists $INC{'Quux2.pm'},       '  %INC sees Quux2.pm' );
 163 is( ref $INC{'Quux2.pm'}, 'FooLoader',
 164                                    '  val Quux2.pm is an object in %INC' );
 165 is( $INC{'Quux2.pm'}, $sref,       '  val Quux2.pm is correct in %INC' );
 166
 167 pop @INC;
 168
 169 push @INC, sub {
 170     my ($self, $filename) = @_;
 171     if (substr($filename,0,4) eq 'Toto') {
 172         $INC{$filename} = 'xyz';
 173         return get_temp_fh($filename);
 174     }
 175     else {
 176         return undef;
 177     }
 178 };
 179
 180 $evalret = eval { require Toto; 1 };
 181 die $@ if $@;
 182 ok( $evalret,                      'require Toto; magic via anonymous code ref'  );
 183 ok( exists $INC{'Toto.pm'},        '  %INC sees Toto.pm' );
 184 ok( ! ref $INC{'Toto.pm'},         q/  val Toto.pm isn't a ref in %INC/ );
 185 is( $INC{'Toto.pm'}, 'xyz',        '  val Toto.pm is correct in %INC' );
 186
 187 pop @INC;
 188
 189 push @INC, sub {
 190     my ($self, $filename) = @_;
 191     if ($filename eq 'abc.pl') {
 192         return get_temp_fh($filename, qq(return "abc";\n));
 193     }
 194     else {
 195         return undef;
 196     }
 197 };
 198
 199 my $ret = "";
 200 $ret ||= do 'abc.pl';
 201 is( $ret, 'abc', 'do "abc.pl" sees return value' );
 202
 203 {
 204     my $filename = $^O eq 'MacOS' ? ':Foo:Foo.pm' : './Foo.pm';
 205     #local @INC; # local fails on tied @INC
 206     my @old_INC = @INC; # because local doesn't work on tied arrays
 207     @INC = sub { $filename = 'seen'; return undef; };
 208     eval { require $filename; };
 209     is( $filename, 'seen', 'the coderef sees fully-qualified pathnames' );
 210     @INC = @old_INC;
 211 }
 212
 213 exit if $minitest;
 214
 215 pop @INC;
 216
 217 push @INC, sub {
 218     my ($cr, $filename) = @_;
 219     my $module = $filename; $module =~ s,/,::,g; $module =~ s/\.pm$//;
 220     open my $fh, '<', \"package $module; sub complain { warn q() }; \$::file = __FILE__;"
 221         or die $!;
 222     $INC{$filename} = "/custom/path/to/$filename";
 223     return $fh;
 224 };
 225
 226 require Publius::Vergilius::Maro;
 227 is( $INC{'Publius/Vergilius/Maro.pm'}, '/custom/path/to/Publius/Vergilius/Maro.pm', '%INC set correctly');
 228 is( our $file, '/custom/path/to/Publius/Vergilius/Maro.pm', '__FILE__ set correctly' );
 229 {
 230     my $warning;
 231     local $SIG{__WARN__} = sub { $warning = shift };
 232     Publius::Vergilius::Maro::complain();
 233     like( $warning, qr{something's wrong at /custom/path/to/Publius/Vergilius/Maro.pm}, 'warn() reports correct file source' );
 234 }
 235
 236 pop @INC;
 237
 238 if ($can_fork) {
 239     require PerlIO::scalar;
 240     # This little bundle of joy generates n more recursive use statements,
 241     # with each module chaining the next one down to 0. If it works, then we
 242     # can safely nest subprocesses
 243     my $use_filter_too;
 244     push @INC, sub {
 245         return unless $_[1] =~ /^BBBLPLAST(\d+)\.pm/;
 246         my $pid = open my $fh, "-|";
 247         if ($pid) {
 248             # Parent
 249             return $fh unless $use_filter_too;
 250             # Try filters and state in addition.
 251             return ($fh, sub {s/$_[1]/pass/; return}, "die")
 252         }
 253         die "Can't fork self: $!" unless defined $pid;
 254
 255         # Child
 256         my $count = $1;
 257         # Lets force some fun with odd sized reads.
 258         $| = 1;
 259         print 'push @main::bbblplast, ';
 260         print "$count;\n";
 261         if ($count--) {
 262             print "use BBBLPLAST$count;\n";
 263         }
 264         if ($use_filter_too) {
 265             print "die('In $_[1]');";
 266         } else {
 267             print "pass('In $_[1]');";
 268         }
 269         print '"Truth"';
 270         POSIX::_exit(0);
 271         die "Can't get here: $!";
 272     };
 273
 274     @::bbblplast = ();
 275     require BBBLPLAST5;
 276     is ("@::bbblplast", "0 1 2 3 4 5", "All ran");
 277
 278     foreach (keys %INC) {
 279         delete $INC{$_} if /^BBBLPLAST/;
 280     }
 281
 282     @::bbblplast = ();
 283     $use_filter_too = 1;
 284
 285     require BBBLPLAST5;
 286
 287     is ("@::bbblplast", "0 1 2 3 4 5", "All ran with a filter");
 288 }