t/op/filetest.t

   1 #!./perl
   2
   3 # There are few filetest operators that are portable enough to test.
   4 # See pod/perlport.pod for details.
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';
   9     require './test.pl';
  10 }
  11
  12 use Config;
  13 plan(tests => 28 + 27*10);
  14
  15 ok( -d 'op' );
  16 ok( -f 'TEST' );
  17 ok( !-f 'op' );
  18 ok( !-d 'TEST' );
  19 ok( -r 'TEST' );
  20
  21 # make sure TEST is r-x
  22 eval { chmod 0555, 'TEST' or die "chmod 0555, 'TEST' failed: $!" };
  23 chomp ($bad_chmod = $@);
  24
  25 $oldeuid = $>;          # root can read and write anything
  26 eval '$> = 1';          # so switch uid (may not be implemented)
  27
  28 print "# oldeuid = $oldeuid, euid = $>\n";
  29
  30 SKIP: {
  31     if (!$Config{d_seteuid}) {
  32         skip('no seteuid');
  33     }
  34     elsif ($Config{config_args} =~/Dmksymlinks/) {
  35         skip('we cannot chmod symlinks');
  36     }
  37     elsif ($bad_chmod) {
  38         skip( $bad_chmod );
  39     }
  40     else {
  41         ok( !-w 'TEST' );
  42     }
  43 }
  44
  45 # Scripts are not -x everywhere so cannot test that.
  46
  47 eval '$> = $oldeuid';   # switch uid back (may not be implemented)
  48
  49 # this would fail for the euid 1
  50 # (unless we have unpacked the source code as uid 1...)
  51 ok( -r 'op' );
  52
  53 # this would fail for the euid 1
  54 # (unless we have unpacked the source code as uid 1...)
  55 SKIP: {
  56     if ($Config{d_seteuid}) {
  57         ok( -w 'op' );
  58     } else {
  59         skip('no seteuid');
  60     }
  61 }
  62
  63 ok( -x 'op' ); # Hohum.  Are directories -x everywhere?
  64
  65 is( "@{[grep -r, qw(foo io noo op zoo)]}", "io op" );
  66
  67 # Test stackability of filetest operators
  68
  69 ok( defined( -f -d 'TEST' ) && ! -f -d _ );
  70 ok( !defined( -e 'zoo' ) );
  71 ok( !defined( -e -d 'zoo' ) );
  72 ok( !defined( -f -e 'zoo' ) );
  73 ok( -f -e 'TEST' );
  74 ok( -e -f 'TEST' );
  75 ok( defined(-d -e 'TEST') );
  76 ok( defined(-e -d 'TEST') );
  77 ok( ! -f -d 'op' );
  78 ok( -x -d -x 'op' );
  79 ok( (-s -f 'TEST' > 1), "-s returns real size" );
  80 ok( -f -s 'TEST' == 1 );
  81
  82 # now with an empty file
  83 my $tempfile = tempfile();
  84 open my $fh, ">", $tempfile;
  85 close $fh;
  86 ok( -f $tempfile );
  87 is( -s $tempfile, 0 );
  88 is( -f -s $tempfile, 0 );
  89 is( -s -f $tempfile, 0 );
  90 unlink $tempfile;
  91
  92 # test that _ is a bareword after filetest operators
  93
  94 -f 'TEST';
  95 ok( -f _ );
  96 sub _ { "this is not a file name" }
  97 ok( -f _ );
  98
  99 my $over;
 100 {
 101     package OverFtest;
 102
 103     use overload -X => sub {
 104         $over = [overload::StrVal($_[0]), $_[1]];
 105         "-$_[1]";
 106     };
 107 }
 108 {
 109     package OverString;
 110
 111     # No fallback. -X should fall back to string overload even without
 112     # it.
 113     use overload q/""/ => sub { $over = 1; "TEST" };
 114 }
 115 {
 116     package OverBoth;
 117
 118     use overload
 119         q/""/   => sub { "TEST" },
 120         -X      => sub { "-$_[1]" };
 121 }
 122 {
 123     package OverNeither;
 124
 125     # Need fallback. Previous veraions of perl required 'fallback' to do
 126     # -X operations on an object with no "" overload.
 127     use overload
 128         '+' => sub { 1 },
 129         fallback => 1;
 130 }
 131
 132 my $ft = bless [], "OverFtest";
 133 my $ftstr = overload::StrVal($ft);
 134 my $str = bless [], "OverString";
 135 my $both = bless [], "OverBoth";
 136 my $neither = bless [], "OverNeither";
 137 my $nstr = overload::StrVal($neither);
 138
 139 for my $op (split //, "rwxoRWXOezsfdlpSbctugkTMBAC") {
 140     $over = [];
 141     ok( my $rv = eval "-$op \$ft",  "overloaded -$op succeeds" )
 142         or diag( $@ );
 143     is( $over->[0], $ftstr,         "correct object for overloaded -$op" );
 144     is( $over->[1], $op,            "correct op for overloaded -$op" );
 145     is( $rv,        "-$op",         "correct return value for overloaded -$op");
 146
 147     $over = 0;
 148     $rv = eval "-$op \$str";
 149     ok( !$@,                        "-$op succeeds with string overloading" )
 150         or diag( $@ );
 151     is( $rv, eval "-$op 'TEST'",    "correct -$op on string overload" );
 152     is( $over,      1,              "string overload called for -$op" );
 153
 154     $rv = eval "-$op \$both";
 155     is( $rv,        "-$op",         "correct -$op on string/-X overload" );
 156
 157     $rv = eval "-$op \$neither";
 158     ok( !$@,                        "-$op succeeds with random overloading" )
 159         or diag( $@ );
 160     is( $rv, eval "-$op \$nstr",    "correct -$op with random overloading" );
 161 }
 162
 163 is( -r -f $ft,  "-r",               "stacked overloaded -X" );