t/op/chdir.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     # We're not going to chdir() into 't' because we don't know if
   5     # chdir() works!  Instead, we'll hedge our bets and put both
   6     # possibilities into @INC.
   7     @INC = qw(t . lib ../lib);
   8 }
   9
  10 use Config;
  11 require "test.pl";
  12 plan(tests => 48);
  13
  14 my $IsVMS   = $^O eq 'VMS';
  15 my $IsMacOS = $^O eq 'MacOS';
  16
  17 # For an op regression test, I don't want to rely on "use constant" working.
  18 my $has_fchdir = ($Config{d_fchdir} || "") eq "define";
  19
  20 # Might be a little early in the testing process to start using these,
  21 # but I can't think of a way to write this test without them.
  22 use File::Spec::Functions qw(:DEFAULT splitdir rel2abs splitpath);
  23
  24 # Can't use Cwd::abs_path() because it has different ideas about
  25 # path separators than File::Spec.
  26 sub abs_path {
  27     my $d = rel2abs(curdir);
  28
  29     $d = uc($d) if $IsVMS;
  30     $d = lc($d) if $^O =~ /^uwin/;
  31     $d;
  32 }
  33
  34 my $Cwd = abs_path;
  35
  36 # Let's get to a known position
  37 SKIP: {
  38     my ($vol,$dir) = splitpath(abs_path,1);
  39     my $test_dir = $IsVMS ? 'T' : 't';
  40     skip("Already in t/", 2) if (splitdir($dir))[-1] eq $test_dir;
  41
  42     ok( chdir($test_dir),     'chdir($test_dir)');
  43     is( abs_path, catdir($Cwd, $test_dir),    '  abs_path() agrees' );
  44 }
  45
  46 $Cwd = abs_path;
  47
  48 SKIP: {
  49     skip("no fchdir", 16) unless $has_fchdir;
  50     my $has_dirfd = ($Config{d_dirfd} || "") eq "define";
  51     ok(opendir(my $dh, "."), "opendir .");
  52     ok(open(my $fh, "<", "op"), "open op");
  53     ok(chdir($fh), "fchdir op");
  54     ok(-f "chdir.t", "verify that we are in op");
  55     if ($has_dirfd) {
  56        ok(chdir($dh), "fchdir back");
  57     }
  58     else {
  59        eval { chdir($dh); };
  60        like($@, qr/^The dirfd function is unimplemented at/, "dirfd is unimplemented");
  61        chdir ".." or die $!;
  62     }
  63
  64     # same with bareword file handles
  65     no warnings 'once';
  66     *DH = $dh;
  67     *FH = $fh;
  68     ok(chdir FH, "fchdir op bareword");
  69     ok(-f "chdir.t", "verify that we are in op");
  70     if ($has_dirfd) {
  71        ok(chdir DH, "fchdir back bareword");
  72     }
  73     else {
  74        eval { chdir(DH); };
  75        like($@, qr/^The dirfd function is unimplemented at/, "dirfd is unimplemented");
  76        chdir ".." or die $!;
  77     }
  78     ok(-d "op", "verify that we are back");
  79
  80     # And now the ambiguous case
  81     ok(opendir(H, "op"), "opendir op") or diag $!;
  82     ok(open(H, "<", "base"), "open base") or diag $!;
  83     if (($Config{d_dirfd} || "") eq "define") {
  84         ok(chdir(H), "fchdir to op");
  85         ok(-f "chdir.t", "verify that we are in 'op'");
  86         chdir ".." or die $!;
  87     }
  88     else {
  89         eval { chdir(H); };
  90         like($@, qr/^The dirfd function is unimplemented at/,
  91              "dirfd is unimplemented");
  92         SKIP: {
  93             skip("dirfd is unimplemented");
  94         }
  95     }
  96     ok(closedir(H), "closedir");
  97     ok(chdir(H), "fchdir to base");
  98     ok(-f "cond.t", "verify that we are in 'base'");
  99     chdir ".." or die $!;
 100 }
 101
 102 SKIP: {
 103     skip("has fchdir", 1) if $has_fchdir;
 104     opendir(my $dh, "op");
 105     eval { chdir($dh); };
 106     like($@, qr/^The fchdir function is unimplemented at/, "fchdir is unimplemented");
 107 }
 108
 109 # The environment variables chdir() pays attention to.
 110 my @magic_envs = qw(HOME LOGDIR SYS$LOGIN);
 111
 112 sub check_env {
 113     my($key) = @_;
 114
 115     # Make sure $ENV{'SYS$LOGIN'} is only honored on VMS.
 116     if( $key eq 'SYS$LOGIN' && !$IsVMS && !$IsMacOS ) {
 117         ok( !chdir(),         "chdir() on $^O ignores only \$ENV{$key} set" );
 118         is( abs_path, $Cwd,   '  abs_path() did not change' );
 119         pass( "  no need to test SYS\$LOGIN on $^O" ) for 1..7;
 120     }
 121     else {
 122         ok( chdir(),              "chdir() w/ only \$ENV{$key} set" );
 123         is( abs_path, $ENV{$key}, '  abs_path() agrees' );
 124         chdir($Cwd);
 125         is( abs_path, $Cwd,       '  and back again' );
 126
 127         my $warning = '';
 128         local $SIG{__WARN__} = sub { $warning .= join '', @_ };
 129
 130
 131         # Check the deprecated chdir(undef) feature.
 132 #line 64
 133         ok( chdir(undef),           "chdir(undef) w/ only \$ENV{$key} set" );
 134         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
 135         is( $warning,  <<WARNING,   '  got uninit & deprecation warning' );
 136 Use of uninitialized value in chdir at $0 line 64.
 137 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 64.
 138 WARNING
 139
 140         chdir($Cwd);
 141
 142         # Ditto chdir('').
 143         $warning = '';
 144 #line 76
 145         ok( chdir(''),              "chdir('') w/ only \$ENV{$key} set" );
 146         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
 147         is( $warning,  <<WARNING,   '  got deprecation warning' );
 148 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 76.
 149 WARNING
 150
 151         chdir($Cwd);
 152     }
 153 }
 154
 155 my %Saved_Env = ();
 156 sub clean_env {
 157     foreach my $env (@magic_envs) {
 158         $Saved_Env{$env} = $ENV{$env};
 159
 160         # Can't actually delete SYS$ stuff on VMS.
 161         next if $IsVMS && $env eq 'SYS$LOGIN';
 162         next if $IsVMS && $env eq 'HOME' && !$Config{'d_setenv'};
 163
 164         unless ($IsMacOS) { # ENV on MacOS is "special" :-)
 165             # On VMS, %ENV is many layered.
 166             delete $ENV{$env} while exists $ENV{$env};
 167         }
 168     }
 169
 170     # The following means we won't really be testing for non-existence,
 171     # but in Perl we can only delete from the process table, not the job
 172     # table.
 173     $ENV{'SYS$LOGIN'} = '' if $IsVMS;
 174 }
 175
 176 END {
 177     no warnings 'uninitialized';
 178
 179     # Restore the environment for VMS (and doesn't hurt for anyone else)
 180     @ENV{@magic_envs} = @Saved_Env{@magic_envs};
 181
 182     # On VMS this must be deleted or process table is wrong on exit
 183     # when this script is run interactively.
 184     delete $ENV{'SYS$LOGIN'} if $IsVMS;
 185 }
 186
 187
 188 foreach my $key (@magic_envs) {
 189     # We're going to be using undefs a lot here.
 190     no warnings 'uninitialized';
 191
 192     clean_env;
 193     $ENV{$key} = catdir $Cwd, ($IsVMS ? 'OP' : 'op');
 194
 195     check_env($key);
 196 }
 197
 198 {
 199     clean_env;
 200     if (($IsVMS || $IsMacOS) && !$Config{'d_setenv'}) {
 201         pass("Can't reset HOME, so chdir() test meaningless");
 202     } else {
 203         ok( !chdir(),                   'chdir() w/o any ENV set' );
 204     }
 205     is( abs_path, $Cwd,             '  abs_path() agrees' );
 206 }