t/log.t

   1 use strict;
   2 use warnings;
   3
   4 use Log::Contextual qw{:log with_logger set_logger};
   5 use Log::Contextual::SimpleLogger;
   6 use Test::More qw(no_plan);
   7
   8 my @levels = qw(debug trace warn info error fatal);
   9
  10 my $var1;
  11 my $var2;
  12 my $var3;
  13 my $var_logger1 = Log::Contextual::SimpleLogger->new({
  14    levels  => [qw(trace debug info warn error fatal)],
  15    coderef => sub { $var1 = shift },
  16 });
  17
  18 my $var_logger2 = Log::Contextual::SimpleLogger->new({
  19    levels  => [qw(trace debug info warn error fatal)],
  20    coderef => sub { $var2 = shift },
  21 });
  22
  23 my $var_logger3 = Log::Contextual::SimpleLogger->new({
  24    levels  => [qw(trace debug info warn error fatal)],
  25    coderef => sub { $var3 = shift },
  26 });
  27
  28 SETLOGGER: {
  29    set_logger(sub { $var_logger3 });
  30    log_debug { 'set_logger' };
  31    is( $var3, "[debug] set_logger\n", 'set logger works' );
  32 }
  33
  34 SETLOGGERTWICE: {
  35    my $foo;
  36    local $SIG{__WARN__} = sub { $foo = shift };
  37    set_logger(sub { $var_logger3 });
  38    like(
  39       $foo, qr/set_logger \(or -logger\) called more than once!  This is a bad idea! at/,
  40       'set_logger twice warns correctly'
  41    );
  42 }
  43
  44 WITHLOGGER: {
  45    with_logger sub { $var_logger2 } => sub {
  46
  47       with_logger $var_logger1 => sub {
  48          log_debug { 'nothing!' }
  49       };
  50       log_debug { 'frew!' };
  51
  52    };
  53
  54    is( $var1, "[debug] nothing!\n", 'inner scoped logger works' );
  55    is( $var2, "[debug] frew!\n", 'outer scoped logger works' );
  56 }
  57
  58 SETWITHLOGGER: {
  59    with_logger $var_logger1 => sub {
  60       log_debug { 'nothing again!' };
  61       # do this just so the following set_logger won't warn
  62       local $SIG{__WARN__} = sub {};
  63       set_logger(sub { $var_logger3 });
  64       log_debug { 'this is a set inside a with' };
  65    };
  66
  67    is( $var1, "[debug] nothing again!\n",
  68       'inner scoped logger works after using set_logger'
  69    );
  70
  71    is( $var3, "[debug] this is a set inside a with\n",
  72       'set inside with works'
  73    );
  74
  75    log_debug { 'frioux!' };
  76    is( $var3, "[debug] frioux!\n",
  77       q{set_logger's logger comes back after scoped logger}
  78    );
  79 }
  80
  81 VANILLA: {
  82    for (@levels) {
  83       main->can("log_$_")->(sub { 'fiSMBoC' });
  84       is( $var3, "[$_] fiSMBoC\n", "$_ works");
  85
  86       my @vars = main->can("log_$_")->(sub { 'fiSMBoC: ' . $_[1] }, qw{foo bar baz});
  87       is( $var3, "[$_] fiSMBoC: bar\n", "log_$_ works with input");
  88       ok( eq_array(\@vars, [qw{foo bar baz}]), "log_$_ passes data through correctly");
  89
  90       my $val = main->can("logS_$_")->(sub { 'fiSMBoC: ' . $_[0] }, 'foo');
  91       is( $var3, "[$_] fiSMBoC: foo\n", "logS_$_ works with input");
  92       is( $val, 'foo', "logS_$_ passes data through correctly");
  93    }
  94 }
  95
  96 ok(!eval { Log::Contextual->import; 1 }, 'Blank Log::Contextual import dies');
  97