t/harness

   1 #!./perl
   2
   3 # We suppose that perl _mostly_ works at this moment, so may use
   4 # sophisticated testing.
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';              # pick up only this build's lib
   9     $ENV{PERL5LIB} = '../lib';    # so children will see it too
  10 }
  11
  12 my $torture; # torture testing?
  13
  14 use Test::Harness;
  15 use strict;
  16
  17 $Test::Harness::switches = "";    # Too much noise otherwise
  18 $Test::Harness::Verbose++ while @ARGV && $ARGV[0] eq '-v' && shift;
  19
  20 if ($ARGV[0] && $ARGV[0] eq '-torture') {
  21     shift;
  22     $torture = 1;
  23 }
  24
  25 # Let tests know they're running in the perl core.  Useful for modules
  26 # which live dual lives on CPAN.
  27 $ENV{PERL_CORE} = 1;
  28
  29 #fudge DATA for now.
  30 my %datahandle = qw(
  31                 lib/bigint.t            1
  32                 lib/bigintpm.t          1
  33                 lib/bigfloat.t          1
  34                 lib/bigfloatpm.t        1
  35                 op/gv.t                 1
  36                 lib/complex.t           1
  37                 lib/ph.t                1
  38                 lib/soundex.t           1
  39                 op/misc.t               1
  40                 op/runlevel.t           1
  41                 op/tie.t                1
  42                 op/lex_assign.t         1
  43                 );
  44
  45 foreach (keys %datahandle) {
  46      unlink "$_.t";
  47 }
  48
  49 my (@tests, $re);
  50
  51 # [.VMS]TEST.COM calls harness with empty arguments, so clean-up @ARGV
  52 @ARGV = grep $_ && length( $_ ) => @ARGV;
  53
  54 sub _populate_hash {
  55     return map {$_, 1} split /\s+/, $_[0];
  56 }
  57
  58 # Generate T::H schedule rules that run the contents of each directory
  59 # sequentially.
  60 sub _seq_dir_rules {
  61     my @tests = @_;
  62     my %dir;
  63     for (@tests) {
  64         s{[^/]+$}{\*};
  65         $dir{$_}++;
  66     }
  67
  68     return { par => [ map { { seq => $_ } } sort keys %dir ] };
  69 }
  70
  71 sub _extract_tests;
  72 sub _extract_tests {
  73     # This can probably be done more tersely with a map, but I doubt that it
  74     # would be as clear
  75     my @results;
  76     foreach (@_) {
  77         my $ref = ref $_;
  78         if ($ref) {
  79             if ($ref eq 'ARRAY') {
  80                 push @results, _extract_tests @$_;
  81             } elsif ($ref eq 'HASH') {
  82                 push @results, _extract_tests values %$_;
  83             } else {
  84                 die "Unknown reference type $ref";
  85             }
  86         } else {
  87             push @results, glob $_;
  88         }
  89     }
  90     @results;
  91 }
  92
  93 if ($ARGV[0] && $ARGV[0]=~/^-re/) {
  94     if ($ARGV[0]!~/=/) {
  95         shift;
  96         $re=join "|",@ARGV;
  97         @ARGV=();
  98     } else {
  99         (undef,$re)=split/=/,shift;
 100     }
 101 }
 102
 103 my $jobs = $ENV{TEST_JOBS};
 104 my ($rules, $state);
 105
 106 if (@ARGV) {
 107     # If you want these run in speed order, just use prove
 108     if ($^O eq 'MSWin32') {
 109         @tests = map(glob($_),@ARGV);
 110     }
 111     else {
 112         @tests = @ARGV;
 113     }
 114 } else {
 115     # Ideally we'd get somewhere close to Tux's Oslo rules
 116     # my $rules = {
 117     #     par => [
 118     #         { seq => '../ext/DB_File/t/*' },
 119     #         { seq => '../ext/IO_Compress_Zlib/t/*' },
 120     #         { seq => '../lib/CPANPLUS/*' },
 121     #         { seq => '../lib/ExtUtils/t/*' },
 122     #         '*'
 123     #     ]
 124     # };
 125
 126     # but for now, run all directories in sequence. In particular, it would be
 127     # nice to get the tests in t/op/*.t able to run in parallel.
 128
 129     unless (@tests) {
 130         my @seq = <base/*.t>;
 131
 132         my @next = qw(comp cmd run io op uni mro lib);
 133         push @next, 'japh' if $torture;
 134         push @next, 'win32' if $^O eq 'MSWin32';
 135         # Hopefully TAP::Parser::Scheduler will support this syntax soon.
 136         # my $next = { par => '{' . join (',', @next) . '}/*.t' };
 137         my $next = { par => [
 138                              map { "$_/*.t" } @next
 139                             ] };
 140         @tests = _extract_tests ($next);
 141
 142         # This is a bit of a game, because we only want to sort these tests in
 143         # speed order. base/*.t wants to run first, and ext,lib etc last and in
 144         # MANIFEST order
 145         if ($jobs) {
 146             require App::Prove::State;
 147             $state = App::Prove::State->new({ store => 'test_state' });
 148             $state->apply_switch('slow', 'save');
 149             # For some reason get_tests returns *all* the tests previously run,
 150             # (in the right order), not simply the selection in @tests
 151             # (in the right order). Not sure if this is a bug or a feature.
 152             # Whatever, *we* are only interested in the ones that are in @tests
 153             my %seen;
 154             @seen{@tests} = ();
 155             @tests = grep {exists $seen{$_} } $state->get_tests(0, @tests);
 156         }
 157         @tests = (@seq, @tests);
 158         push @seq, $next;
 159
 160         my @last;
 161         use Config;
 162         my %skip;
 163         {
 164             my %extensions = _populate_hash $Config{'extensions'};
 165             my %known_extensions = _populate_hash $Config{'known_extensions'};
 166             foreach (keys %known_extensions) {
 167                 $skip{$_}++ unless $extensions{$_};
 168             }
 169         }
 170         use File::Spec;
 171         my $updir = File::Spec->updir;
 172         my $mani  = File::Spec->catfile(File::Spec->updir, "MANIFEST");
 173         if (open(MANI, $mani)) {
 174             my @manitests = ();
 175             my $ext_pat = $^O eq 'MSWin32' ? '(?:win32/)?ext' : 'ext';
 176             while (<MANI>) { # similar code in t/TEST
 177                 if (m!^($ext_pat/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 178                     my ($test, $extension) = ($1, $2);
 179                     if (defined $extension) {
 180                         $extension =~ s!/t$!!;
 181                         # XXX Do I want to warn that I'm skipping these?
 182                         next if $skip{$extension};
 183                     }
 184                     push @manitests, File::Spec->catfile($updir, $test);
 185                 }
 186             }
 187             close MANI;
 188             # Sort the list of test files read from MANIFEST into a sensible
 189             # order instead of using the order in which they are listed there
 190             push @last, sort { lc $a cmp lc $b } @manitests;
 191         } else {
 192             warn "$0: cannot open $mani: $!\n";
 193         }
 194         push @last, <Module_Pluggable/*.t>;
 195         push @last, <pod/*.t>;
 196         push @last, <x2p/*.t>;
 197
 198         push @tests, @last;
 199
 200         push @seq, _seq_dir_rules @last;
 201
 202         $rules = { seq => \@seq };
 203     }
 204 }
 205 if ($^O eq 'MSWin32') {
 206     s,\\,/,g for @tests;
 207 }
 208 @tests=grep /$re/, @tests
 209     if $re;
 210
 211 if ($jobs) {
 212     eval 'use TAP::Harness 3.13; 1' or die $@;
 213     my $h = TAP::Harness->new({ jobs => $jobs, rules => $rules});
 214     if ($state) {
 215         $h->callback(
 216                      after_test => sub {
 217                          $state->observe_test(@_);
 218                      }
 219                     );
 220     }
 221     $h->runtests(@tests);
 222 } else {
 223     Test::Harness::runtests @tests;
 224 }
 225 exit(0);