t/harness

   1 #!./perl
   2
   3 # We suppose that perl _mostly_ works at this moment, so may use
   4 # sophisticated testing.
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';              # pick up only this build's lib
   9     $ENV{PERL5LIB} = '../lib';    # so children will see it too
  10 }
  11
  12 my $torture; # torture testing?
  13
  14 use Test::Harness;
  15 use strict;
  16
  17 $Test::Harness::switches = "";    # Too much noise otherwise
  18 $Test::Harness::Verbose++ while @ARGV && $ARGV[0] eq '-v' && shift;
  19
  20 if ($ARGV[0] && $ARGV[0] eq '-torture') {
  21     shift;
  22     $torture = 1;
  23 }
  24
  25 # Let tests know they're running in the perl core.  Useful for modules
  26 # which live dual lives on CPAN.
  27 $ENV{PERL_CORE} = 1;
  28
  29 #fudge DATA for now.
  30 my %datahandle = qw(
  31                 lib/bigint.t            1
  32                 lib/bigintpm.t          1
  33                 lib/bigfloat.t          1
  34                 lib/bigfloatpm.t        1
  35                 op/gv.t                 1
  36                 lib/complex.t           1
  37                 lib/ph.t                1
  38                 lib/soundex.t           1
  39                 op/misc.t               1
  40                 op/runlevel.t           1
  41                 op/tie.t                1
  42                 op/lex_assign.t         1
  43                 );
  44
  45 foreach (keys %datahandle) {
  46      unlink "$_.t";
  47 }
  48
  49 my (@tests, $rules, $re);
  50
  51 # [.VMS]TEST.COM calls harness with empty arguments, so clean-up @ARGV
  52 @ARGV = grep $_ && length( $_ ) => @ARGV;
  53
  54 sub _populate_hash {
  55     return map {$_, 1} split /\s+/, $_[0];
  56 }
  57
  58 sub _glob_and_parallelise {
  59     my @dirs;
  60     # Run the tests in each of these directories in sequence, but the
  61     # directories themselves can be parallelised.
  62     foreach (@_) {
  63         push @dirs, { seq => "$_/*.t" };
  64     }
  65     { par =>  \@dirs };
  66 }
  67
  68 # Generate T::H schedule rules that run the contents of each directory
  69 # sequentially.
  70 sub _seq_dir_rules {
  71     my @tests = @_;
  72     my %dir;
  73     for (@tests) {
  74         s{[^/]+$}{\*};
  75         $dir{$_}++;
  76     }
  77
  78     return { par => [ map { { seq => $_ } } sort keys %dir ] };
  79 }
  80
  81 sub _extract_tests;
  82 sub _extract_tests {
  83     # This can probably be done more tersely with a map, but I doubt that it
  84     # would be as clear
  85     my @results;
  86     foreach (@_) {
  87         my $ref = ref $_;
  88         if ($ref) {
  89             if ($ref eq 'ARRAY') {
  90                 push @results, _extract_tests @$_;
  91             } elsif ($ref eq 'HASH') {
  92                 push @results, _extract_tests values %$_;
  93             } else {
  94                 die "Unknown reference type $ref";
  95             }
  96         } else {
  97             push @results, glob $_;
  98         }
  99     }
 100     @results;
 101 }
 102
 103 if ($ARGV[0] && $ARGV[0]=~/^-re/) {
 104     if ($ARGV[0]!~/=/) {
 105         shift;
 106         $re=join "|",@ARGV;
 107         @ARGV=();
 108     } else {
 109         (undef,$re)=split/=/,shift;
 110     }
 111 }
 112
 113 if (@ARGV) {
 114     if ($^O eq 'MSWin32') {
 115         @tests = map(glob($_),@ARGV);
 116     }
 117     else {
 118         @tests = @ARGV;
 119     }
 120 } else {
 121     # Ideally we'd get somewhere close to Tux's Oslo rules
 122     # my $rules = {
 123     #     par => [
 124     #         { seq => '../ext/DB_File/t/*' },
 125     #         { seq => '../ext/IO_Compress_Zlib/t/*' },
 126     #         { seq => '../lib/CPANPLUS/*' },
 127     #         { seq => '../lib/ExtUtils/t/*' },
 128     #         '*'
 129     #     ]
 130     # };
 131
 132     # but for now, run all directories in sequence. In particular, it would be
 133     # nice to get the tests in t/op/*.t able to run in parallel.
 134
 135     unless (@tests) {
 136         my @seq;
 137         push @seq, <base/*.t>;
 138
 139         push @seq, _glob_and_parallelise qw(comp cmd run io);
 140         my @next = qw(op uni mro lib);
 141         push @next, 'japh' if $torture;
 142         push @next, 'win32' if $^O eq 'MSWin32';
 143         push @seq, { par => [
 144                              map { glob "$_/*.t" } @next
 145                             ] };
 146
 147         my @last;
 148         use Config;
 149         my %skip;
 150         {
 151             my %extensions = _populate_hash $Config{'extensions'};
 152             my %known_extensions = _populate_hash $Config{'known_extensions'};
 153             foreach (keys %known_extensions) {
 154                 $skip{$_}++ unless $extensions{$_};
 155             }
 156         }
 157         use File::Spec;
 158         my $updir = File::Spec->updir;
 159         my $mani  = File::Spec->catfile(File::Spec->updir, "MANIFEST");
 160         if (open(MANI, $mani)) {
 161             my @manitests = ();
 162             my $ext_pat = $^O eq 'MSWin32' ? '(?:win32/)?ext' : 'ext';
 163             while (<MANI>) { # similar code in t/TEST
 164                 if (m!^($ext_pat/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 165                     my ($test, $extension) = ($1, $2);
 166                     if (defined $extension) {
 167                         $extension =~ s!/t$!!;
 168                         # XXX Do I want to warn that I'm skipping these?
 169                         next if $skip{$extension};
 170                     }
 171                     push @manitests, File::Spec->catfile($updir, $test);
 172                 }
 173             }
 174             close MANI;
 175             # Sort the list of test files read from MANIFEST into a sensible
 176             # order instead of using the order in which they are listed there
 177             push @last, sort { lc $a cmp lc $b } @manitests;
 178         } else {
 179             warn "$0: cannot open $mani: $!\n";
 180         }
 181         push @last, <Module_Pluggable/*.t>;
 182         push @last, <pod/*.t>;
 183         push @last, <x2p/*.t>;
 184
 185         @tests = (_extract_tests (@seq), @last);
 186
 187         push @seq, _seq_dir_rules @last;
 188
 189         $rules = { seq => \@seq };
 190
 191     }
 192 }
 193 if ($^O eq 'MSWin32') {
 194     s,\\,/,g for @tests;
 195 }
 196 @tests=grep /$re/, @tests
 197     if $re;
 198
 199 my $jobs = $ENV{TEST_JOBS};
 200 if ($jobs) {
 201     eval 'use TAP::Harness 3.13; 1' or die $@;
 202     my $h = TAP::Harness->new({ jobs => $jobs, rules => $rules});
 203     $h->runtests(@tests);
 204 } else {
 205     Test::Harness::runtests @tests;
 206 }
 207 exit(0);