t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6 use DBICTest::Schema;
   7
   8 =head1 NAME
   9
  10 DBICTest - Library to be used by DBIx::Class test scripts.
  11
  12 =head1 SYNOPSIS
  13
  14   use lib qw(t/lib);
  15   use DBICTest;
  16   use Test::More;
  17
  18   my $schema = DBICTest->init_schema();
  19
  20 =head1 DESCRIPTION
  21
  22 This module provides the basic utilities to write tests against
  23 DBIx::Class.
  24
  25 =head1 METHODS
  26
  27 =head2 init_schema
  28
  29   my $schema = DBICTest->init_schema(
  30     no_deploy=>1,
  31     no_populate=>1,
  32   );
  33
  34 This method removes the test SQLite database in t/var/DBIxClass.db
  35 and then creates a new, empty database.
  36
  37 This method will call deploy_schema() by default, unless the
  38 no_deploy flag is set.
  39
  40 Also, by default, this method will call populate_schema() by
  41 default, unless the no_deploy or no_populate flags are set.
  42
  43 =cut
  44
  45 sub init_schema {
  46     my $self = shift;
  47     my %args = @_;
  48     my $db_file = "t/var/DBIxClass.db";
  49
  50     unlink($db_file) if -e $db_file;
  51     unlink($db_file . "-journal") if -e $db_file . "-journal";
  52     mkdir("t/var") unless -d "t/var";
  53
  54     my $dsn = $ENV{"DBICTEST_DSN"} || "dbi:SQLite:${db_file}";
  55     my $dbuser = $ENV{"DBICTEST_DBUSER"} || '';
  56     my $dbpass = $ENV{"DBICTEST_DBPASS"} || '';
  57
  58    my $schema = DBICTest::Schema->compose_connection('DBICTest' => $dsn, $dbuser, $dbpass);
  59     $schema->storage->on_connect_do(['PRAGMA synchronous = OFF']);
  60     if ( !$args{no_deploy} ) {
  61         __PACKAGE__->deploy_schema( $schema );
  62         __PACKAGE__->populate_schema( $schema ) if( !$args{no_populate} );
  63     }
  64     return $schema;
  65 }
  66
  67 =head2 deploy_schema
  68
  69   DBICTest->deploy_schema( $schema );
  70
  71 This method does one of two things to the schema.  It can either call
  72 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
  73 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
  74 file and execute the SQL within. Either way you end up with a fresh set
  75 of tables for testing.
  76
  77 =cut
  78
  79 sub deploy_schema {
  80     my $self = shift;
  81     my $schema = shift;
  82
  83     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
  84         return $schema->deploy();
  85     } else {
  86         open IN, "t/lib/sqlite.sql";
  87         my $sql;
  88         { local $/ = undef; $sql = <IN>; }
  89         close IN;
  90         ($schema->storage->dbh->do($_) || print "Error on SQL: $_\n") for split(/;\n/, $sql);
  91     }
  92 }
  93
  94 =head2 populate_schema
  95
  96   DBICTest->populate_schema( $schema );
  97
  98 After you deploy your schema you can use this method to populate
  99 the tables with test data.
 100
 101 =cut
 102
 103 sub populate_schema {
 104     my $self = shift;
 105     my $schema = shift;
 106
 107     $schema->populate('Host', [
 108         [ qw/hostname address/ ],
 109         [ 'localhost', 2130706433 ],
 110     ]);
 111
 112     $schema->populate('Network', [
 113        [ qw/netname address/ ],
 114        [ qw{localnet 127.0.0.0/8} ],
 115     ]);
 116 }
 117
 118 1;