t/lib/filefind.t

   1 ####!./perl
   2
   3
   4 my %Expect;
   5 my $symlink_exists = eval { symlink("",""); 1 };
   6
   7 BEGIN {
   8     chdir 't' if -d 't';
   9     unshift @INC, '../lib';
  10 }
  11
  12 if ( $symlink_exists ) { print "1..59\n"; }
  13 else                   { print "1..34\n"; }
  14
  15 use File::Find;
  16
  17 find(sub { print "ok 1\n" if $_ eq 'filefind.t'; }, ".");
  18 finddepth(sub { print "ok 2\n" if $_ eq 'filefind.t'; }, ".");
  19
  20
  21 my $case = 2;
  22
  23 END {
  24     unlink 'FA/FA_ord','FA/FSL','FA/FAA/FAA_ord',
  25            'FA/FAB/FAB_ord','FA/FAB/FABA/FABA_ord','FB/FB_ord','FB/FBA/FBA_ord';
  26     rmdir 'FA/FAA';
  27     rmdir 'FA/FAB/FABA';
  28     rmdir 'FA/FAB';
  29     rmdir 'FA';
  30     rmdir 'FB/FBA';
  31     rmdir 'FB';
  32 }
  33
  34 sub Check($) {
  35   $case++;
  36   if ($_[0]) { print "ok $case\n"; }
  37   else       { print "not ok $case\n"; }
  38 }
  39
  40 sub CheckDie($) {
  41   $case++;
  42   if ($_[0]) { print "ok $case\n"; }
  43   else { print "not ok $case\n $!\n"; exit 0; }
  44 }
  45
  46 sub touch {
  47   CheckDie( open(my $T,'>',$_[0]) );
  48 }
  49
  50 sub MkDir($$) {
  51   CheckDie( mkdir($_[0],$_[1]) );
  52 }
  53
  54 sub wanted {
  55 #  print "'$_' => 1, ";
  56   Check( $Expect{$_} );
  57   delete $Expect{$_};
  58   $File::Find::prune=1 if  $_ eq 'FABA';
  59 }
  60
  61 MkDir( 'FA',0770 );
  62 MkDir( 'FB',0770  );
  63 touch('FB/FB_ord');
  64 MkDir( 'FB/FBA',0770  );
  65 touch('FB/FBA/FBA_ord');
  66 CheckDie( symlink('../FB','FA/FSL') ) if $symlink_exists;
  67 touch('FA/FA_ord');
  68
  69 MkDir( 'FA/FAA',0770  );
  70 touch('FA/FAA/FAA_ord');
  71 MkDir( 'FA/FAB',0770  );
  72 touch('FA/FAB/FAB_ord');
  73 MkDir( 'FA/FAB/FABA',0770  );
  74 touch('FA/FAB/FABA/FABA_ord');
  75
  76 %Expect=('.' => 1, 'FSL' => 1, 'FA_ord' => 1, 'FAB' => 1, 'FAB_ord' => 1, 'FABA' => 1,
  77          'FAA' => 1, 'FAA_ord' => 1);
  78
  79 File::Find::find( {wanted => \&wanted, },'FA' );
  80 Check( scalar(keys %Expect) == 0 );
  81
  82 %Expect=('FA' => 1, 'FA/FSL' => 1, 'FA/FA_ord' => 1, 'FA/FAB' => 1, 'FA/FAB/FAB_ord' => 1,
  83          'FA/FAB/FABA' => 1, 'FA/FAB/FABA/FABA_ord' => 1, 'FA/FAA' => 1, 'FA/FAA/FAA_ord' => 1);
  84 File::Find::find( {wanted => \&wanted, no_chdir => 1},'FA' );
  85
  86 Check( scalar(keys %Expect) == 0 );
  87
  88 if ( $symlink_exists ) {
  89   %Expect=('.' => 1, 'FA_ord' => 1, 'FSL' => 1, 'FB_ord' => 1, 'FBA' => 1,
  90            'FBA_ord' => 1, 'FAB' => 1, 'FAB_ord' => 1, 'FABA' => 1, 'FAA' => 1,
  91            'FAA_ord' => 1);
  92
  93   File::Find::find( {wanted => \&wanted, follow_fast => 1},'FA' );
  94   Check( scalar(keys %Expect) == 0 );
  95   %Expect=('FA' => 1, 'FA/FA_ord' => 1, 'FA/FSL' => 1, 'FA/FSL/FB_ord' => 1,
  96            'FA/FSL/FBA' => 1, 'FA/FSL/FBA/FBA_ord' => 1, 'FA/FAB' => 1,
  97            'FA/FAB/FAB_ord' => 1, 'FA/FAB/FABA' => 1, 'FA/FAB/FABA/FABA_ord' => 1,
  98            'FA/FAA' => 1, 'FA/FAA/FAA_ord' => 1);
  99   File::Find::find( {wanted => \&wanted, follow_fast => 1, no_chdir => 1},'FA' );
 100   Check( scalar(keys %Expect) == 0 );
 101 }
 102
 103 print "# of cases: $case\n";