t/backcompat/0.04006/lib/dbixcsl_common_tests.pm

   1 package dbixcsl_common_tests;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use DBIx::Class::Schema::Loader;
   8 use DBI;
   9
  10 sub new {
  11     my $class = shift;
  12
  13     my $self;
  14
  15     if( ref($_[0]) eq 'HASH') {
  16        my $args = shift;
  17        $self = { (%$args) };
  18     }
  19     else {
  20        $self = { @_ };
  21     }
  22
  23     # Only MySQL uses this
  24     $self->{innodb} ||= '';
  25
  26     $self->{verbose} = $ENV{TEST_VERBOSE} || 0;
  27
  28     return bless $self => $class;
  29 }
  30
  31 sub skip_tests {
  32     my ($self, $why) = @_;
  33
  34     plan skip_all => $why;
  35 }
  36
  37 sub _monikerize {
  38     my $name = shift;
  39     return 'LoaderTest2X' if $name =~ /^loader_test2$/i;
  40     return undef;
  41 }
  42
  43 sub run_tests {
  44     my $self = shift;
  45
  46     plan tests => 88;
  47
  48     $self->create();
  49
  50     my $schema_class = 'DBIXCSL_Test::Schema';
  51
  52     my $debug = ($self->{verbose} > 1) ? 1 : 0;
  53
  54     my @connect_info = ( $self->{dsn}, $self->{user}, $self->{password} );
  55     my %loader_opts = (
  56         constraint              => qr/^(?:\S+\.)?loader_test[0-9]+$/i,
  57         relationships           => 1,
  58         additional_classes      => 'TestAdditional',
  59         additional_base_classes => 'TestAdditionalBase',
  60         left_base_classes       => [ qw/TestLeftBase/ ],
  61         components              => [ qw/TestComponent/ ],
  62         inflect_plural          => { loader_test4 => 'loader_test4zes' },
  63         inflect_singular        => { fkid => 'fkid_singular' },
  64         moniker_map             => \&_monikerize,
  65         debug                   => $debug,
  66     );
  67
  68     $loader_opts{db_schema} = $self->{db_schema} if $self->{db_schema};
  69     eval { require Class::Inspector };
  70     if($@) {
  71         $self->{_no_rs_components} = 1;
  72     }
  73     else {
  74         $loader_opts{resultset_components} = [ qw/TestRSComponent/ ];
  75     }
  76
  77     {
  78        my @loader_warnings;
  79        local $SIG{__WARN__} = sub { push(@loader_warnings, $_[0]); };
  80         eval qq{
  81             package $schema_class;
  82             use base qw/DBIx::Class::Schema::Loader/;
  83
  84             __PACKAGE__->loader_options(\%loader_opts);
  85             __PACKAGE__->connection(\@connect_info);
  86         };
  87         ok(!$@, "Loader initialization") or diag $@;
  88
  89         my $warn_count = 0;
  90         $warn_count++ if grep /ResultSetManager/, @loader_warnings;
  91
  92         if($self->{skip_rels}) {
  93             is(scalar(@loader_warnings), $warn_count)
  94               or diag "Did not get the expected 0 warnings.  Warnings are: "
  95                 . join('',@loader_warnings);
  96             ok(1);
  97         }
  98         else {
  99             $warn_count++;
 100             is(scalar(@loader_warnings), $warn_count)
 101               or diag "Did not get the expected 1 warning.  Warnings are: "
 102                 . join('',@loader_warnings);
 103             is(grep(/loader_test9 has no primary key/, @loader_warnings), 1);
 104         }
 105     }
 106
 107     my $conn = $schema_class->clone;
 108     my $monikers = {};
 109     my $classes = {};
 110     foreach my $source_name ($schema_class->sources) {
 111         my $table_name = $schema_class->source($source_name)->from;
 112         $monikers->{$table_name} = $source_name;
 113         $classes->{$table_name} = $schema_class . q{::} . $source_name;
 114     }
 115
 116     my $moniker1 = $monikers->{loader_test1};
 117     my $class1   = $classes->{loader_test1};
 118     my $rsobj1   = $conn->resultset($moniker1);
 119
 120     my $moniker2 = $monikers->{loader_test2};
 121     my $class2   = $classes->{loader_test2};
 122     my $rsobj2   = $conn->resultset($moniker2);
 123
 124     my $moniker23 = $monikers->{LOADER_TEST23};
 125     my $class23   = $classes->{LOADER_TEST23};
 126     my $rsobj23   = $conn->resultset($moniker1);
 127
 128     my $moniker24 = $monikers->{LoAdEr_test24};
 129     my $class24   = $classes->{LoAdEr_test24};
 130     my $rsobj24   = $conn->resultset($moniker2);
 131
 132     isa_ok( $rsobj1, "DBIx::Class::ResultSet" );
 133     isa_ok( $rsobj2, "DBIx::Class::ResultSet" );
 134     isa_ok( $rsobj23, "DBIx::Class::ResultSet" );
 135     isa_ok( $rsobj24, "DBIx::Class::ResultSet" );
 136
 137     my @columns_lt2 = $class2->columns;
 138     is($columns_lt2[0], 'id', "Column Ordering 0");
 139     is($columns_lt2[1], 'dat', "Column Ordering 1");
 140     is($columns_lt2[2], 'dat2', "Column Ordering 2");
 141
 142     my %uniq1 = $class1->unique_constraints;
 143     my $uniq1_test = 0;
 144     foreach my $ucname (keys %uniq1) {
 145         my $cols_arrayref = $uniq1{$ucname};
 146         if(@$cols_arrayref == 1 && $cols_arrayref->[0] eq 'dat') {
 147            $uniq1_test = 1;
 148            last;
 149         }
 150     }
 151     ok($uniq1_test) or diag "Unique constraints not working";
 152
 153     my %uniq2 = $class2->unique_constraints;
 154     my $uniq2_test = 0;
 155     foreach my $ucname (keys %uniq2) {
 156         my $cols_arrayref = $uniq2{$ucname};
 157         if(@$cols_arrayref == 2
 158            && $cols_arrayref->[0] eq 'dat2'
 159            && $cols_arrayref->[1] eq 'dat') {
 160             $uniq2_test = 2;
 161             last;
 162         }
 163     }
 164     ok($uniq2_test) or diag "Multi-col unique constraints not working";
 165
 166     is($moniker2, 'LoaderTest2X', "moniker_map testing");
 167
 168     {
 169         my ($skip_tab, $skip_tabo, $skip_taba, $skip_cmeth,
 170             $skip_rsmeth, $skip_tcomp, $skip_trscomp);
 171
 172         can_ok( $class1, 'test_additional_base' ) or $skip_tab = 1;
 173         can_ok( $class1, 'test_additional_base_override' ) or $skip_tabo = 1;
 174         can_ok( $class1, 'test_additional_base_additional' ) or $skip_taba = 1;
 175         can_ok( $class1, 'dbix_class_testcomponent' ) or $skip_tcomp = 1;
 176         can_ok( $class1, 'loader_test1_classmeth' ) or $skip_cmeth = 1;
 177
 178         TODO: {
 179             local $TODO = "Not yet supported by ResultSetManger code";
 180             can_ok( $rsobj1, 'loader_test1_rsmeth' ) or $skip_rsmeth = 1;
 181         }
 182
 183         SKIP: {
 184             skip "Pre-requisite test failed", 1 if $skip_tab;
 185             is( $class1->test_additional_base, "test_additional_base",
 186                 "Additional Base method" );
 187         }
 188
 189         SKIP: {
 190             skip "Pre-requisite test failed", 1 if $skip_tabo;
 191             is( $class1->test_additional_base_override,
 192                 "test_left_base_override",
 193                 "Left Base overrides Additional Base method" );
 194         }
 195
 196         SKIP: {
 197             skip "Pre-requisite test failed", 1 if $skip_taba;
 198             is( $class1->test_additional_base_additional, "test_additional",
 199                 "Additional Base can use Additional package method" );
 200         }
 201
 202         SKIP: {
 203             skip "Pre-requisite test failed", 1 if $skip_tcomp;
 204             is( $class1->dbix_class_testcomponent,
 205                 'dbix_class_testcomponent works' );
 206         }
 207
 208         SKIP: {
 209             skip "These two tests need Class::Inspector installed", 2
 210                      if $self->{_no_rs_components};
 211             can_ok($rsobj1, 'dbix_class_testrscomponent') or $skip_trscomp = 1;
 212             SKIP: {
 213                 skip "Pre-requisite test failed", 1 if $skip_trscomp;
 214                 is( $rsobj1->dbix_class_testrscomponent,
 215                     'dbix_class_testrscomponent works' );
 216             }
 217         }
 218
 219         SKIP: {
 220             skip "Pre-requisite test failed", 1 if $skip_cmeth;
 221             is( $class1->loader_test1_classmeth, 'all is well' );
 222         }
 223
 224         # XXX put this back in when the TODO above works...
 225         #SKIP: {
 226         #    skip "Pre-requisite test failed", 1 if $skip_rsmeth;
 227         #    is( $rsobj1->loader_test1_rsmeth, 'all is still well' );
 228         #}
 229     }
 230
 231
 232     my $obj    = $rsobj1->find(1);
 233     is( $obj->id,  1 );
 234     is( $obj->dat, "foo" );
 235     is( $rsobj2->count, 4 );
 236     my $saved_id;
 237     eval {
 238         my $new_obj1 = $rsobj1->create({ dat => 'newthing' });
 239         $saved_id = $new_obj1->id;
 240     };
 241     ok(!$@) or diag "Died during create new record using a PK::Auto key: $@";
 242     ok($saved_id) or diag "Failed to get PK::Auto-generated id";
 243
 244     my $new_obj1 = $rsobj1->search({ dat => 'newthing' })->first;
 245     ok($new_obj1) or diag "Cannot find newly inserted PK::Auto record";
 246     is($new_obj1->id, $saved_id);
 247
 248     my ($obj2) = $rsobj2->search({ dat => 'bbb' })->first;
 249     is( $obj2->id, 2 );
 250
 251     SKIP: {
 252         skip $self->{skip_rels}, 50 if $self->{skip_rels};
 253
 254         my $moniker3 = $monikers->{loader_test3};
 255         my $class3   = $classes->{loader_test3};
 256         my $rsobj3   = $conn->resultset($moniker3);
 257
 258         my $moniker4 = $monikers->{loader_test4};
 259         my $class4   = $classes->{loader_test4};
 260         my $rsobj4   = $conn->resultset($moniker4);
 261
 262         my $moniker5 = $monikers->{loader_test5};
 263         my $class5   = $classes->{loader_test5};
 264         my $rsobj5   = $conn->resultset($moniker5);
 265
 266         my $moniker6 = $monikers->{loader_test6};
 267         my $class6   = $classes->{loader_test6};
 268         my $rsobj6   = $conn->resultset($moniker6);
 269
 270         my $moniker7 = $monikers->{loader_test7};
 271         my $class7   = $classes->{loader_test7};
 272         my $rsobj7   = $conn->resultset($moniker7);
 273
 274         my $moniker8 = $monikers->{loader_test8};
 275         my $class8   = $classes->{loader_test8};
 276         my $rsobj8   = $conn->resultset($moniker8);
 277
 278         my $moniker9 = $monikers->{loader_test9};
 279         my $class9   = $classes->{loader_test9};
 280         my $rsobj9   = $conn->resultset($moniker9);
 281
 282         my $moniker16 = $monikers->{loader_test16};
 283         my $class16   = $classes->{loader_test16};
 284         my $rsobj16   = $conn->resultset($moniker16);
 285
 286         my $moniker17 = $monikers->{loader_test17};
 287         my $class17   = $classes->{loader_test17};
 288         my $rsobj17   = $conn->resultset($moniker17);
 289
 290         my $moniker18 = $monikers->{loader_test18};
 291         my $class18   = $classes->{loader_test18};
 292         my $rsobj18   = $conn->resultset($moniker18);
 293
 294         my $moniker19 = $monikers->{loader_test19};
 295         my $class19   = $classes->{loader_test19};
 296         my $rsobj19   = $conn->resultset($moniker19);
 297
 298         my $moniker20 = $monikers->{loader_test20};
 299         my $class20   = $classes->{loader_test20};
 300         my $rsobj20   = $conn->resultset($moniker20);
 301
 302         my $moniker21 = $monikers->{loader_test21};
 303         my $class21   = $classes->{loader_test21};
 304         my $rsobj21   = $conn->resultset($moniker21);
 305
 306         my $moniker22 = $monikers->{loader_test22};
 307         my $class22   = $classes->{loader_test22};
 308         my $rsobj22   = $conn->resultset($moniker22);
 309
 310         my $moniker25 = $monikers->{loader_test25};
 311         my $class25   = $classes->{loader_test25};
 312         my $rsobj25   = $conn->resultset($moniker25);
 313
 314         my $moniker26 = $monikers->{loader_test26};
 315         my $class26   = $classes->{loader_test26};
 316         my $rsobj26   = $conn->resultset($moniker26);
 317
 318         isa_ok( $rsobj3, "DBIx::Class::ResultSet" );
 319         isa_ok( $rsobj4, "DBIx::Class::ResultSet" );
 320         isa_ok( $rsobj5, "DBIx::Class::ResultSet" );
 321         isa_ok( $rsobj6, "DBIx::Class::ResultSet" );
 322         isa_ok( $rsobj7, "DBIx::Class::ResultSet" );
 323         isa_ok( $rsobj8, "DBIx::Class::ResultSet" );
 324         isa_ok( $rsobj9, "DBIx::Class::ResultSet" );
 325         isa_ok( $rsobj16, "DBIx::Class::ResultSet" );
 326         isa_ok( $rsobj17, "DBIx::Class::ResultSet" );
 327         isa_ok( $rsobj18, "DBIx::Class::ResultSet" );
 328         isa_ok( $rsobj19, "DBIx::Class::ResultSet" );
 329         isa_ok( $rsobj20, "DBIx::Class::ResultSet" );
 330         isa_ok( $rsobj21, "DBIx::Class::ResultSet" );
 331         isa_ok( $rsobj22, "DBIx::Class::ResultSet" );
 332         isa_ok( $rsobj25, "DBIx::Class::ResultSet" );
 333         isa_ok( $rsobj26, "DBIx::Class::ResultSet" );
 334
 335         # basic rel test
 336         my $obj4 = $rsobj4->find(123);
 337         isa_ok( $obj4->fkid_singular, $class3);
 338
 339         my $obj3 = $rsobj3->find(1);
 340         my $rs_rel4 = $obj3->search_related('loader_test4zes');
 341         isa_ok( $rs_rel4->first, $class4);
 342
 343         # find on multi-col pk
 344         my $obj5 = $rsobj5->find({id1 => 1, id2 => 1});
 345         is( $obj5->id2, 1 );
 346
 347         # mulit-col fk def
 348         my $obj6 = $rsobj6->find(1);
 349         isa_ok( $obj6->loader_test2, $class2);
 350         isa_ok( $obj6->loader_test5, $class5);
 351
 352         # fk that references a non-pk key (UNIQUE)
 353         my $obj8 = $rsobj8->find(1);
 354         isa_ok( $obj8->loader_test7, $class7);
 355
 356         # test double-fk 17 ->-> 16
 357         my $obj17 = $rsobj17->find(33);
 358
 359         my $rs_rel16_one = $obj17->loader16_one;
 360         isa_ok($rs_rel16_one, $class16);
 361         is($rs_rel16_one->dat, 'y16');
 362
 363         my $rs_rel16_two = $obj17->loader16_two;
 364         isa_ok($rs_rel16_two, $class16);
 365         is($rs_rel16_two->dat, 'z16');
 366
 367         my $obj16 = $rsobj16->find(2);
 368         my $rs_rel17 = $obj16->search_related('loader_test17_loader16_ones');
 369         isa_ok($rs_rel17->first, $class17);
 370         is($rs_rel17->first->id, 3);
 371
 372         # XXX test m:m 18 <- 20 -> 19
 373
 374         # XXX test double-fk m:m 21 <- 22 -> 21
 375
 376         # test double multi-col fk 26 -> 25
 377         my $obj26 = $rsobj26->find(33);
 378
 379         my $rs_rel25_one = $obj26->loader_test25_id_rel1;
 380         isa_ok($rs_rel25_one, $class25);
 381         is($rs_rel25_one->dat, 'x25');
 382
 383         my $rs_rel25_two = $obj26->loader_test25_id_rel2;
 384         isa_ok($rs_rel25_two, $class25);
 385         is($rs_rel25_two->dat, 'y25');
 386
 387         my $obj25 = $rsobj25->find(3,42);
 388         my $rs_rel26 = $obj25->search_related('loader_test26_id_rel1s');
 389         isa_ok($rs_rel26->first, $class26);
 390         is($rs_rel26->first->id, 3);
 391
 392         # from Chisel's tests...
 393         SKIP: {
 394             if($self->{vendor} =~ /sqlite/i) {
 395                 skip 'SQLite cannot do the advanced tests', 8;
 396             }
 397
 398             my $moniker10 = $monikers->{loader_test10};
 399             my $class10   = $classes->{loader_test10};
 400             my $rsobj10   = $conn->resultset($moniker10);
 401
 402             my $moniker11 = $monikers->{loader_test11};
 403             my $class11   = $classes->{loader_test11};
 404             my $rsobj11   = $conn->resultset($moniker11);
 405
 406             isa_ok( $rsobj10, "DBIx::Class::ResultSet" );
 407             isa_ok( $rsobj11, "DBIx::Class::ResultSet" );
 408
 409             my $obj10 = $rsobj10->create({ subject => 'xyzzy' });
 410
 411             $obj10->update();
 412             ok( defined $obj10, '$obj10 is defined' );
 413
 414             my $obj11 = $rsobj11->create({ loader_test10 => $obj10->id() });
 415             $obj11->update();
 416             ok( defined $obj11, '$obj11 is defined' );
 417
 418             eval {
 419                 my $obj10_2 = $obj11->loader_test10;
 420                 $obj10_2->loader_test11( $obj11->id11() );
 421                 $obj10_2->update();
 422             };
 423             is($@, '', 'No errors after eval{}');
 424
 425             SKIP: {
 426                 skip 'Previous eval block failed', 3
 427                     unless ($@ eq '');
 428
 429                 my $results = $rsobj10->search({ subject => 'xyzzy' });
 430                 is( $results->count(), 1,
 431                     'One $rsobj10 returned from search' );
 432
 433                 my $obj10_3 = $results->first();
 434                 isa_ok( $obj10_3, $class10 );
 435                 is( $obj10_3->loader_test11()->id(), $obj11->id(),
 436                     'found same $rsobj11 object we expected' );
 437             }
 438         }
 439
 440         SKIP: {
 441             skip 'This vendor cannot do inline relationship definitions', 5
 442                 if $self->{no_inline_rels};
 443
 444             my $moniker12 = $monikers->{loader_test12};
 445             my $class12   = $classes->{loader_test12};
 446             my $rsobj12   = $conn->resultset($moniker12);
 447
 448             my $moniker13 = $monikers->{loader_test13};
 449             my $class13   = $classes->{loader_test13};
 450             my $rsobj13   = $conn->resultset($moniker13);
 451
 452             isa_ok( $rsobj12, "DBIx::Class::ResultSet" );
 453             isa_ok( $rsobj13, "DBIx::Class::ResultSet" );
 454
 455             my $obj13 = $rsobj13->find(1);
 456             isa_ok( $obj13->id, $class12 );
 457             isa_ok( $obj13->loader_test12, $class12);
 458             isa_ok( $obj13->dat, $class12);
 459         }
 460
 461         SKIP: {
 462             skip 'This vendor cannot do out-of-line implicit rel defs', 3
 463                 if $self->{no_implicit_rels};
 464             my $moniker14 = $monikers->{loader_test14};
 465             my $class14   = $classes->{loader_test14};
 466             my $rsobj14   = $conn->resultset($moniker14);
 467
 468             my $moniker15 = $monikers->{loader_test15};
 469             my $class15   = $classes->{loader_test15};
 470             my $rsobj15   = $conn->resultset($moniker15);
 471
 472             isa_ok( $rsobj14, "DBIx::Class::ResultSet" );
 473             isa_ok( $rsobj15, "DBIx::Class::ResultSet" );
 474
 475             my $obj15 = $rsobj15->find(1);
 476             isa_ok( $obj15->loader_test14, $class14 );
 477         }
 478     }
 479
 480     # rescan test
 481     SKIP: {
 482         skip $self->{skip_rels}, 4 if $self->{skip_rels};
 483
 484         my @statements_rescan = (
 485             qq{
 486                 CREATE TABLE loader_test30 (
 487                     id INTEGER NOT NULL PRIMARY KEY,
 488                     loader_test2 INTEGER NOT NULL,
 489                     FOREIGN KEY (loader_test2) REFERENCES loader_test2 (id)
 490                 ) $self->{innodb}
 491             },
 492             q{ INSERT INTO loader_test30 (id,loader_test2) VALUES(123, 1) },
 493             q{ INSERT INTO loader_test30 (id,loader_test2) VALUES(321, 2) },
 494         );
 495
 496         my $dbh = $self->dbconnect(1);
 497         $dbh->do($_) for @statements_rescan;
 498         $dbh->disconnect;
 499
 500         my @new = $conn->rescan;
 501         is(scalar(@new), 1);
 502         is($new[0], 'LoaderTest30');
 503
 504         my $rsobj30   = $conn->resultset('LoaderTest30');
 505         isa_ok($rsobj30, 'DBIx::Class::ResultSet');
 506         my $obj30 = $rsobj30->find(123);
 507         isa_ok( $obj30->loader_test2, $class2);
 508     }
 509 }
 510
 511 sub dbconnect {
 512     my ($self, $complain) = @_;
 513
 514     my $dbh = DBI->connect(
 515          $self->{dsn}, $self->{user},
 516          $self->{password},
 517          {
 518              RaiseError => $complain,
 519              PrintError => $complain,
 520              AutoCommit => 1,
 521          }
 522     );
 523
 524     die "Failed to connect to database: $DBI::errstr" if !$dbh;
 525
 526     return $dbh;
 527 }
 528
 529 sub create {
 530     my $self = shift;
 531
 532     $self->{_created} = 1;
 533
 534     my $make_auto_inc = $self->{auto_inc_cb} || sub {};
 535     my @statements = (
 536         qq{
 537             CREATE TABLE loader_test1 (
 538                 id $self->{auto_inc_pk},
 539                 dat VARCHAR(32) NOT NULL UNIQUE
 540             ) $self->{innodb}
 541         },
 542         $make_auto_inc->(qw/loader_test1 id/),
 543
 544         q{ INSERT INTO loader_test1 (dat) VALUES('foo') },
 545         q{ INSERT INTO loader_test1 (dat) VALUES('bar') },
 546         q{ INSERT INTO loader_test1 (dat) VALUES('baz') },
 547
 548         qq{
 549             CREATE TABLE loader_test2 (
 550                 id $self->{auto_inc_pk},
 551                 dat VARCHAR(32) NOT NULL,
 552                 dat2 VARCHAR(32) NOT NULL,
 553                 UNIQUE (dat2, dat)
 554             ) $self->{innodb}
 555         },
 556         $make_auto_inc->(qw/loader_test2 id/),
 557
 558         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('aaa', 'zzz') },
 559         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('bbb', 'yyy') },
 560         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ccc', 'xxx') },
 561         q{ INSERT INTO loader_test2 (dat, dat2) VALUES('ddd', 'www') },
 562
 563         qq{
 564             CREATE TABLE LOADER_TEST23 (
 565                 ID INTEGER NOT NULL PRIMARY KEY,
 566                 DAT VARCHAR(32) NOT NULL UNIQUE
 567             ) $self->{innodb}
 568         },
 569
 570         qq{
 571             CREATE TABLE LoAdEr_test24 (
 572                 iD INTEGER NOT NULL PRIMARY KEY,
 573                 DaT VARCHAR(32) NOT NULL UNIQUE
 574             ) $self->{innodb}
 575         },
 576     );
 577
 578     my @statements_reltests = (
 579         qq{
 580             CREATE TABLE loader_test3 (
 581                 id INTEGER NOT NULL PRIMARY KEY,
 582                 dat VARCHAR(32)
 583             ) $self->{innodb}
 584         },
 585
 586         q{ INSERT INTO loader_test3 (id,dat) VALUES(1,'aaa') },
 587         q{ INSERT INTO loader_test3 (id,dat) VALUES(2,'bbb') },
 588         q{ INSERT INTO loader_test3 (id,dat) VALUES(3,'ccc') },
 589         q{ INSERT INTO loader_test3 (id,dat) VALUES(4,'ddd') },
 590
 591         qq{
 592             CREATE TABLE loader_test4 (
 593                 id INTEGER NOT NULL PRIMARY KEY,
 594                 fkid INTEGER NOT NULL,
 595                 dat VARCHAR(32),
 596                 FOREIGN KEY( fkid ) REFERENCES loader_test3 (id)
 597             ) $self->{innodb}
 598         },
 599
 600         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(123,1,'aaa') },
 601         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(124,2,'bbb') },
 602         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(125,3,'ccc') },
 603         q{ INSERT INTO loader_test4 (id,fkid,dat) VALUES(126,4,'ddd') },
 604
 605         qq{
 606             CREATE TABLE loader_test5 (
 607                 id1 INTEGER NOT NULL,
 608                 iD2 INTEGER NOT NULL,
 609                 dat VARCHAR(8),
 610                 PRIMARY KEY (id1,id2)
 611             ) $self->{innodb}
 612         },
 613
 614         q{ INSERT INTO loader_test5 (id1,id2,dat) VALUES (1,1,'aaa') },
 615
 616         qq{
 617             CREATE TABLE loader_test6 (
 618                 id INTEGER NOT NULL PRIMARY KEY,
 619                 Id2 INTEGER,
 620                 loader_test2 INTEGER,
 621                 dat VARCHAR(8),
 622                 FOREIGN KEY (loader_test2)  REFERENCES loader_test2 (id),
 623                 FOREIGN KEY(id,Id2) REFERENCES loader_test5 (id1,iD2)
 624             ) $self->{innodb}
 625         },
 626
 627         (q{ INSERT INTO loader_test6 (id, id2,loader_test2,dat) } .
 628          q{ VALUES (1, 1,1,'aaa') }),
 629
 630         qq{
 631             CREATE TABLE loader_test7 (
 632                 id INTEGER NOT NULL PRIMARY KEY,
 633                 id2 VARCHAR(8) NOT NULL UNIQUE,
 634                 dat VARCHAR(8)
 635             ) $self->{innodb}
 636         },
 637
 638         q{ INSERT INTO loader_test7 (id,id2,dat) VALUES (1,'aaa','bbb') },
 639
 640         qq{
 641             CREATE TABLE loader_test8 (
 642                 id INTEGER NOT NULL PRIMARY KEY,
 643                 loader_test7 VARCHAR(8) NOT NULL,
 644                 dat VARCHAR(8),
 645                 FOREIGN KEY (loader_test7) REFERENCES loader_test7 (id2)
 646             ) $self->{innodb}
 647         },
 648
 649         (q{ INSERT INTO loader_test8 (id,loader_test7,dat) } .
 650          q{ VALUES (1,'aaa','bbb') }),
 651
 652         qq{
 653             CREATE TABLE loader_test9 (
 654                 loader_test9 VARCHAR(8) NOT NULL
 655             ) $self->{innodb}
 656         },
 657
 658         qq{
 659             CREATE TABLE loader_test16 (
 660                 id INTEGER NOT NULL PRIMARY KEY,
 661                 dat  VARCHAR(8)
 662             ) $self->{innodb}
 663         },
 664
 665         qq{ INSERT INTO loader_test16 (id,dat) VALUES (2,'x16') },
 666         qq{ INSERT INTO loader_test16 (id,dat) VALUES (4,'y16') },
 667         qq{ INSERT INTO loader_test16 (id,dat) VALUES (6,'z16') },
 668
 669         qq{
 670             CREATE TABLE loader_test17 (
 671                 id INTEGER NOT NULL PRIMARY KEY,
 672                 loader16_one INTEGER,
 673                 loader16_two INTEGER,
 674                 FOREIGN KEY (loader16_one) REFERENCES loader_test16 (id),
 675                 FOREIGN KEY (loader16_two) REFERENCES loader_test16 (id)
 676             ) $self->{innodb}
 677         },
 678
 679         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (3, 2, 4) },
 680         qq{ INSERT INTO loader_test17 (id, loader16_one, loader16_two) VALUES (33, 4, 6) },
 681
 682         qq{
 683             CREATE TABLE loader_test18 (
 684                 id INTEGER NOT NULL PRIMARY KEY,
 685                 dat  VARCHAR(8)
 686             ) $self->{innodb}
 687         },
 688
 689         qq{ INSERT INTO loader_test18 (id,dat) VALUES (1,'x18') },
 690         qq{ INSERT INTO loader_test18 (id,dat) VALUES (2,'y18') },
 691         qq{ INSERT INTO loader_test18 (id,dat) VALUES (3,'z18') },
 692
 693         qq{
 694             CREATE TABLE loader_test19 (
 695                 id INTEGER NOT NULL PRIMARY KEY,
 696                 dat  VARCHAR(8)
 697             ) $self->{innodb}
 698         },
 699
 700         qq{ INSERT INTO loader_test19 (id,dat) VALUES (4,'x19') },
 701         qq{ INSERT INTO loader_test19 (id,dat) VALUES (5,'y19') },
 702         qq{ INSERT INTO loader_test19 (id,dat) VALUES (6,'z19') },
 703
 704         qq{
 705             CREATE TABLE loader_test20 (
 706                 parent INTEGER NOT NULL,
 707                 child INTEGER NOT NULL,
 708                 PRIMARY KEY (parent, child),
 709                 FOREIGN KEY (parent) REFERENCES loader_test18 (id),
 710                 FOREIGN KEY (child) REFERENCES loader_test19 (id)
 711             ) $self->{innodb}
 712         },
 713
 714         q{ INSERT INTO loader_test20 (parent, child) VALUES (1,4) },
 715         q{ INSERT INTO loader_test20 (parent, child) VALUES (2,5) },
 716         q{ INSERT INTO loader_test20 (parent, child) VALUES (3,6) },
 717
 718         qq{
 719             CREATE TABLE loader_test21 (
 720                 id INTEGER NOT NULL PRIMARY KEY,
 721                 dat  VARCHAR(8)
 722             ) $self->{innodb}
 723         },
 724
 725         q{ INSERT INTO loader_test21 (id,dat) VALUES (7,'a21')},
 726         q{ INSERT INTO loader_test21 (id,dat) VALUES (11,'b21')},
 727         q{ INSERT INTO loader_test21 (id,dat) VALUES (13,'c21')},
 728         q{ INSERT INTO loader_test21 (id,dat) VALUES (17,'d21')},
 729
 730         qq{
 731             CREATE TABLE loader_test22 (
 732                 parent INTEGER NOT NULL,
 733                 child INTEGER NOT NULL,
 734                 PRIMARY KEY (parent, child),
 735                 FOREIGN KEY (parent) REFERENCES loader_test21 (id),
 736                 FOREIGN KEY (child) REFERENCES loader_test21 (id)
 737             ) $self->{innodb}
 738         },
 739
 740         q{ INSERT INTO loader_test22 (parent, child) VALUES (7,11)},
 741         q{ INSERT INTO loader_test22 (parent, child) VALUES (11,13)},
 742         q{ INSERT INTO loader_test22 (parent, child) VALUES (13,17)},
 743
 744         qq{
 745             CREATE TABLE loader_test25 (
 746                 id1 INTEGER NOT NULL,
 747                 id2 INTEGER NOT NULL,
 748                 dat VARCHAR(8),
 749                 PRIMARY KEY (id1,id2)
 750             ) $self->{innodb}
 751         },
 752
 753         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (33,5,'x25') },
 754         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (33,7,'y25') },
 755         q{ INSERT INTO loader_test25 (id1,id2,dat) VALUES (3,42,'z25') },
 756
 757         qq{
 758             CREATE TABLE loader_test26 (
 759                id INTEGER NOT NULL PRIMARY KEY,
 760                rel1 INTEGER NOT NULL,
 761                rel2 INTEGER NOT NULL,
 762                FOREIGN KEY (id, rel1) REFERENCES loader_test25 (id1, id2),
 763                FOREIGN KEY (id, rel2) REFERENCES loader_test25 (id1, id2)
 764             ) $self->{innodb}
 765         },
 766
 767         q{ INSERT INTO loader_test26 (id,rel1,rel2) VALUES (33,5,7) },
 768         q{ INSERT INTO loader_test26 (id,rel1,rel2) VALUES (3,42,42) },
 769     );
 770
 771     my @statements_advanced = (
 772         qq{
 773             CREATE TABLE loader_test10 (
 774                 id10 $self->{auto_inc_pk},
 775                 subject VARCHAR(8),
 776                 loader_test11 INTEGER
 777             ) $self->{innodb}
 778         },
 779         $make_auto_inc->(qw/loader_test10 id10/),
 780
 781         qq{
 782             CREATE TABLE loader_test11 (
 783                 id11 $self->{auto_inc_pk},
 784                 message VARCHAR(8) DEFAULT 'foo',
 785                 loader_test10 INTEGER,
 786                 FOREIGN KEY (loader_test10) REFERENCES loader_test10 (id10)
 787             ) $self->{innodb}
 788         },
 789         $make_auto_inc->(qw/loader_test11 id11/),
 790
 791         (q{ ALTER TABLE loader_test10 ADD CONSTRAINT } .
 792          q{ loader_test11_fk FOREIGN KEY (loader_test11) } .
 793          q{ REFERENCES loader_test11 (id11) }),
 794     );
 795
 796     my @statements_inline_rels = (
 797         qq{
 798             CREATE TABLE loader_test12 (
 799                 id INTEGER NOT NULL PRIMARY KEY,
 800                 id2 VARCHAR(8) NOT NULL UNIQUE,
 801                 dat VARCHAR(8) NOT NULL UNIQUE
 802             ) $self->{innodb}
 803         },
 804
 805         q{ INSERT INTO loader_test12 (id,id2,dat) VALUES (1,'aaa','bbb') },
 806
 807         qq{
 808             CREATE TABLE loader_test13 (
 809                 id INTEGER NOT NULL PRIMARY KEY REFERENCES loader_test12,
 810                 loader_test12 VARCHAR(8) NOT NULL REFERENCES loader_test12 (id2),
 811                 dat VARCHAR(8) REFERENCES loader_test12 (dat)
 812             ) $self->{innodb}
 813         },
 814
 815         (q{ INSERT INTO loader_test13 (id,loader_test12,dat) } .
 816          q{ VALUES (1,'aaa','bbb') }),
 817     );
 818
 819
 820     my @statements_implicit_rels = (
 821         qq{
 822             CREATE TABLE loader_test14 (
 823                 id INTEGER NOT NULL PRIMARY KEY,
 824                 dat VARCHAR(8)
 825             ) $self->{innodb}
 826         },
 827
 828         q{ INSERT INTO loader_test14 (id,dat) VALUES (123,'aaa') },
 829
 830         qq{
 831             CREATE TABLE loader_test15 (
 832                 id INTEGER NOT NULL PRIMARY KEY,
 833                 loader_test14 INTEGER NOT NULL,
 834                 FOREIGN KEY (loader_test14) REFERENCES loader_test14
 835             ) $self->{innodb}
 836         },
 837
 838         q{ INSERT INTO loader_test15 (id,loader_test14) VALUES (1,123) },
 839     );
 840
 841     $self->drop_tables;
 842
 843     my $dbh = $self->dbconnect(1);
 844
 845     # Silence annoying but harmless postgres "NOTICE:  CREATE TABLE..."
 846     local $SIG{__WARN__} = sub {
 847         my $msg = shift;
 848         print STDERR $msg unless $msg =~ m{^NOTICE:\s+CREATE TABLE};
 849     };
 850
 851     $dbh->do($_) for (@statements);
 852     unless($self->{skip_rels}) {
 853         # hack for now, since DB2 doesn't like inline comments, and we need
 854         # to test one for mysql, which works on everyone else...
 855         # this all needs to be refactored anyways.
 856         $dbh->do($_) for (@statements_reltests);
 857         unless($self->{vendor} =~ /sqlite/i) {
 858             $dbh->do($_) for (@statements_advanced);
 859         }
 860         unless($self->{no_inline_rels}) {
 861             $dbh->do($_) for (@statements_inline_rels);
 862         }
 863         unless($self->{no_implicit_rels}) {
 864             $dbh->do($_) for (@statements_implicit_rels);
 865         }
 866     }
 867     $dbh->disconnect();
 868 }
 869
 870 sub drop_tables {
 871     my $self = shift;
 872
 873     my @tables = qw/
 874         loader_test1
 875         loader_test2
 876         LOADER_TEST23
 877         LoAdEr_test24
 878     /;
 879
 880     my @tables_auto_inc = (
 881         [ qw/loader_test1 id/ ],
 882         [ qw/loader_test2 id/ ],
 883     );
 884
 885     my @tables_reltests = qw/
 886         loader_test4
 887         loader_test3
 888         loader_test6
 889         loader_test5
 890         loader_test8
 891         loader_test7
 892         loader_test9
 893         loader_test17
 894         loader_test16
 895         loader_test20
 896         loader_test19
 897         loader_test18
 898         loader_test22
 899         loader_test21
 900         loader_test26
 901         loader_test25
 902     /;
 903
 904     my @tables_advanced = qw/
 905         loader_test11
 906         loader_test10
 907     /;
 908
 909     my @tables_advanced_auto_inc = (
 910         [ qw/loader_test10 id10/ ],
 911         [ qw/loader_test11 id11/ ],
 912     );
 913
 914     my @tables_inline_rels = qw/
 915         loader_test13
 916         loader_test12
 917     /;
 918
 919     my @tables_implicit_rels = qw/
 920         loader_test15
 921         loader_test14
 922     /;
 923
 924     my @tables_rescan = qw/ loader_test30 /;
 925
 926     my $drop_fk_mysql =
 927         q{ALTER TABLE loader_test10 DROP FOREIGN KEY loader_test11_fk};
 928
 929     my $drop_fk =
 930         q{ALTER TABLE loader_test10 DROP CONSTRAINT loader_test11_fk};
 931
 932     my $dbh = $self->dbconnect(0);
 933
 934     my $drop_auto_inc = $self->{auto_inc_drop_cb} || sub {};
 935
 936     unless($self->{skip_rels}) {
 937         $dbh->do("DROP TABLE $_") for (@tables_reltests);
 938         unless($self->{vendor} =~ /sqlite/i) {
 939             if($self->{vendor} =~ /mysql/i) {
 940                 $dbh->do($drop_fk_mysql);
 941             }
 942             else {
 943                 $dbh->do($drop_fk);
 944             }
 945             $dbh->do("DROP TABLE $_") for (@tables_advanced);
 946             $dbh->do($_) for map { $drop_auto_inc->(@$_) } @tables_advanced_auto_inc;
 947         }
 948         unless($self->{no_inline_rels}) {
 949             $dbh->do("DROP TABLE $_") for (@tables_inline_rels);
 950         }
 951         unless($self->{no_implicit_rels}) {
 952             $dbh->do("DROP TABLE $_") for (@tables_implicit_rels);
 953         }
 954         $dbh->do("DROP TABLE $_") for (@tables_rescan);
 955     }
 956     $dbh->do("DROP TABLE $_") for (@tables);
 957     $dbh->do($_) for map { $drop_auto_inc->(@$_) } @tables_auto_inc;
 958     $dbh->disconnect;
 959 }
 960
 961 sub DESTROY {
 962     my $self = shift;
 963     $self->drop_tables if $self->{_created};
 964 }
 965
 966 1;