t/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4
   5 use Test::More;
   6 use DBIx::Class::Schema::Loader;
   7 use DBI;
   8
   9 sub new {
  10     my $class = shift;
  11
  12     my $self;
  13
  14     if( ref($_[0]) eq 'HASH') {
  15        my $args = shift;
  16        $self = { (%$args) };
  17     }
  18     else {
  19        $self = { @_ };
  20     }
  21
  22     # Only MySQL uses this
  23     $self->{innodb} ||= '';
  24
  25     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  26
  27     return bless $self => $class;
  28 }
  29
  30 sub skip_tests {
  31     my ($self, $why) = @_;
  32
  33     plan skip_all => $why;
  34 }
  35
  36 sub run_tests {
  37     my $self = shift;
  38
  39     plan tests => 27;
  40
  41     $self->create();
  42
  43     my $schema_class = 'DBIXCSL_Test_' . $self->{vendor} . '::Schema';
  44
  45     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  46
  47     my %loader_opts = (
  48         dsn           => $self->{dsn},
  49         user          => $self->{user},
  50         password      => $self->{password},
  51         constraint    => '^(?:\S+\.)?(?i:loader_test)[0-9]+$',
  52         relationships => 1,
  53         debug         => $debug,
  54     );
  55
  56     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  57     $loader_opts{drop_db_schema} = $self->{drop_db_schema} if $self->{drop_db_schema};
  58
  59     eval qq{
  60         package $schema_class;
  61         use base qw/DBIx::Class::Schema::Loader/;
  62
  63         __PACKAGE__->load_from_connection(\%loader_opts);
  64     };
  65     ok(!$@, "Loader initialization failed: $@");
  66
  67     my $conn = $schema_class->connect($self->{dsn},$self->{user},$self->{password});
  68
  69     my $moniker1 = $conn->moniker('loader_test1');
  70     my $rsobj1 = $conn->resultset($moniker1);
  71     my $moniker2 = $conn->moniker('loader_test2');
  72     my $rsobj2 = $conn->resultset($moniker2);
  73
  74     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
  75     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
  76
  77     my $obj    = $rsobj1->find(1);
  78     is( $obj->id,  1 );
  79     is( $obj->dat, "foo" );
  80     is( $rsobj2->count, 4 );
  81
  82     my ($obj2) = $rsobj2->find( dat => 'bbb' );
  83     is( $obj2->id, 2 );
  84
  85     SKIP: {
  86         skip $self->{skip_rels}, 20 if $self->{skip_rels};
  87
  88         my $moniker3 = $conn->moniker('loader_test3');
  89         my $rsobj3 = $conn->resultset($moniker3);
  90         my $moniker4 = $conn->moniker('loader_test4');
  91         my $rsobj4 = $conn->resultset($moniker4);
  92         my $moniker5 = $conn->moniker('loader_test5');
  93         my $rsobj5 = $conn->resultset($moniker5);
  94         my $moniker6 = $conn->moniker('loader_test6');
  95         my $rsobj6 = $conn->resultset($moniker6);
  96         my $moniker7 = $conn->moniker('loader_test7');
  97         my $rsobj7 = $conn->resultset($moniker7);
  98         my $moniker8 = $conn->moniker('loader_test8');
  99         my $rsobj8 = $conn->resultset($moniker8);
 100         my $moniker9 = $conn->moniker('loader_test9');
 101         my $rsobj9 = $conn->resultset($moniker9);
 102
 103         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 104         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 105         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 106         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 107         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 108         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 109         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 110
 111         # basic rel test
 112         my $obj4 = $rsobj4->find(123);
 113         isa_ok( $obj4->fkid, "$schema_class\::$moniker3");
 114
 115         # fk def in comments should not be parsed
 116         my $obj5 = $rsobj5->find( id1 => 1, id2 => 1 );
 117         is( ref( $obj5->id2 ), '' );
 118
 119         # mulit-col fk def (works for some, not others...)
 120         my $obj6 = $rsobj6->find(1);
 121         isa_ok( $obj6->loader_test2, "$schema_class\::$moniker2" );
 122         SKIP: {
 123             skip "Multi-column FKs are only half-working for this vendor", 1
 124                 unless $self->{multi_fk_broken};
 125             is( ref( $obj6->id2 ), '' );
 126         }
 127
 128         # fk that references a non-pk key (UNIQUE)
 129         my $obj8 = $rsobj8->find(1);
 130         isa_ok( $obj8->loader_test7, "$schema_class\::$moniker7" );
 131
 132         # from Chisel's tests...
 133         SKIP: {
 134             if($self->{vendor} =~ /sqlite/i) {
 135                 skip 'SQLite cannot do the advanced tests', 8;
 136             }
 137
 138             my $moniker10 = $conn->moniker('loader_test10');
 139             my $rsobj10 = $conn->resultset($moniker10);
 140             my $moniker11 = $conn->moniker('loader_test11');
 141             my $rsobj11 = $conn->resultset($moniker11);
 142
 143             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 144             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 145
 146             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 147
 148             $obj10->update();
 149             ok( defined $obj10, '$obj10 is defined' );
 150
 151             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 152             $obj11->update();
 153             ok( defined $obj11, '$obj11 is defined' );
 154
 155             eval {
 156                 my $obj10_2 = $obj11->loader_test10;
 157                 $obj10_2->loader_test11( $obj11->id11() );
 158                 $obj10_2->update();
 159             };
 160             is($@, '', 'No errors after eval{}');
 161
 162             SKIP: {
 163                 skip 'Previous eval block failed', 3
 164                     unless ($@ eq '');
 165
 166                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 167                 is( $results->count(), 1,
 168                     'One $rsobj10 returned from search' );
 169
 170                 my $obj10_3 = $results->first();
 171                 isa_ok( $obj10_3, "$schema_class\::$moniker10" );
 172                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 173                     'found same $rsobj11 object we expected' );
 174             }
 175         }
 176     }
 177 }
 178
 179 sub dbconnect {
 180     my ($self, $complain) = @_;
 181
 182     my $dbh = DBI->connect(
 183          $self->{dsn}, $self->{user},
 184          $self->{password},
 185          {
 186              RaiseError => $complain,
 187              PrintError => $complain,
 188              AutoCommit => 1,
 189          }
 190     );
 191
 192     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 193
 194     return $dbh;
 195 }
 196
 197 sub create {
 198     my $self = shift;
 199
 200     my @statements = (
 201         qq{
 202             CREATE TABLE loader_test1 (
 203                 id $self->{auto_inc_pk},
 204                 dat VARCHAR(32)
 205             ) $self->{innodb};
 206         },
 207
 208         q{ INSERT INTO loader_test1 (dat) VALUES('foo'); },
 209         q{ INSERT INTO loader_test1 (dat) VALUES('bar'); },
 210         q{ INSERT INTO loader_test1 (dat) VALUES('baz'); },
 211
 212         qq{
 213             CREATE TABLE loader_test2 (
 214                 id $self->{auto_inc_pk},
 215                 dat VARCHAR(32)
 216             ) $self->{innodb};
 217         },
 218
 219         q{ INSERT INTO loader_test2 (dat) VALUES('aaa'); },
 220         q{ INSERT INTO loader_test2 (dat) VALUES('bbb'); },
 221         q{ INSERT INTO loader_test2 (dat) VALUES('ccc'); },
 222         q{ INSERT INTO loader_test2 (dat) VALUES('ddd'); },
 223     );
 224
 225     my @statements_reltests = (
 226         qq{
 227             CREATE TABLE loader_test3 (
 228                 id INTEGER NOT NULL PRIMARY KEY,
 229                 dat VARCHAR(32)
 230             ) $self->{innodb};
 231         },
 232
 233         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa'); },
 234         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb'); },
 235         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc'); },
 236         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd'); },
 237
 238         qq{
 239             CREATE TABLE loader_test4 (
 240                 id INTEGER NOT NULL PRIMARY KEY,
 241                 fkid INTEGER NOT NULL,
 242                 dat VARCHAR(32),
 243                 FOREIGN KEY (fkid) REFERENCES loader_test3 (id)
 244             ) $self->{innodb};
 245         },
 246
 247         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa'); },
 248         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb'); },
 249         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc'); },
 250         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd'); },
 251
 252         qq{
 253             CREATE TABLE loader_test5 (
 254                 id1 INTEGER NOT NULL,
 255                 id2 INTEGER NOT NULL, -- , id2 INTEGER REFERENCES loader_test1,
 256                 dat VARCHAR(8),
 257                 PRIMARY KEY (id1,id2)
 258             ) $self->{innodb};
 259         },
 260
 261         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa'); },
 262
 263         qq{
 264             CREATE TABLE loader_test6 (
 265                 id $self->{auto_inc_pk},
 266                 id2 INTEGER,
 267                 loader_test2 INTEGER,
 268                 dat VARCHAR(8),
 269                 FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id),
 270                 FOREIGN KEY (id, id2 ) REFERENCES loader_test5 (id1,id2)
 271             ) $self->{innodb};
 272         },
 273
 274         (q{ INSERT INTO loader_test6 (id2,loader_test2,dat) } .
 275          q{ VALUES (1,1,'aaa'); }),
 276
 277         qq{
 278             CREATE TABLE loader_test7 (
 279                 id INTEGER NOT NULL PRIMARY KEY,
 280                 id2 VARCHAR(8) NOT NULL UNIQUE,
 281                 dat VARCHAR(8)
 282             ) $self->{innodb};
 283         },
 284
 285         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb'); },
 286
 287         qq{
 288             CREATE TABLE loader_test8 (
 289                 id INTEGER NOT NULL PRIMARY KEY,
 290                 loader_test7 VARCHAR(8) NOT NULL,
 291                 dat VARCHAR(8),
 292                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 293             ) $self->{innodb};
 294         },
 295
 296         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 297          q{ VALUES (1,'aaa','bbb'); }),
 298
 299         qq{
 300             CREATE TABLE loader_test9 (
 301                 loader_test9 VARCHAR(8) NOT NULL
 302             ) $self->{innodb};
 303         },
 304     );
 305
 306     my @statements_advanced = (
 307         qq{
 308             CREATE TABLE loader_test10 (
 309                 id10 $self->{auto_inc_pk},
 310                 subject VARCHAR(8),
 311                 loader_test11 INTEGER
 312             ) $self->{innodb};
 313         },
 314
 315         qq{
 316             CREATE TABLE loader_test11 (
 317                 id11 $self->{auto_inc_pk},
 318                 message VARCHAR(8) DEFAULT 'foo',
 319                 loader_test10 INTEGER,
 320                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 321             ) $self->{innodb};
 322         },
 323
 324         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 325          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 326          q{ REFERENCES loader_test11 (id11); }),
 327     );
 328
 329     $self->drop_tables;
 330
 331     $self->{created} = 1;
 332
 333     my $dbh = $self->dbconnect(1);
 334     $dbh->do($_) for (@statements);
 335     unless($self->{skip_rels}) {
 336         # hack for now, since DB2 doesn't like inline comments, and we need
 337         # to test one for mysql, which works on everyone else...
 338         # this all needs to be refactored anyways.
 339         if($self->{vendor} =~ /DB2/i) {
 340             @statements_reltests = map { s/--.*\n//; $_ } @statements_reltests;
 341         }
 342         $dbh->do($_) for (@statements_reltests);
 343         unless($self->{vendor} =~ /sqlite/i) {
 344             $dbh->do($_) for (@statements_advanced);
 345         }
 346     }
 347     $dbh->disconnect();
 348 }
 349
 350 sub drop_tables {
 351     my $self = shift;
 352
 353     return unless $self->{created};
 354
 355     my @tables = qw/
 356         loader_test1
 357         loader_test2
 358     /;
 359
 360     my @tables_reltests = qw/
 361         loader_test4
 362         loader_test3
 363         loader_test6
 364         loader_test5
 365         loader_test8
 366         loader_test7
 367         loader_test9
 368     /;
 369
 370     my @tables_advanced = qw/
 371         loader_test11
 372         loader_test10
 373     /;
 374
 375     my $drop_fk_mysql =
 376         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 377
 378     my $drop_fk =
 379         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 380
 381     my $dbh = $self->dbconnect(0);
 382
 383     unless($self->{skip_rels}) {
 384         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 385         unless($self->{vendor} =~ /sqlite/i) {
 386             if($self->{vendor} =~ /mysql/i) {
 387                 $dbh->do($drop_fk_mysql);
 388             }
 389             else {
 390                 $dbh->do($drop_fk);
 391             }
 392             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 393         }
 394     }
 395     $dbh->do("DROP TABLE $_") for (@tables);
 396     $dbh->disconnect;
 397 }
 398
 399 sub DESTROY { shift->drop_tables; }
 400
 401 1;