t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 $| = 1;
   9
  10 # for testing TEST only
  11 #BEGIN { require '../lib/strict.pm'; strict->import() };
  12 #BEGIN { require '../lib/warnings.pm'; warnings->import() };
  13
  14 # Let tests know they're running in the perl core.  Useful for modules
  15 # which live dual lives on CPAN.
  16 $ENV{PERL_CORE} = 1;
  17
  18 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  19 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  20 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
  21
  22 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
  23 {
  24     my @argv = ();
  25     foreach my $idx (0..$#ARGV) {
  26         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  27         $::core    = 1 if $1 eq 'core';
  28         $::verbose = 1 if $1 eq 'v';
  29         $::torture = 1 if $1 eq 'torture';
  30         $::with_utf8 = 1 if $1 eq 'utf8';
  31         $::with_utf16 = 1 if $1 eq 'utf16';
  32         $::bytecompile = 1 if $1 eq 'bytecompile';
  33         $::compile = 1 if $1 eq 'compile';
  34         $::taintwarn = 1 if $1 eq 'taintwarn';
  35         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
  36         if ($1 =~ /^deparse(,.+)?$/) {
  37             $::deparse = 1;
  38             $::deparse_opts = $1;
  39         }
  40     }
  41     @ARGV = @argv;
  42 }
  43
  44 chdir 't' if -f 't/TEST';
  45
  46 die "You need to run \"make test\" first to set things up.\n"
  47   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
  48
  49 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
  50     unless (-x 'perl.third') {
  51         unless (-x '../perl.third') {
  52             die "You need to run \"make perl.third first.\n";
  53         }
  54         else {
  55             print "Symlinking ../perl.third as perl.third...\n";
  56             die "Failed to symlink: $!\n"
  57                 unless symlink("../perl.third", "perl.third");
  58             die "Symlinked but no executable perl.third: $!\n"
  59                 unless -x 'perl.third';
  60         }
  61     }
  62 }
  63
  64 # check leakage for embedders
  65 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
  66
  67 $ENV{EMXSHELL} = 'sh';        # For OS/2
  68
  69 # Roll your own File::Find!
  70 use TestInit;
  71 use File::Spec;
  72 if ($show_elapsed_time) { require Time::HiRes }
  73 my $curdir = File::Spec->curdir;
  74 my $updir  = File::Spec->updir;
  75
  76 sub _find_tests {
  77     my($dir) = @_;
  78     opendir DIR, $dir or die "Trouble opening $dir: $!";
  79     foreach my $f (sort { $a cmp $b } readdir DIR) {
  80         next if $f eq $curdir or $f eq $updir or
  81             $f =~ /^(?:CVS|RCS|SCCS|\.svn)$/;
  82
  83         my $fullpath = File::Spec->catfile($dir, $f);
  84
  85         _find_tests($fullpath) if -d $fullpath;
  86         $fullpath = VMS::Filespec::unixify($fullpath) if $^O eq 'VMS';
  87         push @ARGV, $fullpath if $f =~ /\.t$/;
  88     }
  89 }
  90
  91 sub _quote_args {
  92     my ($args) = @_;
  93     my $argstring = '';
  94
  95     foreach (split(/\s+/,$args)) {
  96        # In VMS protect with doublequotes because otherwise
  97        # DCL will lowercase -- unless already doublequoted.
  98        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
  99        $argstring .= ' ' . $_;
 100     }
 101     return $argstring;
 102 }
 103
 104 sub _populate_hash {
 105     return map {$_, 1} split /\s+/, $_[0];
 106 }
 107
 108 unless (@ARGV) {
 109     foreach my $dir (qw(base comp cmd run io op uni)) {
 110         _find_tests($dir);
 111     }
 112     _find_tests("lib") unless $::core;
 113     # Config.pm may be broken for make minitest. And this is only a refinement
 114     # for skipping tests on non-default builds, so it is allowed to fail.
 115     # What we want to to is make a list of extensions which we did not build.
 116     my $configsh = File::Spec->catfile($updir, "config.sh");
 117     my %skip;
 118     if (-f $configsh) {
 119         my (%extensions, %known_extensions);
 120         open FH, $configsh or die "Can't open $configsh: $!";
 121         while (<FH>) {
 122             if (/^extensions=['"](.*)['"]$/) {
 123                 # Deliberate string interpolation to avoid triggering possible
 124                 # $1 resetting bugs.
 125                 %extensions = _populate_hash ("$1");
 126             }
 127             elsif (/^known_extensions=['"](.*)['"]$/) {
 128                 %known_extensions = _populate_hash ($1);
 129             }
 130         }
 131         if (%extensions) {
 132             if (%known_extensions) {
 133                 foreach (keys %known_extensions) {
 134                     $skip{$_}++ unless $extensions{$_};
 135                 }
 136             } else {
 137                 warn "No known_extensions line found in $configsh";
 138             }
 139         } else {
 140             warn "No extensions line found in $configsh";
 141         }
 142     }
 143     my $mani = File::Spec->catfile($updir, "MANIFEST");
 144     if (open(MANI, $mani)) {
 145         while (<MANI>) { # similar code in t/harness
 146             if (m!^(ext/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 147                 my $t = $1;
 148                 my $extension = $2;
 149                 if (!$::core || $t =~ m!^lib/[a-z]!)
 150                 {
 151                     if (defined $extension) {
 152                         $extension =~ s!/t$!!;
 153                         # XXX Do I want to warn that I'm skipping these?
 154                         next if $skip{$extension};
 155                     }
 156                     my $path = File::Spec->catfile($updir, $t);
 157                     push @ARGV, $path;
 158                     $::path_to_name{$path} = $t;
 159                 }
 160             }
 161         }
 162         close MANI;
 163     } else {
 164         warn "$0: cannot open $mani: $!\n";
 165     }
 166     unless ($::core) {
 167         _find_tests('pod');
 168         _find_tests('x2p');
 169         _find_tests('japh') if $::torture;
 170     }
 171 }
 172
 173 # Tests known to cause infinite loops for the perlcc tests.
 174 # %::infinite = ( 'comp/require.t', 1, 'op/bop.t', 1, 'lib/hostname.t', 1 );
 175 %::infinite = ();
 176
 177 if ($::deparse) {
 178     _testprogs('deparse', '',   @ARGV);
 179 }
 180 elsif( $::compile ) {
 181     _testprogs('compile', '',   @ARGV);
 182 }
 183 elsif( $::bytecompile ) {
 184     _testprogs('bytecompile', '', @ARGV);
 185 }
 186 elsif ($::with_utf16) {
 187     for my $e (0, 1) {
 188         for my $b (0, 1) {
 189             print STDERR "# ENDIAN $e BOM $b\n";
 190             my @UARGV;
 191             for my $a (@ARGV) {
 192                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 193                 my $f = $e ? "v" : "n";
 194                 push @UARGV, $u;
 195                 unlink($u);
 196                 if (open(A, $a)) {
 197                     if (open(U, ">$u")) {
 198                         print U pack("$f", 0xFEFF) if $b;
 199                         while (<A>) {
 200                             print U pack("$f*", unpack("C*", $_));
 201                         }
 202                         close(U);
 203                     }
 204                     close(A);
 205                 }
 206             }
 207             _testprogs('perl', '', @UARGV);
 208             unlink(@UARGV);
 209         }
 210     }
 211 }
 212 else {
 213     _testprogs('compile', '',   @ARGV) if -e "../testcompile";
 214     _testprogs('perl',    '',   @ARGV);
 215 }
 216
 217 sub _testprogs {
 218     my ($type, $args, @tests) = @_;
 219
 220     print <<'EOT' if ($type eq 'compile');
 221 ------------------------------------------------------------------------------
 222 TESTING COMPILER
 223 ------------------------------------------------------------------------------
 224 EOT
 225
 226     print <<'EOT' if ($type eq 'deparse');
 227 ------------------------------------------------------------------------------
 228 TESTING DEPARSER
 229 ------------------------------------------------------------------------------
 230 EOT
 231
 232     print <<EOT if ($type eq 'bytecompile');
 233 ------------------------------------------------------------------------------
 234 TESTING BYTECODE COMPILER
 235 ------------------------------------------------------------------------------
 236 EOT
 237
 238     $ENV{PERLCC_TIMEOUT} = 120
 239           if ($type eq 'compile' && !$ENV{PERLCC_TIMEOUT});
 240
 241     $::bad_files = 0;
 242
 243     foreach my $t (@tests) {
 244       unless (exists $::path_to_name{$t}) {
 245         my $tname = File::Spec->catfile('t',$t);
 246         $tname = VMS::Filespec::unixify($tname) if $^O eq 'VMS';
 247         $::path_to_name{$t} = $tname;
 248       }
 249     }
 250     my $maxlen = 0;
 251     foreach (@::path_to_name{@tests}) {
 252         s/\.\w+\z/./;
 253         my $len = length ;
 254         $maxlen = $len if $len > $maxlen;
 255     }
 256     # + 3 : we want three dots between the test name and the "ok"
 257     my $dotdotdot = $maxlen + 3 ;
 258     my $valgrind = 0;
 259     my $valgrind_log = 'current.valgrind';
 260     my $total_files = @tests;
 261     my $good_files = 0;
 262     my $tested_files  = 0;
 263     my $totmax = 0;
 264     my %failed_tests;
 265
 266     while (my $test = shift @tests) {
 267         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 268
 269         if ( $::infinite{$test} && $type eq 'compile' ) {
 270             print STDERR "$test creates infinite loop! Skipping.\n";
 271             next;
 272         }
 273         if ($test =~ /^$/) {
 274             next;
 275         }
 276         if ($type eq 'deparse') {
 277             if ($test eq "comp/redef.t") {
 278                 # Redefinition happens at compile time
 279                 next;
 280             }
 281             elsif ($test =~ m{lib/Switch/t/}) {
 282                 # B::Deparse doesn't support source filtering
 283                 next;
 284             }
 285         }
 286         my $te = $::path_to_name{$test} . '.'
 287                     x ($dotdotdot - length($::path_to_name{$test}));
 288
 289         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 290             print $te;
 291             $te = '';
 292         }
 293
 294         # XXX DAPM %OVER not defined anywhere
 295         # $test = $OVER{$test} if exists $OVER{$test};
 296
 297         open(SCRIPT,"<",$test) or die "Can't run $test.\n";
 298         $_ = <SCRIPT>;
 299         close(SCRIPT) unless ($type eq 'deparse');
 300         if ($::with_utf16) {
 301             $_ =~ tr/\0//d;
 302         }
 303         my $switch;
 304         if (/#!.*\bperl.*\s-\w*([tT])/) {
 305             $switch = qq{"-$1"};
 306         }
 307         else {
 308             if ($::taintwarn) {
 309                 # not all tests are expected to pass with this option
 310                 $switch = '"-t"';
 311             }
 312             else {
 313                 $switch = '';
 314             }
 315         }
 316
 317         my $test_executable; # for 'compile' tests
 318         my $file_opts = "";
 319         if ($type eq 'deparse') {
 320             # Look for #line directives which change the filename
 321             while (<SCRIPT>) {
 322                 $file_opts .= ",-f$3$4"
 323                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 324             }
 325             close(SCRIPT);
 326         }
 327
 328         my $utf8 = $::with_utf8 ? '-I../lib -Mutf8' : '';
 329         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
 330         if ($type eq 'deparse') {
 331             my $deparse_cmd =
 332                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,-sv1.,".
 333                 "-l$::deparse_opts$file_opts ".
 334                 "$test > $test.dp ".
 335                 "&& ./perl $testswitch $switch -I../lib $test.dp |";
 336             open(RESULTS, $deparse_cmd)
 337                 or print "can't deparse '$deparse_cmd': $!.\n";
 338         }
 339         elsif ($type eq 'bytecompile') {
 340             my ($pwd, $null);
 341             if( $^O eq 'MSWin32') {
 342                 $pwd = `cd`;
 343                 $null = 'nul';
 344             } else {
 345                 $pwd = `pwd`;
 346                 $null = '/dev/null';
 347             }
 348             chomp $pwd;
 349             my $perl = $ENV{PERL} || "$pwd/perl";
 350             my $bswitch = "-MO=Bytecode,-H,-TI,-s$pwd/$test,";
 351             $bswitch .= "-TF$test.plc,"
 352                 if $test =~ m(chdir|pod/|CGI/t/carp|lib/DB);
 353             $bswitch .= "-k,"
 354                 if $test =~ m(deparse|terse|ext/Storable/t/code);
 355             $bswitch .= "-b,"
 356                 if $test =~ m(op/getpid);
 357             my $bytecompile_cmd =
 358                 "$perl $testswitch $switch -I../lib $bswitch".
 359                 "-o$test.plc $test 2>$null &&".
 360                 "$perl $testswitch $switch -I../lib $utf8 $test.plc |";
 361             open(RESULTS,$bytecompile_cmd)
 362                 or print "can't byte-compile '$bytecompile_cmd': $!.\n";
 363         }
 364         elsif ($type eq 'perl') {
 365             my $perl = $ENV{PERL} || './perl';
 366             my $redir = $^O eq 'VMS' ? '2>&1' : '';
 367             if ($ENV{PERL_VALGRIND}) {
 368                 my $valgrind = $ENV{VALGRIND} // 'valgrind';
 369                 $perl = "$valgrind --suppressions=perl.supp --leak-check=yes "
 370                                 . "--leak-resolution=high --show-reachable=yes "
 371                                 . "--num-callers=50 --log-fd=3 $perl";
 372                 $redir = "3>$valgrind_log";
 373             }
 374             my $run = "$perl" . _quote_args("$testswitch $switch $utf8")
 375                               . " $test $redir|";
 376             open(RESULTS,$run) or print "can't run '$run': $!.\n";
 377         }
 378         else {
 379             my $compile_cmd;
 380             my $pl2c = "$testswitch -I../lib ../utils/perlcc --testsuite " .
 381               # -O9 for good measure, -fcog is broken ATM
 382                        "$switch -Wb=-O9,-fno-cog -L .. " .
 383                        "-I \".. ../lib/CORE\" $args $utf8 $test -o ";
 384
 385             if( $^O eq 'MSWin32' ) {
 386                 $test_executable = "$test.exe";
 387                 # hopefully unused name...
 388                 open HACK, "> xweghyz.pl";
 389                 print HACK <<EOT;
 390 #!./perl
 391
 392 open HACK, '.\\perl $pl2c $test_executable |';
 393 # cl.exe prints the name of the .c file on stdout (\%^\$^#)
 394 while(<HACK>) {m/^\\w+\\.[cC]\$/ && next;print}
 395 open HACK, '$test_executable |';
 396 while(<HACK>) {print}
 397 EOT
 398                 close HACK;
 399                 $compile_cmd = 'xweghyz.pl |';
 400             }
 401             else {
 402                 $test_executable = "$test.plc";
 403                 $compile_cmd
 404                     = "./perl $pl2c $test_executable && $test_executable |";
 405             }
 406             unlink $test_executable if -f $test_executable;
 407             open(RESULTS, $compile_cmd)
 408                 or print "can't compile '$compile_cmd': $!.\n";
 409         }
 410         # Our environment may force us to use UTF-8, but we can't be sure that
 411         # anything we're reading from will be generating (well formed) UTF-8
 412         # This may not be the best way - possibly we should unset ${^OPEN} up
 413         # top?
 414         binmode RESULTS;
 415
 416         my $failure;
 417         my $next = 0;
 418         my $seen_leader = 0;
 419         my $seen_ok = 0;
 420         my $trailing_leader = 0;
 421         my $max;
 422         my %todo;
 423         while (<RESULTS>) {
 424             next if /^\s*$/; # skip blank lines
 425             if ($::verbose) {
 426                 print $_;
 427             }
 428             unless (/^\#/) {
 429                 if ($trailing_leader) {
 430                     # shouldn't be anything following a postfix 1..n
 431                     $failure = 'FAILED--extra output after trailing 1..n';
 432                     last;
 433                 }
 434                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 435                     if ($seen_leader) {
 436                         $failure = 'FAILED--seen duplicate leader';
 437                         last;
 438                     }
 439                     $max = $1;
 440                     %todo = map { $_ => 1 } split / /, $3 if $3;
 441                     $totmax += $max;
 442                     $tested_files++;
 443                     if ($seen_ok) {
 444                         # 1..n appears at end of file
 445                         $trailing_leader = 1;
 446                         if ($next != $max) {
 447                             $failure = "FAILED--expected $max tests, saw $next";
 448                             last;
 449                         }
 450                     }
 451                     else {
 452                         $next = 0;
 453                     }
 454                     $seen_leader = 1;
 455                 }
 456                 else {
 457                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 458                         unless ($seen_leader) {
 459                             unless ($seen_ok) {
 460                                 $next = 0;
 461                             }
 462                         }
 463                         $seen_ok = 1;
 464                         $next++;
 465                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 466                         $num = $next unless $num;
 467
 468                         if ($num == $next) {
 469
 470                             # SKIP is essentially the same as TODO for t/TEST
 471                             # this still conforms to TAP:
 472                             # http://search.cpan.org/dist/Test-Harness/lib/Test/Harness/TAP.pod
 473                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 474                             $istodo = 1 if $todo{$num};
 475
 476                             if( $not && !$istodo ) {
 477                                 $failure = "FAILED at test $num";
 478                                 last;
 479                             }
 480                         }
 481                         else {
 482                             $failure ="FAILED--expected test $next, saw test $num";
 483                             last;
 484                         }
 485                     }
 486                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 487                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 488                     }
 489                     else {
 490                         # module tests are allowed extra output,
 491                         # because Test::Harness allows it
 492                         next if $test =~ /^\W*(ext|lib)\b/;
 493                         $failure = "FAILED--unexpected output at test $next";
 494                         last;
 495                     }
 496                 }
 497             }
 498         }
 499         close RESULTS;
 500
 501         if (not defined $failure) {
 502             $failure = 'FAILED--no leader found' unless $seen_leader;
 503         }
 504
 505         if ($ENV{PERL_VALGRIND}) {
 506             my @valgrind;
 507             if (-e $valgrind_log) {
 508                 if (open(V, $valgrind_log)) {
 509                     @valgrind = <V>;
 510                     close V;
 511                 } else {
 512                     warn "$0: Failed to open '$valgrind_log': $!\n";
 513                 }
 514             }
 515             if (@valgrind) {
 516                 my $leaks = 0;
 517                 my $errors = 0;
 518                 for my $i (0..$#valgrind) {
 519                     local $_ = $valgrind[$i];
 520                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 521                         $errors += $1;   # there may be multiple error summaries
 522                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 523                         for my $off (1 .. 4) {
 524                             if ($valgrind[$i+$off] =~
 525                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 526                                 $leaks += $1;
 527                             }
 528                         }
 529                     }
 530                 }
 531                 if ($errors or $leaks) {
 532                     if (rename $valgrind_log, "$test.valgrind") {
 533                         $valgrind++;
 534                     } else {
 535                         warn "$0: Failed to create '$test.valgrind': $!\n";
 536                     }
 537                 }
 538             } else {
 539                 warn "No valgrind output?\n";
 540             }
 541             if (-e $valgrind_log) {
 542                 unlink $valgrind_log
 543                     or warn "$0: Failed to unlink '$valgrind_log': $!\n";
 544             }
 545         }
 546         if ($type eq 'deparse') {
 547             unlink "./$test.dp";
 548         }
 549         if ($ENV{PERL_3LOG}) {
 550             my $tpp = $test;
 551             $tpp =~ s:^\.\./::;
 552             $tpp =~ s:/:_:g;
 553             $tpp =~ s:\.t$:.3log:;
 554             rename("perl.3log", $tpp) ||
 555                 die "rename: perl3.log to $tpp: $!\n";
 556         }
 557         # test if the compiler compiled something
 558         if( $type eq 'compile' && !-e "$test_executable" ) {
 559             $failure = "Test did not compile";
 560         }
 561         if (not defined $failure and $next != $max) {
 562             $failure="FAILED--expected $max tests, saw $next";
 563         }
 564
 565         if (defined $failure) {
 566             print "${te}$failure\n";
 567             $::bad_files++;
 568             if ($test =~ /^base/) {
 569                 die "Failed a basic test ($test) -- cannot continue.\n";
 570             }
 571             ++$failed_tests{$test};
 572         }
 573         else {
 574             if ($max) {
 575                 my $elapsed;
 576                 if ( $show_elapsed_time ) {
 577                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 578                 }
 579                 else {
 580                     $elapsed = "";
 581                 }
 582                 print "${te}ok$elapsed\n";
 583                 $good_files++;
 584             }
 585             else {
 586                 print "${te}skipping test on this platform\n";
 587                 $tested_files -= 1;
 588             }
 589         }
 590     } # while tests
 591
 592     if ($::bad_files == 0) {
 593         if ($good_files) {
 594             print "All tests successful.\n";
 595             # XXX add mention of 'perlbug -ok' ?
 596         }
 597         else {
 598             die "FAILED--no tests were run for some reason.\n";
 599         }
 600     }
 601     else {
 602         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 603         my $s = $::bad_files == 1 ? "" : "s";
 604         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 605         for my $test ( sort keys %failed_tests ) {
 606             print "\t$test\n";
 607         }
 608         warn <<'SHRDLU_1';
 609 ### Since not all tests were successful, you may want to run some of
 610 ### them individually and examine any diagnostic messages they produce.
 611 ### See the INSTALL document's section on "make test".
 612 SHRDLU_1
 613         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 614 ### You have a good chance to get more information by running
 615 ###   ./perl harness
 616 ### in the 't' directory since most (>=80%) of the tests succeeded.
 617 SHRDLU_2
 618         if (eval {require Config; import Config; 1}) {
 619             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 620                 warn <<SHRDLU_3;
 621 ### You may have to set your dynamic library search path,
 622 ### $p, to point to the build directory:
 623 SHRDLU_3
 624                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 625                     warn <<SHRDLU_4a;
 626 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 627 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 628 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 629 SHRDLU_4a
 630                 } else {
 631                     warn <<SHRDLU_4b;
 632 ###   setenv $p `pwd`; cd t; ./perl harness
 633 ###   $p=`pwd`; export $p; cd t; ./perl harness
 634 ###   export $p=`pwd`; cd t; ./perl harness
 635 SHRDLU_4b
 636                 }
 637                 warn <<SHRDLU_5;
 638 ### for csh-style shells, like tcsh; or for traditional/modern
 639 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 640 SHRDLU_5
 641             }
 642         }
 643     }
 644     my ($user,$sys,$cuser,$csys) = times;
 645     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 646         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 647     if ($ENV{PERL_VALGRIND}) {
 648         my $s = $valgrind == 1 ? '' : 's';
 649         print "$valgrind valgrind report$s created.\n", ;
 650     }
 651 }
 652 exit ($::bad_files != 0);
 653
 654 # ex: set ts=8 sts=4 sw=4 noet: