Fix the failures in warnings tests when PERL_UNICODE is defined
[p5sagit/p5-mst-13.2.git] / t / lib / common.pl
1 # This code is used by lib/warnings.t and lib/feature.t
2
3 BEGIN {
4     require Config; import Config;
5     require './test.pl';
6 }
7
8 use File::Path;
9 use File::Spec::Functions;
10
11 use strict;
12 our $pragma_name;
13
14 $| = 1;
15
16 my $Is_MacOS   = $^O eq 'MacOS';
17 my $tmpfile = "tmp0000";
18 1 while -e ++$tmpfile;
19 END {  if ($tmpfile) { 1 while unlink $tmpfile} }
20
21 my @prgs = () ;
22 my @w_files = () ;
23
24 if (@ARGV)
25   { print "ARGV = [@ARGV]\n" ;
26     if ($^O eq 'MacOS') {
27       @w_files = map { s#^#:lib:$pragma_name:#; $_ } @ARGV
28     } else {
29       @w_files = map { s#^#./lib/$pragma_name/#; $_ } @ARGV
30     }
31   }
32 else
33   { @w_files = sort glob(catfile(curdir(), "lib", $pragma_name, "*")) }
34
35 my $files = 0;
36 foreach my $file (@w_files) {
37
38     next if $file =~ /(~|\.orig|,v)$/;
39     next if $file =~ /perlio$/ && !(find PerlIO::Layer 'perlio');
40     next if -d $file;
41
42     open F, "<$file" or die "Cannot open $file: $!\n" ;
43     my $line = 0;
44     while (<F>) {
45         $line++;
46         last if /^__END__/ ;
47     }
48
49     {
50         local $/ = undef;
51         $files++;
52         @prgs = (@prgs, $file, split "\n########\n", <F>) ;
53     }
54     close F ;
55 }
56
57 undef $/;
58
59 plan tests => (scalar(@prgs)-$files);
60
61 my $utf8_ok = exists $ENV{PERL_UNICODE} && $ENV{PERL_UNICODE} =~ m{^$|[Dio]} ? 1 : 0;
62
63 for (@prgs){
64     unless (/\n/)
65      {
66       print "# From $_\n";
67       next;
68      }
69     my $switch = "";
70     my @temps = () ;
71     my @temp_path = () ;
72     if (s/^\s*-\w+//){
73         $switch = $&;
74     }
75     my($prog,$expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
76     $expected =~ s{\b
77        UTF8 \s*
78            \? \s* '(.*?)'
79             : \s* '(.*?)'
80             }{$utf8_ok?$1:$2}gexs;
81
82     my ($todo, $todo_reason);
83     $todo = $prog =~ s/^#\s*TODO(.*)\n//m and $todo_reason = $1;
84     if ( $prog =~ /--FILE--/) {
85         my(@files) = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
86         shift @files ;
87         die "Internal error: test $_ didn't split into pairs, got " .
88                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
89             if @files % 2 ;
90         while (@files > 2) {
91             my $filename = shift @files ;
92             my $code = shift @files ;
93             push @temps, $filename ;
94             if ($filename =~ m#(.*)/#) {
95                 mkpath($1);
96                 push(@temp_path, $1);
97             }
98             open F, ">$filename" or die "Cannot open $filename: $!\n" ;
99             print F $code ;
100             close F or die "Cannot close $filename: $!\n";
101         }
102         shift @files ;
103         $prog = shift @files ;
104     }
105
106     # fix up some paths
107     if ($^O eq 'MacOS') {
108         $prog =~ s|require "./abc(d)?";|require ":abc$1";|g;
109         $prog =~ s|"\."|":"|g;
110     }
111
112     open TEST, ">$tmpfile" or die "Cannot open >$tmpfile: $!";
113     print TEST q{
114         BEGIN {
115             open(STDERR, ">&STDOUT")
116               or die "Can't dup STDOUT->STDERR: $!;";
117         }
118     };
119     print TEST "\n#line 1\n";  # So the line numbers don't get messed up.
120     print TEST $prog,"\n";
121     close TEST or die "Cannot close $tmpfile: $!";
122     my $results = runperl( switches => [$switch], stderr => 1, progfile => $tmpfile );
123     my $status = $?;
124     $results =~ s/\n+$//;
125     # allow expected output to be written as if $prog is on STDIN
126     $results =~ s/tmp\d+/-/g;
127     if ($^O eq 'VMS') {
128         # some tests will trigger VMS messages that won't be expected
129         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
130
131         # pipes double these sometimes
132         $results =~ s/\n\n/\n/g;
133     }
134 # bison says 'parse error' instead of 'syntax error',
135 # various yaccs may or may not capitalize 'syntax'.
136     $results =~ s/^(syntax|parse) error/syntax error/mig;
137     # allow all tests to run when there are leaks
138     $results =~ s/Scalars leaked: \d+\n//g;
139
140     # fix up some paths
141     if ($^O eq 'MacOS') {
142         $results =~ s|:abc\.pm\b|abc.pm|g;
143         $results =~ s|:abc(d)?\b|./abc$1|g;
144     }
145
146     $expected =~ s/\n+$//;
147     my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
148     # any special options? (OPTIONS foo bar zap)
149     my $option_regex = 0;
150     my $option_random = 0;
151     if ($expected =~ s/^OPTIONS? (.+)\n//) {
152         foreach my $option (split(' ', $1)) {
153             if ($option eq 'regex') { # allow regular expressions
154                 $option_regex = 1;
155             }
156             elsif ($option eq 'random') { # all lines match, but in any order
157                 $option_random = 1;
158             }
159             else {
160                 die "$0: Unknown OPTION '$option'\n";
161             }
162         }
163     }
164     die "$0: can't have OPTION regex and random\n"
165         if $option_regex + $option_random > 1;
166     my $ok = 1;
167     if ( $results =~ s/^SKIPPED\n//) {
168         print "$results\n" ;
169     }
170     elsif ($option_random)
171     {
172         $ok = randomMatch($results, $expected);
173     }
174     elsif (($prefix  && (( $option_regex && $results !~ /^$expected/) ||
175                          (!$option_regex && $results !~ /^\Q$expected/))) or
176            (!$prefix && (( $option_regex && $results !~ /^$expected/) ||
177                          (!$option_regex && $results ne $expected)))) {
178         my $err_line = "PROG: $switch\n$prog\n" .
179                        "EXPECTED:\n$expected\n" .
180                        "GOT:\n$results\n";
181         if ($todo) {
182             $err_line =~ s/^/# /mg;
183             print $err_line;  # Harness can't filter it out from STDERR.
184         }
185         else {
186             print STDERR $err_line;
187         }
188         $ok = 0;
189     }
190
191     our $TODO = $todo ? $todo_reason : 0;
192     ok($ok);
193
194     foreach (@temps)
195         { unlink $_ if $_ }
196     foreach (@temp_path)
197         { rmtree $_ if -d $_ }
198 }
199
200 sub randomMatch
201 {
202     my $got = shift ;
203     my $expected = shift;
204
205     my @got = sort split "\n", $got ;
206     my @expected = sort split "\n", $expected ;
207
208    return "@got" eq "@expected";
209
210 }
211
212 1;