t/op/chdir.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     # We're not going to chdir() into 't' because we don't know if
   5     # chdir() works!  Instead, we'll hedge our bets and put both
   6     # possibilities into @INC.
   7     @INC = qw(t . lib ../lib);
   8 }
   9
  10 use Config;
  11 require "test.pl";
  12 plan(tests => 31);
  13
  14 my $IsVMS = $^O eq 'VMS';
  15
  16 my ($saved_sys_login);
  17 BEGIN {
  18     $saved_sys_login = $ENV{'SYS$LOGIN'} if $^O eq 'VMS'
  19 }
  20 END {
  21     $ENV{'SYS$LOGIN'} = $saved_sys_login if $^O eq 'VMS';
  22 }
  23
  24 # Might be a little early in the testing process to start using these,
  25 # but I can't think of a way to write this test without them.
  26 use File::Spec::Functions qw(:DEFAULT splitdir rel2abs splitpath);
  27
  28 # Can't use Cwd::abs_path() because it has different ideas about
  29 # path separators than File::Spec.
  30 sub abs_path {
  31     $IsVMS ? uc(rel2abs(curdir)) : rel2abs(curdir);
  32 }
  33
  34 my $Cwd = abs_path;
  35
  36 # Let's get to a known position
  37 SKIP: {
  38     my ($vol,$dir) = splitpath(abs_path,1);
  39     skip("Already in t/", 2) if (splitdir($dir))[-1] eq ($IsVMS ? 'T' : 't');
  40
  41     ok( chdir('t'),     'chdir("t")');
  42     is( abs_path, catdir($Cwd, 't'),       '  abs_path() agrees' );
  43 }
  44
  45 $Cwd = abs_path;
  46
  47 # The environment variables chdir() pays attention to.
  48 my @magic_envs = qw(HOME LOGDIR SYS$LOGIN);
  49
  50 sub check_env {
  51     my($key) = @_;
  52
  53     # Make sure $ENV{'SYS$LOGIN'} is only honored on VMS.
  54     if( $key eq 'SYS$LOGIN' && !$IsVMS ) {
  55         ok( !chdir(),         "chdir() on $^O ignores only \$ENV{$key} set" );
  56         is( abs_path, $Cwd,   '  abs_path() did not change' );
  57         pass( "  no need to test SYS\$LOGIN on $^O" ) for 1..7;
  58     }
  59     else {
  60         ok( chdir(),              "chdir() w/ only \$ENV{$key} set" );
  61         is( abs_path, $ENV{$key}, '  abs_path() agrees' );
  62         chdir($Cwd);
  63         is( abs_path, $Cwd,       '  and back again' );
  64
  65         my $warning = '';
  66         local $SIG{__WARN__} = sub { $warning .= join '', @_ };
  67
  68
  69         # Check the deprecated chdir(undef) feature.
  70 #line 60
  71         ok( chdir(undef),           "chdir(undef) w/ only \$ENV{$key} set" );
  72         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
  73         is( $warning,  <<WARNING,   '  got uninit & deprecation warning' );
  74 Use of uninitialized value in chdir at $0 line 60.
  75 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 60.
  76 WARNING
  77
  78         chdir($Cwd);
  79
  80         # Ditto chdir('').
  81         $warning = '';
  82 #line 72
  83         ok( chdir(''),              "chdir('') w/ only \$ENV{$key} set" );
  84         is( abs_path, $ENV{$key},   '  abs_path() agrees' );
  85         is( $warning,  <<WARNING,   '  got deprecation warning' );
  86 Use of chdir('') or chdir(undef) as chdir() is deprecated at $0 line 72.
  87 WARNING
  88
  89         chdir($Cwd);
  90     }
  91 }
  92
  93 sub clean_env {
  94     foreach (@magic_envs) {
  95         delete $ENV{$_} unless $IsVMS && $_ eq 'HOME' && !$Config{'d_setenv'};
  96     }
  97     # The following means we won't really be testing for non-existence,
  98     # but in Perl we can only delete from the process table, not the job
  99     # table.
 100     $ENV{'SYS$LOGIN'} = '' if $IsVMS;
 101 }
 102
 103 foreach my $key (@magic_envs) {
 104     # We're going to be using undefs a lot here.
 105     no warnings 'uninitialized';
 106
 107     clean_env;
 108     $ENV{$key} = catdir $Cwd, ($IsVMS ? 'OP' : 'op');
 109
 110     check_env($key);
 111 }
 112
 113 {
 114     clean_env;
 115     if ($IsVMS && !$Config{'d_setenv'}) {
 116         pass("Can't reset HOME, so chdir() test meaningless");
 117     } else {
 118         ok( !chdir(),                   'chdir() w/o any ENV set' );
 119     }
 120     is( abs_path, $Cwd,             '  abs_path() agrees' );
 121 }