t/lib/st-06compat.t

   1 #!./perl
   2
   3 # $Id: compat-0.6.t,v 1.0 2000/09/01 19:40:41 ram Exp $
   4 #
   5 #  Copyright (c) 1995-2000, Raphael Manfredi
   6 #
   7 #  You may redistribute only under the same terms as Perl 5, as specified
   8 #  in the README file that comes with the distribution.
   9 #
  10 # $Log: compat-0.6.t,v $
  11 # Revision 1.0  2000/09/01 19:40:41  ram
  12 # Baseline for first official release.
  13 #
  14
  15 BEGIN {
  16     chdir('t') if -d 't';
  17     @INC = '.';
  18     push @INC, '../lib';
  19     require Config; import Config;
  20     if ($Config{'extensions'} !~ /\bStorable\b/) {
  21         print "1..0 # Skip: Storable was not built\n";
  22         exit 0;
  23     }
  24     require 'lib/st-dump.pl';
  25 }
  26
  27 sub ok;
  28
  29 print "1..8\n";
  30
  31 use Storable qw(freeze nfreeze thaw);
  32
  33 package TIED_HASH;
  34
  35 sub TIEHASH {
  36         my $self = bless {}, shift;
  37         return $self;
  38 }
  39
  40 sub FETCH {
  41         my $self = shift;
  42         my ($key) = @_;
  43         $main::hash_fetch++;
  44         return $self->{$key};
  45 }
  46
  47 sub STORE {
  48         my $self = shift;
  49         my ($key, $val) = @_;
  50         $self->{$key} = $val;
  51 }
  52
  53 package SIMPLE;
  54
  55 sub make {
  56         my $self = bless [], shift;
  57         my ($x) = @_;
  58         $self->[0] = $x;
  59         return $self;
  60 }
  61
  62 package ROOT;
  63
  64 sub make {
  65         my $self = bless {}, shift;
  66         my $h = tie %hash, TIED_HASH;
  67         $self->{h} = $h;
  68         $self->{ref} = \%hash;
  69         my @pool;
  70         for (my $i = 0; $i < 5; $i++) {
  71                 push(@pool, SIMPLE->make($i));
  72         }
  73         $self->{obj} = \@pool;
  74         my @a = ('string', $h, $self);
  75         $self->{a} = \@a;
  76         $self->{num} = [1, 0, -3, -3.14159, 456, 4.5];
  77         $h->{key1} = 'val1';
  78         $h->{key2} = 'val2';
  79         return $self;
  80 };
  81
  82 sub num { $_[0]->{num} }
  83 sub h   { $_[0]->{h} }
  84 sub ref { $_[0]->{ref} }
  85 sub obj { $_[0]->{obj} }
  86
  87 package main;
  88
  89 my $Is_EBCDIC = (ord('A') == 193) ? 1 : 0;
  90
  91 my $r = ROOT->make;
  92
  93 my $data = '';
  94 if (!$Is_EBCDIC) {
  95         while (<DATA>) {
  96             next if /^#/;
  97             $data .= unpack("u", $_);
  98         }
  99 }
 100 else {
 101         while (<DATA>) {
 102             next if /^#$/;    # skip comments
 103             next if /^#\s+/;  # skip comments
 104             next if /^[^#]/;  # skip uuencoding for ASCII machines
 105             s/^#//;           # prepare uuencoded data for EBCDIC machines
 106             $data .= unpack("u", $_);
 107         }
 108 }
 109
 110 my $expected_length = $Is_EBCDIC ? 217 : 278;
 111 ok 1, length $data == $expected_length;
 112
 113 my $y = thaw($data);
 114 ok 2, 1;
 115 ok 3, ref $y eq 'ROOT';
 116
 117 $Storable::canonical = 1;               # Prevent "used once" warning
 118 $Storable::canonical = 1;
 119 # Allow for long double string conversions.
 120 $y->{num}->[3] += 0;
 121 $r->{num}->[3] += 0;
 122 ok 4, nfreeze($y) eq nfreeze($r);
 123
 124 ok 5, $y->ref->{key1} eq 'val1';
 125 ok 6, $y->ref->{key2} eq 'val2';
 126 ok 7, $hash_fetch == 2;
 127
 128 my $num = $r->num;
 129 my $ok = 1;
 130 for (my $i = 0; $i < @$num; $i++) {
 131         do { $ok = 0; last } unless $num->[$i] == $y->num->[$i];
 132 }
 133 ok 8, $ok;
 134
 135 __END__
 136 #
 137 # using Storable-0.6@11, output of: print pack("u", nfreeze(ROOT->make));
 138 # original size: 278 bytes
 139 #
 140 M`P,````%!`(````&"(%8"(!8"'U8"@@M,RXQ-#$U.5@)```!R%@*`S0N-5A8
 141 M6`````-N=6T$`P````(*!'9A;#%8````!&ME>3$*!'9A;#)8````!&ME>3)B
 142 M"51)141?2$%32%A8`````6@$`@````,*!G-T<FEN9U@$``````I8!```````
 143 M6%A8`````6$$`@````4$`@````$(@%AB!E-)35!,15A8!`(````!"(%88@93
 144 M24U03$586`0"`````0B"6&(&4TE-4$Q%6%@$`@````$(@UAB!E-)35!,15A8
 145 M!`(````!"(188@9324U03$586%A8`````V]B:@0,!``````*6%A8`````W)E
 146 (9F($4D]/5%@`
 147 #
 148 # using Storable-0.6@11, output of: print '#' . pack("u", nfreeze(ROOT->make));
 149 # on OS/390 (cp 1047) original size: 217 bytes
 150 #
 151 #M!0,1!-G6UN,#````!00,!!$)X\G%Q&W(P>+(`P````(*!*6!D_$````$DH6H
 152 #M\0H$I8&3\@````22A:CR`````YF%A@0"````!@B!"(`(?0H(8/-+\?3Q]?D)
 153 #M```!R`H#]$OU`````Y6DE`0"````!001!N+)U-?3Q0(````!"(`$$@("````
 154 #M`0B!!!("`@````$(@@02`@(````!"(,$$@("`````0B$`````Y:"D00`````
 155 #E!`````&(!`(````#"@:BHYF)E8<$``````0$```````````!@0``