t/comp/use.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     $INC{"feature.pm"} = 1; # so we don't attempt to load feature.pm
   7 }
   8
   9 print "1..68\n";
  10
  11 # Can't require test.pl, as we're testing the use/require mechanism here.
  12
  13 my $test = 1;
  14
  15 sub _ok {
  16     my ($type, $got, $expected, $name) = @_;
  17
  18     my $result;
  19     if ($type eq 'is') {
  20         $result = $got eq $expected;
  21     } elsif ($type eq 'isnt') {
  22         $result = $got ne $expected;
  23     } elsif ($type eq 'like') {
  24         $result = $got =~ $expected;
  25     } else {
  26         die "Unexpected type '$type'$name";
  27     }
  28     if ($result) {
  29         if ($name) {
  30             print "ok $test - $name\n";
  31         } else {
  32             print "ok $test\n";
  33         }
  34     } else {
  35         if ($name) {
  36             print "not ok $test - $name\n";
  37         } else {
  38             print "not ok $test\n";
  39         }
  40         my @caller = caller(2);
  41         print "# Failed test at $caller[1] line $caller[2]\n";
  42         print "# Got      '$got'\n";
  43         if ($type eq 'is') {
  44             print "# Expected '$expected'\n";
  45         } elsif ($type eq 'isnt') {
  46             print "# Expected not '$expected'\n";
  47         } elsif ($type eq 'like') {
  48             print "# Expected $expected\n";
  49         }
  50     }
  51     $test = $test + 1;
  52     $result;
  53 }
  54
  55 sub like ($$;$) {
  56     _ok ('like', @_);
  57 }
  58 sub is ($$;$) {
  59     _ok ('is', @_);
  60 }
  61 sub isnt ($$;$) {
  62     _ok ('isnt', @_);
  63 }
  64
  65 eval "use 5.000";       # implicit semicolon
  66 is ($@, '');
  67
  68 eval "use 5.000;";
  69 is ($@, '');
  70
  71 eval "use 6.000;";
  72 like ($@, qr/Perl v6\.0\.0 required--this is only \Q$^V\E, stopped/);
  73
  74 eval "no 6.000;";
  75 is ($@, '');
  76
  77 eval "no 5.000;";
  78 like ($@, qr/Perls since v5\.0\.0 too modern--this is \Q$^V\E, stopped/);
  79
  80 eval "use 5.6;";
  81 like ($@, qr/Perl v5\.600\.0 required \(did you mean v5\.6\.0\?\)--this is only \Q$^V\E, stopped/);
  82
  83 eval "use 5.8;";
  84 like ($@, qr/Perl v5\.800\.0 required \(did you mean v5\.8\.0\?\)--this is only \Q$^V\E, stopped/);
  85
  86 eval "use 5.9;";
  87 like ($@, qr/Perl v5\.900\.0 required \(did you mean v5\.9\.0\?\)--this is only \Q$^V\E, stopped/);
  88
  89 eval "use 5.10;";
  90 like ($@, qr/Perl v5\.100\.0 required \(did you mean v5\.10\.0\?\)--this is only \Q$^V\E, stopped/);
  91
  92 eval "use 5.11;";
  93 like ($@, qr/Perl v5\.110\.0 required \(did you mean v5\.11\.0\?\)--this is only \Q$^V\E, stopped/);
  94
  95 eval sprintf "use %.6f;", $];
  96 is ($@, '');
  97
  98
  99 eval sprintf "use %.6f;", $] - 0.000001;
 100 is ($@, '');
 101
 102 eval sprintf("use %.6f;", $] + 1);
 103 like ($@, qr/Perl v6.\d+.\d+ required--this is only \Q$^V\E, stopped/);
 104
 105 eval sprintf "use %.6f;", $] + 0.00001;
 106 like ($@, qr/Perl v5.\d+.\d+ required--this is only \Q$^V\E, stopped/);
 107
 108 # check that "use 5.11.0" (and higher) loads strictures
 109 eval 'use 5.11.0; ${"foo"} = "bar";';
 110 like ($@, qr/Can't use string \("foo"\) as a SCALAR ref while "strict refs" in use/);
 111 # but that they can be disabled
 112 eval 'use 5.11.0; no strict "refs"; ${"foo"} = "bar";';
 113 is ($@, "");
 114 # and they are properly scoped
 115 eval '{use 5.11.0;} ${"foo"} = "bar";';
 116 is ($@, "");
 117 # and this doesn't happen with require
 118 eval 'require 5.11.0; ${"foo"} = "bar";';
 119 is ($@, "");
 120
 121 { use lib }     # check that subparse saves pending tokens
 122
 123 local $lib::VERSION = 1.0;
 124
 125 eval "use lib 0.9";
 126 is ($@, '');
 127
 128 eval "use lib 1.0";
 129 is ($@, '');
 130
 131 eval "use lib 1.01";
 132 isnt ($@, '');
 133
 134
 135 eval "use lib 0.9 qw(fred)";
 136 is ($@, '');
 137
 138 if ($^O eq 'MacOS') {
 139     is($INC[0], ":fred:");
 140 } else {
 141     is($INC[0], "fred");
 142 }
 143
 144 eval "use lib 1.0 qw(joe)";
 145 is ($@, '');
 146
 147
 148 if ($^O eq 'MacOS') {
 149     is($INC[0], ":joe:");
 150 } else {
 151     is($INC[0], "joe");
 152 }
 153
 154
 155 eval "use lib 1.01 qw(freda)";
 156 isnt($@, '');
 157
 158 if ($^O eq 'MacOS') {
 159     isnt($INC[0], ":freda:");
 160 } else {
 161     isnt($INC[0], "freda");
 162 }
 163
 164 {
 165     local $lib::VERSION = 35.36;
 166     eval "use lib v33.55";
 167     is ($@, '');
 168
 169     eval "use lib v100.105";
 170     like ($@, qr/lib version v100.105.0 required--this is only version v35\.360\.0/);
 171
 172     eval "use lib 33.55";
 173     is ($@, '');
 174
 175     eval "use lib 100.105";
 176     like ($@, qr/lib version 100.105 required--this is only version 35.36/);
 177
 178     local $lib::VERSION = '35.36';
 179     eval "use lib v33.55";
 180     like ($@, '');
 181
 182     eval "use lib v100.105";
 183     like ($@, qr/lib version v100.105.0 required--this is only version v35\.360\.0/);
 184
 185     eval "use lib 33.55";
 186     is ($@, '');
 187
 188     eval "use lib 100.105";
 189     like ($@, qr/lib version 100.105 required--this is only version 35.36/);
 190
 191     local $lib::VERSION = v35.36;
 192     eval "use lib v33.55";
 193     is ($@, '');
 194
 195     eval "use lib v100.105";
 196     like ($@, qr/lib version v100.105.0 required--this is only version v35\.36\.0/);
 197
 198     eval "use lib 33.55";
 199     is ($@, '');
 200
 201     eval "use lib 100.105";
 202     like ($@, qr/lib version 100.105 required--this is only version v35.36/);
 203 }
 204
 205
 206 {
 207     # Regression test for patch 14937:
 208     #   Check that a .pm file with no package or VERSION doesn't core.
 209     open F, ">xxx$$.pm" or die "Cannot open xxx$$.pm: $!\n";
 210     print F "1;\n";
 211     close F;
 212     eval "use lib '.'; use xxx$$ 3;";
 213     like ($@, qr/^xxx$$ defines neither package nor VERSION--version check failed at/);
 214     unlink "xxx$$.pm";
 215 }
 216
 217 my @ver = split /\./, sprintf "%vd", $^V;
 218
 219 foreach my $index (-3..+3) {
 220     foreach my $v (0, 1) {
 221         my @parts = @ver;
 222         if ($index) {
 223             if ($index < 0) {
 224                 # Jiggle one of the parts down
 225                 --$parts[-$index - 1];
 226                 if ($parts[-$index - 1] < 0) {
 227                     # perl's version number ends with '.0'
 228                     $parts[-$index - 1] = 0;
 229                     $parts[-$index - 2] -= 2;
 230                 }
 231             } else {
 232                 # Jiggle one of the parts up
 233                 ++$parts[$index - 1];
 234             }
 235         }
 236         my $v_version = sprintf "v%d.%d.%d", @parts;
 237         my $version;
 238         if ($v) {
 239             $version = $v_version;
 240         } else {
 241             $version = $parts[0] + $parts[1] / 1000 + $parts[2] / 1000000;
 242         }
 243
 244         eval "use $version";
 245         if ($index > 0) {
 246             # The future
 247             like ($@,
 248                   qr/Perl $v_version required--this is only \Q$^V\E, stopped/,
 249                   "use $version");
 250         } else {
 251             # The present or past
 252             is ($@, '', "use $version");
 253         }
 254
 255         eval "no $version";
 256         if ($index <= 0) {
 257             # The present or past
 258             like ($@,
 259                   qr/Perls since $v_version too modern--this is \Q$^V\E, stopped/,
 260                   "no $version");
 261         } else {
 262             # future
 263             is ($@, '', "no $version");
 264         }
 265     }
 266 }
 267