t/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4
   5 use Test::More;
   6 use DBIx::Class::Schema::Loader;
   7 use DBI;
   8
   9 sub new {
  10     my $class = shift;
  11
  12     my $self;
  13
  14     if( ref($_[0]) eq 'HASH') {
  15        my $args = shift;
  16        $self = { (%$args) };
  17     }
  18     else {
  19        $self = { @_ };
  20     }
  21
  22     # Only MySQL uses this
  23     $self->{innodb} ||= '';
  24
  25     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  26
  27     return bless $self => $class;
  28 }
  29
  30 sub skip_tests {
  31     my ($self, $why) = @_;
  32
  33     plan skip_all => $why;
  34 }
  35
  36 sub run_tests {
  37     my $self = shift;
  38
  39     plan tests => 27;
  40
  41     $self->create();
  42
  43     my $namespace = 'DBIXCSL_Test_' . $self->{vendor};
  44
  45     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  46
  47     my $schema_pkg = "$namespace\::Schema";
  48
  49     eval qq{
  50         package $schema_pkg;
  51         use base qw/DBIx::Class::Schema::Loader/;
  52
  53         __PACKAGE__->load_from_connection(
  54             dsn           => "$self->{dsn}",
  55             user          => "$self->{user}",
  56             password      => "$self->{password}",
  57             namespace     => "$namespace",
  58             constraint    => '^loader_test.*',
  59             relationships => 1,
  60             debug         => "$debug",
  61         );
  62     };
  63     ok(!$@, "Loader initialization failed: $@");
  64
  65     my $conn = $schema_pkg->connect($self->{dsn},$self->{user},$self->{passwd});
  66
  67     my $moniker1 = $conn->moniker('loader_test1');
  68     my $rsobj1 = $conn->resultset($moniker1);
  69     my $moniker2 = $conn->moniker('loader_test2');
  70     my $rsobj2 = $conn->resultset($moniker2);
  71
  72     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
  73     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
  74
  75     my $obj    = $rsobj1->find(1);
  76     is( $obj->id,  1 );
  77     is( $obj->dat, "foo" );
  78     is( $rsobj2->count, 4 );
  79
  80     my ($obj2) = $rsobj2->find( dat => 'bbb' );
  81     is( $obj2->id, 2 );
  82
  83     SKIP: {
  84         skip $self->{skip_rels}, 20 if $self->{skip_rels};
  85
  86         my $moniker3 = $conn->moniker('loader_test3');
  87         my $rsobj3 = $conn->resultset($moniker3);
  88         my $moniker4 = $conn->moniker('loader_test4');
  89         my $rsobj4 = $conn->resultset($moniker4);
  90         my $moniker5 = $conn->moniker('loader_test5');
  91         my $rsobj5 = $conn->resultset($moniker5);
  92         my $moniker6 = $conn->moniker('loader_test6');
  93         my $rsobj6 = $conn->resultset($moniker6);
  94         my $moniker7 = $conn->moniker('loader_test7');
  95         my $rsobj7 = $conn->resultset($moniker7);
  96         my $moniker8 = $conn->moniker('loader_test8');
  97         my $rsobj8 = $conn->resultset($moniker8);
  98         my $moniker9 = $conn->moniker('loader_test9');
  99         my $rsobj9 = $conn->resultset($moniker9);
 100
 101         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 102         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 103         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 104         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 105         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 106         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 107         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 108
 109         # basic rel test
 110         my $obj4 = $rsobj4->find(123);
 111         isa_ok( $obj4->fkid, "$namespace\::$moniker3");
 112
 113         # fk def in comments should not be parsed
 114         my $obj5 = $rsobj5->find( id1 => 1, id2 => 1 );
 115         is( ref( $obj5->id2 ), '' );
 116
 117         # mulit-col fk def (works for some, not others...)
 118         my $obj6 = $rsobj6->find(1);
 119         isa_ok( $obj6->loader_test2, "$namespace\::$moniker2" );
 120         SKIP: {
 121             skip "Multi-column FKs are only half-working for this vendor", 1
 122                 unless $self->{multi_fk_broken};
 123             is( ref( $obj6->id2 ), '' );
 124         }
 125
 126         # fk that references a non-pk key (UNIQUE)
 127         my $obj8 = $rsobj8->find(1);
 128         isa_ok( $obj8->loader_test7, "$namespace\::$moniker7" );
 129
 130         # from Chisel's tests...
 131         SKIP: {
 132             if($self->{vendor} =~ /sqlite/i) {
 133                 skip 'SQLite cannot do the advanced tests', 8;
 134             }
 135
 136             my $moniker10 = $conn->moniker('loader_test10');
 137             my $rsobj10 = $conn->resultset($moniker10);
 138             my $moniker11 = $conn->moniker('loader_test11');
 139             my $rsobj11 = $conn->resultset($moniker11);
 140
 141             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 142             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 143
 144             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 145
 146             $obj10->update();
 147             ok( defined $obj10, '$obj10 is defined' );
 148
 149             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 150             $obj11->update();
 151             ok( defined $obj11, '$obj11 is defined' );
 152
 153             eval {
 154                 my $obj10_2 = $obj11->loader_test10;
 155                 $obj10_2->loader_test11( $obj11->id11() );
 156                 $obj10_2->update();
 157             };
 158             is($@, '', 'No errors after eval{}');
 159
 160             SKIP: {
 161                 skip 'Previous eval block failed', 3
 162                     unless ($@ eq '');
 163
 164                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 165                 is( $results->count(), 1,
 166                     'One $rsobj10 returned from search' );
 167
 168                 my $obj10_3 = $results->first();
 169                 isa_ok( $obj10_3, "$namespace\::$moniker10" );
 170                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 171                     'found same $rsobj11 object we expected' );
 172             }
 173         }
 174     }
 175 }
 176
 177 sub dbconnect {
 178     my ($self, $complain) = @_;
 179
 180     DBI->connect(
 181          $self->{dsn}, $self->{user},
 182          $self->{password},
 183          {
 184              RaiseError => $complain,
 185              PrintError => $complain,
 186              AutoCommit => 1,
 187          }
 188     );
 189 }
 190
 191 sub create {
 192     my $self = shift;
 193
 194     my @statements = (
 195         qq{
 196             CREATE TABLE loader_test1 (
 197                 id $self->{auto_inc_pk},
 198                 dat VARCHAR(32)
 199             ) $self->{innodb};
 200         },
 201
 202         q{ INSERT INTO loader_test1 (dat) VALUES('foo'); },
 203         q{ INSERT INTO loader_test1 (dat) VALUES('bar'); },
 204         q{ INSERT INTO loader_test1 (dat) VALUES('baz'); },
 205
 206         qq{
 207             CREATE TABLE loader_test2 (
 208                 id $self->{auto_inc_pk},
 209                 dat VARCHAR(32)
 210             ) $self->{innodb};
 211         },
 212
 213         q{ INSERT INTO loader_test2 (dat) VALUES('aaa'); },
 214         q{ INSERT INTO loader_test2 (dat) VALUES('bbb'); },
 215         q{ INSERT INTO loader_test2 (dat) VALUES('ccc'); },
 216         q{ INSERT INTO loader_test2 (dat) VALUES('ddd'); },
 217     );
 218
 219     my @statements_reltests = (
 220         qq{
 221             CREATE TABLE loader_test3 (
 222                 id INTEGER NOT NULL PRIMARY KEY,
 223                 dat VARCHAR(32)
 224             ) $self->{innodb};
 225         },
 226
 227         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa'); },
 228         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb'); },
 229         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc'); },
 230         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd'); },
 231
 232         qq{
 233             CREATE TABLE loader_test4 (
 234                 id INTEGER NOT NULL PRIMARY KEY,
 235                 fkid INTEGER NOT NULL,
 236                 dat VARCHAR(32),
 237                 FOREIGN KEY (fkid) REFERENCES loader_test3 (id)
 238             ) $self->{innodb};
 239         },
 240
 241         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa'); },
 242         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb'); },
 243         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc'); },
 244         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd'); },
 245
 246         qq{
 247             CREATE TABLE loader_test5 (
 248                 id1 INTEGER NOT NULL,
 249                 id2 INTEGER NOT NULL, -- , id2 INTEGER REFERENCES loader_test1,
 250                 dat VARCHAR(8),
 251                 PRIMARY KEY (id1,id2)
 252             ) $self->{innodb};
 253         },
 254
 255         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa'); },
 256
 257         qq{
 258             CREATE TABLE loader_test6 (
 259                 id $self->{auto_inc_pk},
 260                 id2 INTEGER,
 261                 loader_test2 INTEGER,
 262                 dat VARCHAR(8),
 263                 FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id),
 264                 FOREIGN KEY (id, id2 ) REFERENCES loader_test5 (id1,id2)
 265             ) $self->{innodb};
 266         },
 267
 268         (q{ INSERT INTO loader_test6 (id2,loader_test2,dat) } .
 269          q{ VALUES (1,1,'aaa'); }),
 270
 271         qq{
 272             CREATE TABLE loader_test7 (
 273                 id INTEGER NOT NULL PRIMARY KEY,
 274                 id2 VARCHAR(8) NOT NULL UNIQUE,
 275                 dat VARCHAR(8)
 276             ) $self->{innodb};
 277         },
 278
 279         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb'); },
 280
 281         qq{
 282             CREATE TABLE loader_test8 (
 283                 id INTEGER NOT NULL PRIMARY KEY,
 284                 loader_test7 VARCHAR(8) NOT NULL,
 285                 dat VARCHAR(8),
 286                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 287             ) $self->{innodb};
 288         },
 289
 290         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 291          q{ VALUES (1,'aaa','bbb'); }),
 292
 293         qq{
 294             CREATE TABLE loader_test9 (
 295                 loader_test9 VARCHAR(8) NOT NULL
 296             ) $self->{innodb};
 297         },
 298     );
 299
 300     my @statements_advanced = (
 301         qq{
 302             CREATE TABLE loader_test10 (
 303                 id10 $self->{auto_inc_pk},
 304                 subject VARCHAR(8),
 305                 loader_test11 INTEGER
 306             ) $self->{innodb};
 307         },
 308
 309         qq{
 310             CREATE TABLE loader_test11 (
 311                 id11 $self->{auto_inc_pk},
 312                 message VARCHAR(8) DEFAULT 'foo',
 313                 loader_test10 INTEGER NOT NULL,
 314                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 315             ) $self->{innodb};
 316         },
 317
 318         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 319          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 320          q{ REFERENCES loader_test11 (id11); }),
 321     );
 322
 323     $self->{created} = 1;
 324
 325     my $dbh = $self->dbconnect(1);
 326     $dbh->do($_) for (@statements);
 327     unless($self->{skip_rels}) {
 328         $dbh->do($_) for (@statements_reltests);
 329         unless($self->{vendor} =~ /sqlite/i) {
 330             $dbh->do($_) for (@statements_advanced);
 331         }
 332     }
 333     $dbh->disconnect();
 334 }
 335
 336 sub DESTROY {
 337     my $self = shift;
 338
 339     return unless $self->{created};
 340
 341     my @tables = qw/
 342         loader_test1
 343         loader_test2
 344     /;
 345
 346     my @tables_reltests = qw/
 347         loader_test4
 348         loader_test3
 349         loader_test6
 350         loader_test5
 351         loader_test8
 352         loader_test7
 353         loader_test9
 354     /;
 355
 356     my @tables_advanced = qw/
 357         loader_test11
 358         loader_test10
 359     /;
 360
 361     my $drop_fk_mysql =
 362         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk;};
 363
 364     my $drop_fk =
 365         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk;};
 366
 367     my $dbh = $self->dbconnect(0);
 368
 369     unless($self->{skip_rels}) {
 370         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 371         unless($self->{vendor} =~ /sqlite/i) {
 372             if($self->{vendor} =~ /mysql/i) {
 373                 $dbh->do($drop_fk_mysql);
 374             }
 375             else {
 376                 $dbh->do($drop_fk);
 377             }
 378             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 379         }
 380     }
 381     $dbh->do("DROP TABLE $_") for (@tables);
 382     $dbh->disconnect();
 383 }
 384
 385 1;