t/inflate/datetime.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Warn;
   6 use Try::Tiny;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 # so user's env doesn't screw us
  11 delete $ENV{DBIC_DT_SEARCH_OK};
  12
  13 my $schema = DBICTest->init_schema();
  14
  15 plan skip_all => 'DT inflation tests need ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_sqlite')
  16   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_sqlite');
  17
  18 # inflation test
  19 my $event = $schema->resultset("Event")->find(1);
  20
  21 isa_ok($event->starts_at, 'DateTime', 'DateTime returned');
  22
  23 # klunky, but makes older Test::More installs happy
  24 my $starts = $event->starts_at;
  25 is("$starts", '2006-04-25T22:24:33', 'Correct date/time');
  26
  27 my $dt_warn_re = qr/DateTime objects.+not supported properly/;
  28
  29 my $row;
  30
  31 {
  32   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  33   local $SIG{__WARN__} = sub {
  34     fail('Disabled warning still issued') if $_[0] =~ $dt_warn_re;
  35     warn @_;
  36   };
  37   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  38 }
  39
  40 warnings_exist {
  41   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  42 } [$dt_warn_re],
  43   'using a DateTime object in ->search generates a warning';
  44
  45 {
  46   local $TODO = "This stuff won't work without a -dt operator of some sort"
  47     unless eval { require DBIx::Class::SQLMaker::DateOps };
  48
  49   is(eval { $row->id }, 1, 'DT in search');
  50
  51   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  52
  53   ok($row =
  54     $schema->resultset('Event')->search({ starts_at => { '>=' => $starts } })
  55     ->single);
  56
  57   is(eval { $row->id }, 1, 'DT in search with condition');
  58 }
  59
  60 # create using DateTime
  61 my $created = $schema->resultset('Event')->create({
  62     starts_at => DateTime->new(year=>2006, month=>6, day=>18),
  63     created_on => DateTime->new(year=>2006, month=>6, day=>23)
  64 });
  65 my $created_start = $created->starts_at;
  66
  67 isa_ok($created->starts_at, 'DateTime', 'DateTime returned');
  68 is("$created_start", '2006-06-18T00:00:00', 'Correct date/time');
  69
  70 ## timestamp field
  71 isa_ok($event->created_on, 'DateTime', 'DateTime returned');
  72
  73 ## varchar fields
  74 isa_ok($event->varchar_date, 'DateTime', 'DateTime returned');
  75 isa_ok($event->varchar_datetime, 'DateTime', 'DateTime returned');
  76
  77 ## skip inflation field
  78 isnt(ref($event->skip_inflation), 'DateTime', 'No DateTime returned for skip inflation column');
  79
  80 # klunky, but makes older Test::More installs happy
  81 my $createo = $event->created_on;
  82 is("$createo", '2006-06-22T21:00:05', 'Correct date/time');
  83
  84 my $created_cron = $created->created_on;
  85
  86 isa_ok($created->created_on, 'DateTime', 'DateTime returned');
  87 is("$created_cron", '2006-06-23T00:00:00', 'Correct date/time');
  88
  89 ## varchar field using inflate_date => 1
  90 my $varchar_date = $event->varchar_date;
  91 is("$varchar_date", '2006-07-23T00:00:00', 'Correct date/time');
  92
  93 ## varchar field using inflate_datetime => 1
  94 my $varchar_datetime = $event->varchar_datetime;
  95 is("$varchar_datetime", '2006-05-22T19:05:07', 'Correct date/time');
  96
  97 ## skip inflation field
  98 my $skip_inflation = $event->skip_inflation;
  99 is ("$skip_inflation", '2006-04-21 18:04:06', 'Correct date/time');
 100
 101 done_testing;