t/io/openpid.t

   1 #!./perl
   2
   3 #####################################################################
   4 #
   5 # Test for process id return value from open
   6 # Ronald Schmidt (The Software Path) RonaldWS@software-path.com
   7 #
   8 #####################################################################
   9
  10 BEGIN {
  11     chdir 't' if -d 't';
  12     unshift @INC, '../lib';
  13     if ($^O eq 'dos') {
  14         print "1..0 # Skip: no multitasking\n";
  15         exit 0;
  16     }
  17 }
  18
  19
  20 use FileHandle;
  21 use Config;
  22 autoflush STDOUT 1;
  23 $SIG{PIPE} = 'IGNORE';
  24
  25 print "1..10\n";
  26
  27 $perl = "$^X -I../lib";
  28
  29 #
  30 # commands run 4 perl programs.  Two of these programs write a
  31 # short message to STDOUT and exit.  Two of these programs
  32 # read from STDIN.  One reader never exits and must be killed.
  33 # the other reader reads one line, waits a few seconds and then
  34 # exits to test the waitpid function.
  35 #
  36 $cmd1 = qq/$perl -e "use FileHandle; autoflush STDOUT 1; / .
  37         qq/print qq[first process\\n]; sleep 30;"/;
  38 $cmd2 = qq/$perl -e "use FileHandle; autoflush STDOUT 1; / .
  39         qq/print qq[second process\\n]; sleep 30;"/;
  40 $cmd3 = qq/$perl -e "print <>;"/; # hangs waiting for end of STDIN
  41 $cmd4 = qq/$perl -e "print scalar <>;"/;
  42
  43 #warn "#$cmd1\n#$cmd2\n#$cmd3\n#$cmd4\n";
  44
  45 # start the processes
  46 $pid1 = open(FH1, "$cmd1 |") or print "not ";
  47 print "ok 1\n";
  48 $pid2 = open(FH2, "$cmd2 |") or print "not ";
  49 print "ok 2\n";
  50 $pid3 = open(FH3, "| $cmd3") or print "not ";
  51 print "ok 3\n";
  52 $pid4 = open(FH4, "| $cmd4") or print "not ";
  53 print "ok 4\n";
  54
  55 print "# pids were $pid1, $pid2, $pid3, $pid4\n";
  56
  57 my $killsig = 'HUP';
  58 $killsig = 1 unless $Config{sig_name} =~ /\bHUP\b/;
  59
  60 # get message from first process and kill it
  61 chomp($from_pid1 = scalar(<FH1>));
  62 print "# child1 returned [$from_pid1]\nnot "
  63     unless $from_pid1 eq 'first process';
  64 print "ok 5\n";
  65 $kill_cnt = kill $killsig, $pid1;
  66 print "not " unless $kill_cnt == 1;
  67 print "ok 6\n";
  68
  69 # get message from second process and kill second process and reader process
  70 chomp($from_pid2 = scalar(<FH2>));
  71 print "# child2 returned [$from_pid2]\nnot "
  72     unless $from_pid2 eq 'second process';
  73 print "ok 7\n";
  74 $kill_cnt = kill $killsig, $pid2, $pid3;
  75 print "not " unless $kill_cnt == 2;
  76 print "ok 8\n";
  77
  78 # send one expected line of text to child process and then wait for it
  79 autoflush FH4 1;
  80 print FH4 "ok 9\n";
  81 print "# waiting for process $pid4 to exit\n";
  82 $reap_pid = waitpid $pid4, 0;
  83 print "# reaped pid $reap_pid != $pid4\nnot "
  84     unless $reap_pid == $pid4;
  85 print "ok 10\n";