t/op/grent.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = "../lib" if -d "../lib";
   6     eval { require Config; import Config; };
   7
   8     my $GR = "/etc/group";
   9
  10     $where = $GR;
  11
  12     if (-x "/usr/bin/nidump") { # nidump is not just NeXT/OpenStep
  13         if (open(GR, "nidump group . |")) {
  14             $where = "NetInfo group";
  15         } else {
  16             print "1..0\n";
  17             exit 0;
  18         }
  19     } elsif ((defined $Config{'i_grp'} and $Config{'i_grp'} ne 'define')
  20              or not -f $GR or not open(GR, $GR)
  21             ) {
  22         print "1..0\n";
  23         exit 0;
  24     }
  25 }
  26
  27 print "1..1\n";
  28
  29 # Go through at most this many groups.
  30 my $max = 25;
  31
  32 my $n   = 0;
  33 my $tst = 1;
  34 my %suspect;
  35 my %seen;
  36
  37 while (<GR>) {
  38     chomp;
  39     my @s = split /:/;
  40     my ($name_s,$passwd_s,$gid_s,$members_s) = @s;
  41     if (@s) {
  42         push @{ $seen{$name_s} }, $.;
  43     } else {
  44         warn "# Your $where line $. is empty.\n";
  45         next;
  46     }
  47     next if $n == $max;
  48     # In principle we could whine if @s != 4 but do we know enough
  49     # of group file formats everywhere?
  50     if (@s == 4) {
  51         $members_s =~ s/\s*,\s*/,/g;
  52         $members_s =~ s/\s+$//;
  53         $members_s =~ s/^\s+//;
  54         @n = getgrgid($gid_s);
  55         # 'nogroup' et al.
  56         next unless @n;
  57         my ($name,$passwd,$gid,$members) = @n;
  58         # Protect against one-to-many and many-to-one mappings.
  59         if ($name_s ne $name) {
  60             @n = getgrnam($name_s);
  61             ($name,$passwd,$gid,$members) = @n;
  62             next if $name_s ne $name;
  63         }
  64         $members =~ s/\s+/,/g;
  65         $suspect{$name_s}++
  66             if $name    ne $name_s    or
  67 # Shadow passwords confuse this.
  68 # Not that group passwords are used much but better not assume anything.
  69 #              $passwd  ne $passwd_s  or
  70                $gid     ne $gid_s     or
  71                $members ne $members_s;
  72     }
  73     $n++;
  74 }
  75
  76 # Drop the multiply defined groups.
  77
  78 foreach (sort keys %seen) {
  79     my $times = @{ $seen{$_} };
  80     if ($times > 1) {
  81         # Multiply defined groups are rarely intentional.
  82         local $" = ", ";
  83         print "# Group '$_' defined multiple times in $where, lines: @{$seen{$_}}.\n";
  84         delete $suspect{$_};
  85     }
  86 }
  87
  88 print "not " if keys %suspect;
  89 print "ok ", $tst++, "\n";
  90
  91 close(GR);