t/generated_app.t

   1 use strict;
   2 use warnings;
   3 use lib ();
   4 use Cwd qw( abs_path );
   5 use File::Temp qw/ tempdir /;
   6 use File::Spec;
   7 use FindBin qw/$Bin/;
   8 use Catalyst::Devel;
   9 use Catalyst::Helper;
  10 use Test::More;
  11 use Config;
  12
  13 eval "use IPC::Run3";
  14 plan skip_all => 'These tests require IPC::Run3' if $@;
  15
  16 my $share_dir = abs_path('share');
  17 plan skip_all => "No share dir at $share_dir!"
  18     unless -d $share_dir;
  19
  20 $ENV{CATALYST_DEVEL_SHAREDIR} = $share_dir;
  21
  22 my $dir = tempdir(CLEANUP => 1);
  23 my $devnull = File::Spec->devnull;
  24
  25 diag "Generated app is in $dir";
  26
  27 chdir $dir or die "Cannot chdir to $dir: $!";
  28
  29 {
  30     open my $fh, '>', $devnull or die "Cannot write to $devnull: $!";
  31
  32     local *STDOUT = $fh;
  33
  34     my $helper = Catalyst::Helper->new(
  35         {
  36             name => 'TestApp',
  37         }
  38     );
  39
  40     $helper->mk_app('TestApp');
  41 }
  42
  43 my $app_dir = File::Spec->catdir($dir, 'TestApp');
  44 chdir($app_dir) or die "Cannot chdir to $app_dir: $!";
  45 lib->import(File::Spec->catdir($dir, 'TestApp', 'lib'));
  46
  47 my @files = qw|
  48     Makefile.PL
  49     testapp.conf
  50     lib/TestApp.pm
  51     lib/TestApp/Controller/Root.pm
  52     README
  53     Changes
  54     t/01app.t
  55     t/02pod.t
  56     t/03podcoverage.t
  57     root/static/images/catalyst_logo.png
  58     root/static/images/btn_120x50_built.png
  59     root/static/images/btn_120x50_built_shadow.png
  60     root/static/images/btn_120x50_powered.png
  61     root/static/images/btn_120x50_powered_shadow.png
  62     root/static/images/btn_88x31_built.png
  63     root/static/images/btn_88x31_built_shadow.png
  64     root/static/images/btn_88x31_powered.png
  65     root/static/images/btn_88x31_powered_shadow.png
  66     root/favicon.ico
  67     Makefile.PL
  68     script/testapp_cgi.pl
  69     script/testapp_fastcgi.pl
  70     script/testapp_server.pl
  71     script/testapp_test.pl
  72     script/testapp_create.pl
  73 |;
  74
  75 foreach my $fn (map { File::Spec->catdir(@$_) } map { [ split /\// ] } @files) {
  76     test_fn($fn);
  77 }
  78 create_ok($_, 'My' . $_) for qw/Model View Controller/;
  79
  80 command_ok( [ $^X, 'Makefile.PL' ] );
  81 ok -e "Makefile", "Makefile generated";
  82 #NOTE: do not assume that 'make' is always 'make' as e.g. Win32/strawberry perl uses 'dmake'
  83 command_ok( [ ($Config{make} || 'make') ] );
  84
  85 run_generated_component_tests();
  86
  87 my $server_script_file = File::Spec->catdir(qw/script testapp_server.pl/);
  88 my $server_script = do {
  89     open(my $fh, '<', $server_script_file) or fail $!;
  90     local $/;
  91     <$fh>;
  92 };
  93
  94 ok $server_script;
  95 ok $server_script =~ qr/CATALYST_SCRIPT_GEN}\s+=\s+(\d+)/,
  96     'SCRIPT_GEN found in generated output';
  97 is $1, $Catalyst::Devel::CATALYST_SCRIPT_GEN, 'Script gen correct';
  98
  99 {
 100     open(my $fh, '>', $server_script_file) or fail $!;
 101     print $fh "MOO\n";
 102 }
 103 my $helper = Catalyst::Helper->new(
 104     {
 105         '.newfiles' => 0,
 106         'makefile'  => 0,
 107         'scripts'   => 1,
 108         name => '.',
 109     }
 110 );
 111 $helper->mk_app( '.' ) or fail;
 112
 113 my $server_script_new = do {
 114     open(my $fh, '<', $server_script_file) or fail $!;
 115     local $/;
 116     <$fh>;
 117 };
 118
 119 is $server_script, $server_script_new;
 120
 121 chdir('/');
 122 done_testing;
 123
 124 sub command_ok {
 125     my $cmd = shift;
 126     my $desc = shift;
 127
 128     my $stdout;
 129     my $stderr;
 130     run3( $cmd, \undef, \$stdout, \$stderr );
 131
 132     $desc ||= "Exit status ok for '@{$cmd}'";
 133     unless ( is $? >> 8, 0, $desc ) {
 134         diag "STDOUT:\n$stdout" if defined $stdout;
 135         diag "STDERR:\n$stderr" if defined $stderr;
 136     }
 137 }
 138
 139 sub runperl {
 140     my $comment = pop @_;
 141     command_ok( [ $^X, '-I', File::Spec->catdir($Bin, '..', 'lib'), @_ ], $comment );
 142 }
 143
 144 my @generated_component_tests;
 145
 146 sub test_fn {
 147     my $fn = shift;
 148     ok -r $fn, "Have $fn in generated app";
 149     if ($fn =~ /script/) {
 150         SKIP: {
 151             skip 'Executable file flag test does not make sense on Win32', 1 if ($^O eq 'MSWin32');
 152             ok -x $fn, "$fn is executable";
 153        }
 154     }
 155     if ($fn =~ /\.p[ml]$/) {
 156         runperl( '-c', $fn, "$fn compiles" );
 157     }
 158     # Save these till later as Catalyst::Test will only be loaded once :-/
 159     push @generated_component_tests, $fn
 160         if $fn =~ /\.t$/;
 161 }
 162
 163 sub run_generated_component_tests {
 164     local $ENV{TEST_POD} = 1;
 165     local $ENV{CATALYST_DEBUG} = 0;
 166     foreach my $fn (@generated_component_tests) {
 167         subtest "Generated app test: $fn", sub {
 168             do $fn;
 169         };
 170     }
 171 }
 172
 173 sub create_ok {
 174     my ($type, $name) = @_;
 175     runperl( File::Spec->catdir('script', 'testapp_create.pl'), $type, $name,
 176         "'script/testapp_create.pl $type $name' ok");
 177     test_fn(File::Spec->catdir('t', sprintf("%s_%s.t", lc $type, $name)));
 178 }