t/lib/extutils.t

   1 #!./perl -w
   2
   3 print "1..26\n";
   4
   5 BEGIN {
   6     chdir 't' if -d 't';
   7     @INC = '../lib';
   8 }
   9
  10 use warnings;
  11 use strict;
  12 use ExtUtils::MakeMaker;
  13 use ExtUtils::Constant qw (constant_types C_constant XS_constant autoload);
  14 use Config;
  15 use File::Spec::Functions;
  16 use File::Spec;
  17 # Because were are going to be changing directory before running Makefile.PL
  18 my $perl = File::Spec->rel2abs( $^X );
  19 # ExtUtils::Constant::C_constant uses $^X inside a comment, and we want to
  20 # compare output to ensure that it is the same. We were probably run as ./perl
  21 # whereas we will run the child with the full path in $perl. So make $^X for
  22 # us the same as our child will see.
  23 $^X = $perl;
  24
  25 print "# perl=$perl\n";
  26 my $runperl = "$perl -x \"-I../../lib\"";
  27
  28 $| = 1;
  29
  30 my $dir = "ext-$$";
  31 my @files;
  32
  33 print "# $dir being created...\n";
  34 mkdir $dir, 0777 or die "mkdir: $!\n";
  35
  36
  37 END {
  38     use File::Path;
  39     print "# $dir being removed...\n";
  40     rmtree($dir);
  41 }
  42
  43 my $package = "ExtTest";
  44
  45 # Test the code that generates 1 and 2 letter name comparisons.
  46 my %compass = (
  47 N => 0, NE => 45, E => 90, SE => 135, S => 180, SW => 225, W => 270, NW => 315
  48 );
  49
  50 my $parent_rfc1149 =
  51   'A Standard for the Transmission of IP Datagrams on Avian Carriers';
  52
  53 my @names = ("FIVE", {name=>"OK6", type=>"PV",},
  54              {name=>"OK7", type=>"PVN",
  55               value=>['"not ok 7\\n\\0ok 7\\n"', 15]},
  56              {name => "FARTHING", type=>"NV"},
  57              {name => "NOT_ZERO", type=>"UV", value=>"~(UV)0"},
  58              {name => "OPEN", type=>"PV", value=>'"/*"',
  59               macro=>["#if 1\n", "#endif\n"]},
  60              {name => "CLOSE", type=>"PV", value=>'"*/"',
  61               macro=>["#if 1\n", "#endif\n"]},
  62              {name => "ANSWER", default=>["UV", 42]}, "NOTDEF",
  63              {name => "Yes", type=>"YES"},
  64              {name => "No", type=>"NO"},
  65              {name => "Undef", type=>"UNDEF"},
  66 # OK. It wasn't really designed to allow the creation of dual valued constants.
  67 # It was more for INADDR_ANY INADDR_BROADCAST INADDR_LOOPBACK INADDR_NONE
  68              {name=>"RFC1149", type=>"SV", value=>"sv_2mortal(temp_sv)",
  69               pre=>"SV *temp_sv = newSVpv(RFC1149, 0); "
  70                    . "(void) SvUPGRADE(temp_sv,SVt_PVIV); SvIOK_on(temp_sv); "
  71                    . "SvIVX(temp_sv) = 1149;"},
  72 );
  73
  74 push @names, $_ foreach keys %compass;
  75
  76 my @names_only = map {(ref $_) ? $_->{name} : $_} @names;
  77
  78 my $types = {};
  79 my $constant_types = constant_types(); # macro defs
  80 my $C_constant = join "\n",
  81   C_constant ($package, undef, "IV", $types, undef, undef, @names);
  82 my $XS_constant = XS_constant ($package, $types); # XS for ExtTest::constant
  83
  84 ################ Header
  85 my $header = catfile($dir, "test.h");
  86 push @files, "test.h";
  87 open FH, ">$header" or die "open >$header: $!\n";
  88 print FH <<"EOT";
  89 #define FIVE 5
  90 #define OK6 "ok 6\n"
  91 #define OK7 1
  92 #define FARTHING 0.25
  93 #define NOT_ZERO 1
  94 #define Yes 0
  95 #define No 1
  96 #define Undef 1
  97 #define RFC1149 "$parent_rfc1149"
  98 #undef NOTDEF
  99
 100 EOT
 101
 102 while (my ($point, $bearing) = each %compass) {
 103   print FH "#define $point $bearing\n"
 104 }
 105 close FH or die "close $header: $!\n";
 106
 107 ################ XS
 108 my $xs = catfile($dir, "$package.xs");
 109 push @files, "$package.xs";
 110 open FH, ">$xs" or die "open >$xs: $!\n";
 111
 112 print FH <<'EOT';
 113 #include "EXTERN.h"
 114 #include "perl.h"
 115 #include "XSUB.h"
 116 EOT
 117
 118 print FH "#include \"test.h\"\n\n";
 119 print FH $constant_types;
 120 print FH $C_constant, "\n";
 121 print FH "MODULE = $package             PACKAGE = $package\n";
 122 print FH "PROTOTYPES: ENABLE\n";
 123 print FH $XS_constant;
 124 close FH or die "close $xs: $!\n";
 125
 126 ################ PM
 127 my $pm = catfile($dir, "$package.pm");
 128 push @files, "$package.pm";
 129 open FH, ">$pm" or die "open >$pm: $!\n";
 130 print FH "package $package;\n";
 131 print FH "use $];\n";
 132
 133 print FH <<'EOT';
 134
 135 use strict;
 136 use warnings;
 137 use Carp;
 138
 139 require Exporter;
 140 require DynaLoader;
 141 use vars qw ($VERSION @ISA @EXPORT_OK);
 142
 143 $VERSION = '0.01';
 144 @ISA = qw(Exporter DynaLoader);
 145 @EXPORT_OK = qw(
 146 EOT
 147
 148 print FH "\t$_\n" foreach (@names_only);
 149 print FH ");\n";
 150 print FH autoload ($package, $]);
 151 print FH "bootstrap $package \$VERSION;\n1;\n__END__\n";
 152 close FH or die "close $pm: $!\n";
 153
 154 ################ test.pl
 155 my $testpl = catfile($dir, "test.pl");
 156 push @files, "test.pl";
 157 open FH, ">$testpl" or die "open >$testpl: $!\n";
 158
 159 print FH "use strict;\n";
 160 print FH "use $package qw(@names_only);\n";
 161 print FH <<'EOT';
 162
 163 # IV
 164 my $five = FIVE;
 165 if ($five == 5) {
 166   print "ok 5\n";
 167 } else {
 168   print "not ok 5 # $five\n";
 169 }
 170
 171 # PV
 172 print OK6;
 173
 174 # PVN containing embedded \0s
 175 $_ = OK7;
 176 s/.*\0//s;
 177 print;
 178
 179 # NV
 180 my $farthing = FARTHING;
 181 if ($farthing == 0.25) {
 182   print "ok 8\n";
 183 } else {
 184   print "not ok 8 # $farthing\n";
 185 }
 186
 187 # UV
 188 my $not_zero = NOT_ZERO;
 189 if ($not_zero > 0 && $not_zero == ~0) {
 190   print "ok 9\n";
 191 } else {
 192   print "not ok 9 # \$not_zero=$not_zero ~0=" . (~0) . "\n";
 193 }
 194
 195 # Value includes a "*/" in an attempt to bust out of a C comment.
 196 # Also tests custom cpp #if clauses
 197 my $close = CLOSE;
 198 if ($close eq '*/') {
 199   print "ok 10\n";
 200 } else {
 201   print "not ok 10 # \$close='$close'\n";
 202 }
 203
 204 # Default values if macro not defined.
 205 my $answer = ANSWER;
 206 if ($answer == 42) {
 207   print "ok 11\n";
 208 } else {
 209   print "not ok 11 # What do you get if you multiply six by nine? '$answer'\n";
 210 }
 211
 212 # not defined macro
 213 my $notdef = eval { NOTDEF; };
 214 if (defined $notdef) {
 215   print "not ok 12 # \$notdef='$notdef'\n";
 216 } elsif ($@ !~ /Your vendor has not defined ExtTest macro NOTDEF/) {
 217   print "not ok 12 # \$@='$@'\n";
 218 } else {
 219   print "ok 12\n";
 220 }
 221
 222 # not a macro
 223 my $notthere = eval { &ExtTest::NOTTHERE; };
 224 if (defined $notthere) {
 225   print "not ok 13 # \$notthere='$notthere'\n";
 226 } elsif ($@ !~ /NOTTHERE is not a valid ExtTest macro/) {
 227   chomp $@;
 228   print "not ok 13 # \$@='$@'\n";
 229 } else {
 230   print "ok 13\n";
 231 }
 232
 233 # Truth
 234 my $yes = Yes;
 235 if ($yes) {
 236   print "ok 14\n";
 237 } else {
 238   print "not ok 14 # $yes='\$yes'\n";
 239 }
 240
 241 # Falsehood
 242 my $no = No;
 243 if (defined $no and !$no) {
 244   print "ok 15\n";
 245 } else {
 246   print "not ok 15 # \$no=" . defined ($no) ? "'$no'\n" : "undef\n";
 247 }
 248
 249 # Undef
 250 my $undef = Undef;
 251 unless (defined $undef) {
 252   print "ok 16\n";
 253 } else {
 254   print "not ok 16 # \$undef='$undef'\n";
 255 }
 256
 257
 258 # invalid macro (chosen to look like a mix up between No and SW)
 259 $notdef = eval { &ExtTest::So };
 260 if (defined $notdef) {
 261   print "not ok 17 # \$notdef='$notdef'\n";
 262 } elsif ($@ !~ /^So is not a valid ExtTest macro/) {
 263   print "not ok 17 # \$@='$@'\n";
 264 } else {
 265   print "ok 17\n";
 266 }
 267
 268 # invalid defined macro
 269 $notdef = eval { &ExtTest::EW };
 270 if (defined $notdef) {
 271   print "not ok 18 # \$notdef='$notdef'\n";
 272 } elsif ($@ !~ /^EW is not a valid ExtTest macro/) {
 273   print "not ok 18 # \$@='$@'\n";
 274 } else {
 275   print "ok 18\n";
 276 }
 277
 278 my %compass = (
 279 EOT
 280
 281 while (my ($point, $bearing) = each %compass) {
 282   print FH "$point => $bearing, "
 283 }
 284
 285 print FH <<'EOT';
 286
 287 );
 288
 289 my $fail;
 290 while (my ($point, $bearing) = each %compass) {
 291   my $val = eval $point;
 292   if ($@) {
 293     print "# $point: \$@='$@'\n";
 294     $fail = 1;
 295   } elsif (!defined $bearing) {
 296     print "# $point: \$val=undef\n";
 297     $fail = 1;
 298   } elsif ($val != $bearing) {
 299     print "# $point: \$val=$val, not $bearing\n";
 300     $fail = 1;
 301   }
 302 }
 303 if ($fail) {
 304   print "not ok 19\n";
 305 } else {
 306   print "ok 19\n";
 307 }
 308
 309 EOT
 310
 311 print FH <<"EOT";
 312 my \$rfc1149 = RFC1149;
 313 if (\$rfc1149 ne "$parent_rfc1149") {
 314   print "not ok 20 # '\$rfc1149' ne '$parent_rfc1149'\n";
 315 } else {
 316   print "ok 20\n";
 317 }
 318
 319 if (\$rfc1149 != 1149) {
 320   printf "not ok 21 # %d != 1149\n", \$rfc1149;
 321 } else {
 322   print "ok 21\n";
 323 }
 324 EOT
 325 close FH or die "close $testpl: $!\n";
 326
 327 ################ Makefile.PL
 328 # We really need a Makefile.PL because make test for a no dynamic linking perl
 329 # will run Makefile.PL again as part of the "make perl" target.
 330 my $makefilePL = catfile($dir, "Makefile.PL");
 331 push @files, "Makefile.PL";
 332 open FH, ">$makefilePL" or die "open >$makefilePL: $!\n";
 333 print FH <<"EOT";
 334 #!$perl -w
 335 use ExtUtils::MakeMaker;
 336 WriteMakefile(
 337               'NAME'            => "$package",
 338               'VERSION_FROM'    => "$package.pm", # finds \$VERSION
 339               (\$] >= 5.005 ?
 340                (#ABSTRACT_FROM => "$package.pm", # XXX add this
 341                 AUTHOR     => "$0") : ())
 342              );
 343 EOT
 344
 345 close FH or die "close $makefilePL: $!\n";
 346
 347 chdir $dir or die $!; push @INC,  '../../lib';
 348 END {chdir ".." or warn $!};
 349
 350 my @perlout = `$runperl Makefile.PL`;
 351 if ($?) {
 352   print "not ok 1 # $runperl Makefile.PL failed: $?\n";
 353   print "# $_" foreach @perlout;
 354   exit($?);
 355 } else {
 356   print "ok 1\n";
 357 }
 358
 359
 360 my $makefile = ($^O eq 'VMS' ? 'descrip' : 'Makefile');
 361 my $makefile_ext = ($^O eq 'VMS' ? '.mms' : '');
 362 if (-f "$makefile$makefile_ext") {
 363   print "ok 2\n";
 364 } else {
 365   print "not ok 2\n";
 366 }
 367 my $makefile_rename = ($^O eq 'VMS' ? '.mms' : '.old');
 368 push @files, "$makefile$makefile_rename"; # Renamed by make clean
 369
 370 my $make = $Config{make};
 371
 372 $make = $ENV{MAKE} if exists $ENV{MAKE};
 373
 374 my $makeout;
 375
 376 print "# make = '$make'\n";
 377 $makeout = `$make`;
 378 if ($?) {
 379   print "not ok 3 # $make failed: $?\n";
 380   exit($?);
 381 } else {
 382   print "ok 3\n";
 383 }
 384
 385 if ($Config{usedl}) {
 386   print "ok 4\n";
 387 } else {
 388   push @files, "perl$Config{exe_ext}";
 389   my $makeperl = "$make perl";
 390   print "# make = '$makeperl'\n";
 391   $makeout = `$makeperl`;
 392   if ($?) {
 393     print "not ok 4 # $makeperl failed: $?\n";
 394     exit($?);
 395   } else {
 396     print "ok 4\n";
 397   }
 398 }
 399
 400 my $test = 22;
 401 my $maketest = "$make test";
 402 print "# make = '$maketest'\n";
 403 $makeout = `$maketest`;
 404
 405 # echo of running the test script
 406 $makeout =~ s/^\s*PERL_DL_NONLAZY=.+?\n//m;
 407 $makeout =~ s/^MCR.+test.pl\n//mig if $^O eq 'VMS';
 408
 409 # GNU make babblings
 410 $makeout =~ s/^\w*?make.+?(?:entering|leaving) directory.+?\n//mig;
 411
 412 # Hopefully gets most make's babblings
 413 # make -f Makefile.aperl perl
 414 $makeout =~ s/^\w*?make.+\sperl[^A-Za-z0-9]*\n//mig;
 415 # make[1]: `perl' is up to date.
 416 $makeout =~ s/^\w*?make.+perl.+?is up to date.*?\n//mig;
 417
 418 print $makeout;
 419
 420 if ($?) {
 421   print "not ok $test # $maketest failed: $?\n";
 422 } else {
 423   print "ok $test\n";
 424 }
 425 $test++;
 426
 427 my $regen = `$runperl $package.xs`;
 428 if ($?) {
 429   print "not ok $test # $runperl $package.xs failed: $?\n";
 430 } else {
 431   print "ok $test\n";
 432 }
 433 $test++;
 434
 435 my $expect = $constant_types . $C_constant .
 436   "\n#### XS Section:\n" . $XS_constant;
 437
 438 if ($expect eq $regen) {
 439   print "ok $test\n";
 440 } else {
 441   print "not ok $test\n";
 442   # open FOO, ">expect"; print FOO $expect;
 443   # open FOO, ">regen"; print FOO $regen; close FOO;
 444 }
 445 $test++;
 446
 447 my $makeclean = "$make clean";
 448 print "# make = '$makeclean'\n";
 449 $makeout = `$makeclean`;
 450 if ($?) {
 451   print "not ok $test # $make failed: $?\n";
 452 } else {
 453   print "ok $test\n";
 454 }
 455 $test++;
 456
 457 foreach (@files) {
 458   unlink $_ or warn "unlink $_: $!";
 459 }
 460
 461 my $fail;
 462 opendir DIR, "." or die "opendir '.': $!";
 463 while (defined (my $entry = readdir DIR)) {
 464   next if $entry =~ /^\.\.?$/;
 465   print "# Extra file '$entry'\n";
 466   $fail = 1;
 467 }
 468 closedir DIR or warn "closedir '.': $!";
 469 if ($fail) {
 470   print "not ok $test\n";
 471 } else {
 472   print "ok $test\n";
 473 }