t/harness

   1 #!./perl
   2
   3 # We suppose that perl _mostly_ works at this moment, so may use
   4 # sophisticated testing.
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';              # pick up only this build's lib
   9 }
  10 delete $ENV{PERL5LIB};
  11
  12 my $torture; # torture testing?
  13
  14 use Test::Harness;
  15 use strict;
  16
  17 $Test::Harness::switches = "";    # Too much noise otherwise
  18 $Test::Harness::Verbose++ while @ARGV && $ARGV[0] eq '-v' && shift;
  19
  20 if ($ARGV[0] && $ARGV[0] eq '-torture') {
  21     shift;
  22     $torture = 1;
  23 }
  24
  25 # Let tests know they're running in the perl core.  Useful for modules
  26 # which live dual lives on CPAN.
  27 $ENV{PERL_CORE} = 1;
  28
  29 #fudge DATA for now.
  30 my %datahandle = qw(
  31                 lib/bigint.t            1
  32                 lib/bigintpm.t          1
  33                 lib/bigfloat.t          1
  34                 lib/bigfloatpm.t        1
  35                 op/gv.t                 1
  36                 lib/complex.t           1
  37                 lib/ph.t                1
  38                 lib/soundex.t           1
  39                 op/misc.t               1
  40                 op/runlevel.t           1
  41                 op/tie.t                1
  42                 op/lex_assign.t         1
  43                 );
  44
  45 foreach (keys %datahandle) {
  46      unlink "$_.t";
  47 }
  48
  49 my (@tests, $re);
  50
  51 # [.VMS]TEST.COM calls harness with empty arguments, so clean-up @ARGV
  52 @ARGV = grep $_ && length( $_ ) => @ARGV;
  53
  54 sub _populate_hash {
  55     return map {$_, 1} split /\s+/, $_[0];
  56 }
  57
  58 sub _extract_tests;
  59 sub _extract_tests {
  60     # This can probably be done more tersely with a map, but I doubt that it
  61     # would be as clear
  62     my @results;
  63     foreach (@_) {
  64         my $ref = ref $_;
  65         if ($ref) {
  66             if ($ref eq 'ARRAY') {
  67                 push @results, _extract_tests @$_;
  68             } elsif ($ref eq 'HASH') {
  69                 push @results, _extract_tests values %$_;
  70             } else {
  71                 die "Unknown reference type $ref";
  72             }
  73         } else {
  74             push @results, glob $_;
  75         }
  76     }
  77     @results;
  78 }
  79
  80 if ($ARGV[0] && $ARGV[0]=~/^-re/) {
  81     if ($ARGV[0]!~/=/) {
  82         shift;
  83         $re=join "|",@ARGV;
  84         @ARGV=();
  85     } else {
  86         (undef,$re)=split/=/,shift;
  87     }
  88 }
  89
  90 my $jobs = $ENV{TEST_JOBS};
  91 my ($fork, $rules, $state);
  92 if ($ENV{HARNESS_OPTIONS}) {
  93     for my $opt ( split /:/, $ENV{HARNESS_OPTIONS} ) {
  94         if ( $opt =~ /^j(\d*)$/ ) {
  95             $jobs ||= $1 || 9;
  96         }
  97         elsif ( $opt eq 'f' ) {
  98             $fork = 1;
  99         }
 100         elsif ( $opt eq 'c' ) {
 101 #            $args->{color} = 1;
 102         }
 103         else {
 104             die "Unknown HARNESS_OPTIONS item: $opt\n";
 105         }
 106     }
 107 }
 108
 109 if (@ARGV) {
 110     # If you want these run in speed order, just use prove
 111     if ($^O eq 'MSWin32') {
 112         @tests = map(glob($_),@ARGV);
 113     }
 114     else {
 115         @tests = @ARGV;
 116     }
 117 } else {
 118     # Ideally we'd get somewhere close to Tux's Oslo rules
 119     # my $rules = {
 120     #     par => [
 121     #         { seq => '../ext/DB_File/t/*' },
 122     #         { seq => '../ext/IO_Compress_Zlib/t/*' },
 123     #         { seq => '../lib/CPANPLUS/*' },
 124     #         { seq => '../lib/ExtUtils/t/*' },
 125     #         '*'
 126     #     ]
 127     # };
 128
 129     # but for now, run all directories in sequence. In particular, it would be
 130     # nice to get the tests in t/op/*.t able to run in parallel.
 131
 132     unless (@tests) {
 133         my @seq = <base/*.t>;
 134
 135         my @next = qw(comp cmd run io op uni mro lib porting);
 136         push @next, 'japh' if $torture;
 137         push @next, 'win32' if $^O eq 'MSWin32';
 138         push @next, 'benchmark' if $ENV{PERL_BENCHMARK};
 139         # Hopefully TAP::Parser::Scheduler will support this syntax soon.
 140         # my $next = { par => '{' . join (',', @next) . '}/*.t' };
 141         my $next = { par => [
 142                              map { "$_/*.t" } @next
 143                             ] };
 144         @tests = _extract_tests ($next);
 145
 146         # This is a bit of a game, because we only want to sort these tests in
 147         # speed order. base/*.t wants to run first, and ext,lib etc last and in
 148         # MANIFEST order
 149         if ($jobs) {
 150             require App::Prove::State;
 151             $state = App::Prove::State->new({ store => 'test_state' });
 152             $state->apply_switch('slow', 'save');
 153             # For some reason get_tests returns *all* the tests previously run,
 154             # (in the right order), not simply the selection in @tests
 155             # (in the right order). Not sure if this is a bug or a feature.
 156             # Whatever, *we* are only interested in the ones that are in @tests
 157             my %seen;
 158             @seen{@tests} = ();
 159             @tests = grep {exists $seen{$_} } $state->get_tests(0, @tests);
 160         }
 161         @tests = (@seq, @tests);
 162         push @seq, $next;
 163
 164         my @last;
 165         use Config;
 166         my %skip;
 167         {
 168             my %extensions = _populate_hash $Config{'extensions'};
 169             my %known_extensions = _populate_hash $Config{'known_extensions'};
 170             foreach (keys %known_extensions) {
 171                 $skip{$_}++ unless $extensions{$_};
 172             }
 173         }
 174         use File::Spec;
 175         my $updir = File::Spec->updir;
 176         my $mani  = File::Spec->catfile(File::Spec->updir, "MANIFEST");
 177         if (open(MANI, $mani)) {
 178             my @manitests = ();
 179             while (<MANI>) { # similar code in t/TEST
 180                 if (m!^(ext/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 181                     my ($test, $extension) = ($1, $2);
 182                     if (defined $extension) {
 183                         $extension =~ s!/t$!!;
 184                         # XXX Do I want to warn that I'm skipping these?
 185                         next if $skip{$extension};
 186                         my $flat_extension = $extension;
 187                         $flat_extension =~ s!-!/!g;
 188                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 189                     }
 190                     push @manitests, File::Spec->catfile($updir, $test);
 191                 }
 192             }
 193             close MANI;
 194             # Sort the list of test files read from MANIFEST into a sensible
 195             # order instead of using the order in which they are listed there
 196             push @last, sort { lc $a cmp lc $b } @manitests;
 197         } else {
 198             warn "$0: cannot open $mani: $!\n";
 199         }
 200         push @last, <pod/*.t>;
 201         push @last, <x2p/*.t>;
 202
 203         my %times;
 204         if ($state) {
 205             # Where known, collate the elapsed times by test name
 206             foreach ($state->results->tests()) {
 207                 $times{$_->name} = $_->elapsed();
 208             }
 209         }
 210
 211         my %dir;
 212         my %total_time;
 213
 214         for (@last) {
 215             if ($^O eq 'MSWin32') {
 216                 s,\\,/,g; # canonicalize path
 217             };
 218             m!(.*[/])! or die "'$_'";
 219             push @{$dir{$1}}, $_;
 220             $total_time{$1} += $times{$_} || 0;
 221         }
 222
 223         push @tests, @last;
 224
 225         # Generate T::H schedule rules that run the contents of each directory
 226         # sequentially.
 227         push @seq, { par => [ map { { seq => "$_*" } } sort {
 228             # Directories, ordered by total time descending then name ascending
 229             $total_time{$b} <=> $total_time{$a} || $a cmp $b
 230         } keys %dir ] };
 231
 232         $rules = { seq => \@seq };
 233     }
 234 }
 235 if ($^O eq 'MSWin32') {
 236     s,\\,/,g for @tests;
 237 }
 238 @tests=grep /$re/, @tests
 239     if $re;
 240
 241 if ($jobs) {
 242     eval 'use TAP::Harness 3.13; 1' or die $@;
 243
 244     # Test::Harness parses $ENV{HARNESS_OPTIONS}, TAP::Harness does not
 245     local $ENV{HARNESS_OPTIONS};
 246     my $h = TAP::Harness->new({ jobs => $jobs, rules => $rules, ($fork ? (fork => $fork) : ())});
 247     if ($state) {
 248         $h->callback(
 249                      after_test => sub {
 250                          $state->observe_test(@_);
 251                      }
 252                     );
 253         $h->callback(
 254                      after_runtests => sub {
 255                          $state->commit(@_);
 256                      }
 257                     );
 258     }
 259     $h->callback(
 260                  parser_args => sub {
 261                      my ( $args, $test ) = @_;
 262                      push @{ $args->{switches} }, '-I../lib';
 263                  }
 264                 );
 265     $h->runtests(@tests);
 266 } else {
 267     Test::Harness::runtests @tests;
 268 }
 269 exit(0);