t/generated_app.t

   1 use strict;
   2 use warnings;
   3 use lib ();
   4 use Cwd qw( abs_path );
   5 use File::Temp qw/ tempdir /;
   6 use File::Spec;
   7 use FindBin qw/$Bin/;
   8 use Catalyst::Devel;
   9 use Catalyst::Helper;
  10 use Test::More;
  11 use Config;
  12
  13 eval "use IPC::Run3";
  14 plan skip_all => 'These tests require IPC::Run3' if $@;
  15
  16 my $share_dir = abs_path('share');
  17 plan skip_all => "No share dir at $share_dir!"
  18     unless -d $share_dir;
  19
  20 $ENV{CATALYST_DEVEL_SHAREDIR} = $share_dir;
  21 my $instdir = tempdir(CLEANUP => 1);
  22
  23 $ENV{PERL_MM_OPT} = "INSTALL_BASE=$instdir";
  24 $ENV{INSTALL_BASE} = $instdir;
  25 if ($ENV{MAKEFLAGS}) {
  26     $ENV{MAKEFLAGS} =~ s/PREFIX=[^\s]+//;
  27     $ENV{MAKEFLAGS} =~ s/INSTALL_BASE=[^\s]+//;
  28 }
  29
  30 my $dir = tempdir(CLEANUP => 1);
  31 my $devnull = File::Spec->devnull;
  32
  33 diag "Generated app is in $dir";
  34
  35 chdir $dir or die "Cannot chdir to $dir: $!";
  36
  37 {
  38     open my $fh, '>', $devnull or die "Cannot write to $devnull: $!";
  39
  40     local *STDOUT = $fh;
  41
  42     my $helper = Catalyst::Helper->new(
  43         {
  44             name => 'TestApp',
  45         }
  46     );
  47
  48     $helper->mk_app('TestApp');
  49 }
  50
  51 my $app_dir = File::Spec->catdir($dir, 'TestApp');
  52 chdir($app_dir) or die "Cannot chdir to $app_dir: $!";
  53 lib->import(File::Spec->catdir($dir, 'TestApp', 'lib'));
  54
  55 my @files = qw|
  56     Makefile.PL
  57     testapp.conf
  58     lib/TestApp.pm
  59     lib/TestApp/Controller/Root.pm
  60     README
  61     Changes
  62     t/01app.t
  63     t/02pod.t
  64     t/03podcoverage.t
  65     root/static/images/catalyst_logo.png
  66     root/static/images/btn_120x50_built.png
  67     root/static/images/btn_120x50_built_shadow.png
  68     root/static/images/btn_120x50_powered.png
  69     root/static/images/btn_120x50_powered_shadow.png
  70     root/static/images/btn_88x31_built.png
  71     root/static/images/btn_88x31_built_shadow.png
  72     root/static/images/btn_88x31_powered.png
  73     root/static/images/btn_88x31_powered_shadow.png
  74     root/favicon.ico
  75     Makefile.PL
  76     script/testapp_cgi.pl
  77     script/testapp_fastcgi.pl
  78     script/testapp_server.pl
  79     script/testapp_test.pl
  80     script/testapp_create.pl
  81 |;
  82
  83 foreach my $fn (map { File::Spec->catdir(@$_) } map { [ File::Spec::Unix->splitdir($_) ] } @files) {
  84     test_fn($fn);
  85 }
  86 create_ok($_, 'My' . $_) for qw/Model View Controller/;
  87
  88 command_ok( [ $^X, 'Makefile.PL' ] );
  89 ok -e "Makefile", "Makefile generated";
  90 #NOTE: do not assume that 'make' is always 'make' as e.g. Win32/strawberry perl uses 'dmake'
  91 command_ok( [ ($Config{make} || 'make') ] );
  92
  93 run_generated_component_tests();
  94
  95 my $server_script_file = File::Spec->catdir(qw/script testapp_server.pl/);
  96 my $server_script = do {
  97     open(my $fh, '<', $server_script_file) or fail $!;
  98     local $/;
  99     <$fh>;
 100 };
 101
 102 ok $server_script;
 103 ok $server_script =~ qr/CATALYST_SCRIPT_GEN}\s+=\s+(\d+)/,
 104     'SCRIPT_GEN found in generated output';
 105 is $1, $Catalyst::Devel::CATALYST_SCRIPT_GEN, 'Script gen correct';
 106
 107 {
 108     open(my $fh, '>', $server_script_file) or fail $!;
 109     print $fh "MOO\n";
 110 }
 111 my $helper = Catalyst::Helper->new(
 112     {
 113         '.newfiles' => 0,
 114         'makefile'  => 0,
 115         'scripts'   => 1,
 116         name => '.',
 117     }
 118 );
 119 $helper->mk_app( '.' ) or fail;
 120
 121 my $server_script_new = do {
 122     open(my $fh, '<', $server_script_file) or fail $!;
 123     local $/;
 124     <$fh>;
 125 };
 126
 127 is $server_script, $server_script_new;
 128
 129 diag "Installed app is in $instdir";
 130 command_ok( [ ($Config{make} || 'make', 'install') ] );
 131
 132 my $inst_app_dir = File::Spec->catdir($instdir);
 133 chdir($inst_app_dir) or die "Cannot chdir to $inst_app_dir: $!";
 134 lib->import(File::Spec->catdir($instdir, 'lib', 'perl5'));
 135
 136 my @installed_files = qw|
 137     lib/perl5/TestApp.pm
 138     lib/perl5/TestApp/testapp.conf
 139     lib/perl5/TestApp/Controller/Root.pm
 140     lib/perl5/TestApp/root/static/images/catalyst_logo.png
 141     lib/perl5/TestApp/root/static/images/btn_120x50_built.png
 142     lib/perl5/TestApp/root/static/images/btn_120x50_built_shadow.png
 143     lib/perl5/TestApp/root/static/images/btn_120x50_powered.png
 144     lib/perl5/TestApp/root/static/images/btn_120x50_powered_shadow.png
 145     lib/perl5/TestApp/root/static/images/btn_88x31_built.png
 146     lib/perl5/TestApp/root/static/images/btn_88x31_built_shadow.png
 147     lib/perl5/TestApp/root/static/images/btn_88x31_powered.png
 148     lib/perl5/TestApp/root/static/images/btn_88x31_powered_shadow.png
 149     lib/perl5/TestApp/root/favicon.ico
 150     bin/testapp_cgi.pl
 151     bin/testapp_fastcgi.pl
 152     bin/testapp_server.pl
 153     bin/testapp_test.pl
 154     bin/testapp_create.pl
 155 |;
 156
 157 foreach my $fn (map { File::Spec->catdir(@$_) } map { [ File::Spec::Unix->splitdir($_) ] } @installed_files) {
 158     my $ffn = File::Spec->catfile($inst_app_dir, $fn);
 159     ok -r $ffn, "'$fn' installed in correct location";
 160 }
 161
 162 chdir('/');
 163 done_testing;
 164
 165 sub command_ok {
 166     my $cmd = shift;
 167     my $desc = shift;
 168
 169     my $stdout;
 170     my $stderr;
 171     run3( $cmd, \undef, \$stdout, \$stderr );
 172
 173     $desc ||= "Exit status ok for '@{$cmd}'";
 174     unless ( is $? >> 8, 0, $desc ) {
 175         diag "STDOUT:\n$stdout" if defined $stdout;
 176         diag "STDERR:\n$stderr" if defined $stderr;
 177     }
 178 }
 179
 180 sub runperl {
 181     my $comment = pop @_;
 182     command_ok( [ $^X, '-I', File::Spec->catdir($Bin, '..', 'lib'), @_ ], $comment );
 183 }
 184
 185 my @generated_component_tests;
 186
 187 sub test_fn {
 188     my $fn = shift;
 189     ok -r $fn, "Have $fn in generated app";
 190     if ($fn =~ /script/) {
 191         SKIP: {
 192             skip 'Executable file flag test does not make sense on Win32', 1 if ($^O eq 'MSWin32');
 193             ok -x $fn, "$fn is executable";
 194        }
 195     }
 196     if ($fn =~ /\.p[ml]$/) {
 197         runperl( '-c', $fn, "$fn compiles" );
 198     }
 199     # Save these till later as Catalyst::Test will only be loaded once :-/
 200     push @generated_component_tests, $fn
 201         if $fn =~ /\.t$/;
 202 }
 203
 204 sub run_generated_component_tests {
 205     local $ENV{TEST_POD} = 1;
 206     local $ENV{CATALYST_DEBUG} = 0;
 207     foreach my $fn (@generated_component_tests) {
 208         subtest "Generated app test: $fn", sub {
 209             do $fn;
 210         };
 211     }
 212 }
 213
 214 sub create_ok {
 215     my ($type, $name) = @_;
 216     runperl( File::Spec->catdir('script', 'testapp_create.pl'), $type, $name,
 217         "'script/testapp_create.pl $type $name' ok");
 218     test_fn(File::Spec->catdir('t', sprintf("%s_%s.t", lc $type, $name)));
 219 }