t/lib/syslfs.t

   1 # NOTE: this file tests how large files (>2GB) work with raw system IO.
   2 # stdio: open(), tell(), seek(), print(), read() is tested in t/op/lfs.t.
   3 # If you modify/add tests here, remember to update also t/op/lfs.t.
   4
   5 BEGIN {
   6         chdir 't' if -d 't';
   7         @INC = '../lib';
   8         require Config; import Config;
   9         # Don't bother if there are no quad offsets.
  10         if ($Config{lseeksize} < 8) {
  11                 print "1..0 # Skip: no 64-bit file offsets\n";
  12                 exit(0);
  13         }
  14         require Fcntl; import Fcntl qw(/^O_/ /^SEEK_/);
  15 }
  16
  17 use strict;
  18
  19 our @s;
  20 our $fail;
  21
  22 sub zap {
  23     close(BIG);
  24     unlink("big");
  25     unlink("big1");
  26     unlink("big2");
  27 }
  28
  29 sub bye {
  30     zap();
  31     exit(0);
  32 }
  33
  34 my $explained;
  35
  36 sub explain {
  37     unless ($explained++) {
  38         print <<EOM;
  39 #
  40 # If the lfs (large file support: large meaning larger than two
  41 # gigabytes) tests are skipped or fail, it may mean either that your
  42 # process (or process group) is not allowed to write large files
  43 # (resource limits) or that the file system (the network filesystem?)
  44 # you are running the tests on doesn't let your user/group have large
  45 # files (quota) or the filesystem simply doesn't support large files.
  46 # You may even need to reconfigure your kernel.  (This is all very
  47 # operating system and site-dependent.)
  48 #
  49 # Perl may still be able to support large files, once you have
  50 # such a process, enough quota, and such a (file) system.
  51 # It is just that the test failed now.
  52 #
  53 EOM
  54     }
  55     print "1..0 # Skip: @_\n" if @_;
  56 }
  57
  58 print "# checking whether we have sparse files...\n";
  59
  60 # Known have-nots.
  61 if ($^O eq 'MSWin32' || $^O eq 'VMS') {
  62     print "1..0 # Skip: no sparse files in $^O\n";
  63     bye();
  64 }
  65
  66 # Known haves that have problems running this test
  67 # (for example because they do not support sparse files, like UNICOS)
  68 if ($^O eq 'unicos') {
  69     print "1..0 # Skip: no sparse files in $^0, unable to test large files\n";
  70     bye();
  71 }
  72
  73 # Then try heuristically to deduce whether we have sparse files.
  74
  75 # We'll start off by creating a one megabyte file which has
  76 # only three "true" bytes.  If we have sparseness, we should
  77 # consume less blocks than one megabyte (assuming nobody has
  78 # one megabyte blocks...)
  79
  80 sysopen(BIG, "big1", O_WRONLY|O_CREAT|O_TRUNC) or
  81     do { warn "sysopen big1 failed: $!\n"; bye };
  82 sysseek(BIG, 1_000_000, SEEK_SET) or
  83     do { warn "sysseek big1 failed: $!\n"; bye };
  84 syswrite(BIG, "big") or
  85     do { warn "syswrite big1 failed; $!\n"; bye };
  86 close(BIG) or
  87     do { warn "close big1 failed: $!\n"; bye };
  88
  89 my @s1 = stat("big1");
  90
  91 print "# s1 = @s1\n";
  92
  93 sysopen(BIG, "big2", O_WRONLY|O_CREAT|O_TRUNC) or
  94     do { warn "sysopen big2 failed: $!\n"; bye };
  95 sysseek(BIG, 2_000_000, SEEK_SET) or
  96     do { warn "sysseek big2 failed: $!\n"; bye };
  97 syswrite(BIG, "big") or
  98     do { warn "syswrite big2 failed; $!\n"; bye };
  99 close(BIG) or
 100     do { warn "close big2 failed: $!\n"; bye };
 101
 102 my @s2 = stat("big2");
 103
 104 print "# s2 = @s2\n";
 105
 106 zap();
 107
 108 unless ($s1[7] == 1_000_003 && $s2[7] == 2_000_003 &&
 109         $s1[11] == $s2[11] && $s1[12] == $s2[12]) {
 110         print "1..0 # Skip: no sparse files?\n";
 111         bye;
 112 }
 113
 114 print "# we seem to have sparse files...\n";
 115
 116 # By now we better be sure that we do have sparse files:
 117 # if we are not, the following will hog 5 gigabytes of disk.  Ooops.
 118 # This may fail by producing some signal; run in a subprocess first for safety
 119
 120 $ENV{LC_ALL} = "C";
 121
 122 my $r = system '../perl', '-I../lib', '-e', <<'EOF';
 123 use Fcntl qw(/^O_/ /^SEEK_/);
 124 sysopen(BIG, "big", O_WRONLY|O_CREAT|O_TRUNC) or die $!;
 125 my $sysseek = sysseek(BIG, 5_000_000_000, SEEK_SET);
 126 my $syswrite = syswrite(BIG, "big");
 127 exit 0;
 128 EOF
 129
 130 sysopen(BIG, "big", O_WRONLY|O_CREAT|O_TRUNC) or
 131         do { warn "sysopen 'big' failed: $!\n"; bye };
 132 my $sysseek = sysseek(BIG, 5_000_000_000, SEEK_SET);
 133 unless (! $r && defined $sysseek && $sysseek == 5_000_000_000) {
 134     $sysseek = 'undef' unless defined $sysseek;
 135     explain("seeking past 2GB failed: ",
 136             $r ? 'signal '.($r & 0x7f) : "$! (sysseek returned $sysseek)");
 137     bye();
 138 }
 139
 140 # The syswrite will fail if there are are filesize limitations (process or fs).
 141 my $syswrite = syswrite(BIG, "big");
 142 print "# syswrite failed: $! (syswrite returned ",
 143       defined $syswrite ? $syswrite : 'undef', ")\n"
 144     unless defined $syswrite && $syswrite == 3;
 145 my $close     = close BIG;
 146 print "# close failed: $!\n" unless $close;
 147 unless($syswrite && $close) {
 148     if ($! =~/too large/i) {
 149         explain("writing past 2GB failed: process limits?");
 150     } elsif ($! =~ /quota/i) {
 151         explain("filesystem quota limits?");
 152     } else {
 153         explain("error: $!");
 154     }
 155     bye();
 156 }
 157
 158 @s = stat("big");
 159
 160 print "# @s\n";
 161
 162 unless ($s[7] == 5_000_000_003) {
 163     explain("kernel/fs not configured to use large files?");
 164     bye();
 165 }
 166
 167 sub fail () {
 168     print "not ";
 169     $fail++;
 170 }
 171
 172 sub offset ($$) {
 173     my ($offset_will_be, $offset_want) = @_;
 174     my $offset_is = eval $offset_will_be;
 175     unless ($offset_is == $offset_want) {
 176         print "# bad offset $offset_is, want $offset_want\n";
 177         my ($offset_func) = ($offset_will_be =~ /^(\w+)/);
 178         if (unpack("L", pack("L", $offset_want)) == $offset_is) {
 179             print "# 32-bit wraparound suspected in $offset_func() since\n";
 180             print "# $offset_want cast into 32 bits equals $offset_is.\n";
 181         } elsif ($offset_want - unpack("L", pack("L", $offset_want)) - 1
 182                  == $offset_is) {
 183             print "# 32-bit wraparound suspected in $offset_func() since\n";
 184             printf "# %s - unpack('L', pack('L', %s)) - 1 equals %s.\n",
 185                 $offset_want,
 186                 $offset_want,
 187                 $offset_is;
 188         }
 189         fail;
 190     }
 191 }
 192
 193 print "1..17\n";
 194
 195 $fail = 0;
 196
 197 fail unless $s[7] == 5_000_000_003;     # exercizes pp_stat
 198 print "ok 1\n";
 199
 200 fail unless -s "big" == 5_000_000_003;  # exercizes pp_ftsize
 201 print "ok 2\n";
 202
 203 fail unless -e "big";
 204 print "ok 3\n";
 205
 206 fail unless -f "big";
 207 print "ok 4\n";
 208
 209 sysopen(BIG, "big", O_RDONLY) or do { warn "sysopen failed: $!\n"; bye };
 210
 211 offset('sysseek(BIG, 4_500_000_000, SEEK_SET)', 4_500_000_000);
 212 print "ok 5\n";
 213
 214 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_000);
 215 print "ok 6\n";
 216
 217 offset('sysseek(BIG, 1, SEEK_CUR)', 4_500_000_001);
 218 print "ok 7\n";
 219
 220 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_001);
 221 print "ok 8\n";
 222
 223 offset('sysseek(BIG, -1, SEEK_CUR)', 4_500_000_000);
 224 print "ok 9\n";
 225
 226 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_000);
 227 print "ok 10\n";
 228
 229 offset('sysseek(BIG, -3, SEEK_END)', 5_000_000_000);
 230 print "ok 11\n";
 231
 232 offset('sysseek(BIG, 0, SEEK_CUR)', 5_000_000_000);
 233 print "ok 12\n";
 234
 235 my $big;
 236
 237 fail unless sysread(BIG, $big, 3) == 3;
 238 print "ok 13\n";
 239
 240 fail unless $big eq "big";
 241 print "ok 14\n";
 242
 243 # 705_032_704 = (I32)5_000_000_000
 244 # See that we don't have "big" in the 705_... spot:
 245 # that would mean that we have a wraparound.
 246 fail unless sysseek(BIG, 705_032_704, SEEK_SET);
 247 print "ok 15\n";
 248
 249 my $zero;
 250
 251 fail unless read(BIG, $zero, 3) == 3;
 252 print "ok 16\n";
 253
 254 fail unless $zero eq "\0\0\0";
 255 print "ok 17\n";
 256
 257 explain() if $fail;
 258
 259 bye(); # does the necessary cleanup
 260
 261 END {
 262    unlink "big"; # be paranoid about leaving 5 gig files lying around
 263 }
 264
 265 # eof