t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.
   5
   6 $| = 1;
   7
   8 # Let tests know they're running in the perl core.  Useful for modules
   9 # which live dual lives on CPAN.
  10 $ENV{PERL_CORE} = 1;
  11
  12 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
  13 @argv = ();
  14 if ($#ARGV >= 0) {
  15     foreach my $idx (0..$#ARGV) {
  16         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  17         $core    = 1 if $1 eq 'core';
  18         $verbose = 1 if $1 eq 'v';
  19         $with_utf= 1 if $1 eq 'utf8';
  20         $byte_compile = 1 if $1 eq 'bytecompile';
  21         $compile = 1 if $1 eq 'compile';
  22         if ($1 =~ /^deparse(,.+)?$/) {
  23             $deparse = 1;
  24             $deparse_opts = $1;
  25         }
  26     }
  27 }
  28 @ARGV = @argv;
  29
  30 chdir 't' if -f 't/TEST';
  31
  32 die "You need to run \"make test\" first to set things up.\n"
  33   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
  34
  35 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
  36     unless (-x 'perl.third') {
  37         unless (-x '../perl.third') {
  38             die "You need to run \"make perl.third first.\n";
  39         }
  40         else {
  41             print "Symlinking ../perl.third as perl.third...\n";
  42             die "Failed to symlink: $!\n"
  43                 unless symlink("../perl.third", "perl.third");
  44             die "Symlinked but no executable perl.third: $!\n"
  45                 unless -x 'perl.third';
  46         }
  47     }
  48 }
  49
  50 # check leakage for embedders
  51 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
  52
  53 $ENV{EMXSHELL} = 'sh';        # For OS/2
  54
  55 # Roll your own File::Find!
  56 use TestInit;
  57 use File::Spec;
  58 my $curdir = File::Spec->curdir;
  59 my $updir  = File::Spec->updir;
  60
  61 sub _find_tests {
  62     my($dir) = @_;
  63     opendir DIR, $dir || die "Trouble opening $dir: $!";
  64     foreach my $f (sort { $a cmp $b } readdir DIR) {
  65         next if $f eq $curdir or $f eq $updir;
  66
  67         my $fullpath = File::Spec->catdir($dir, $f);
  68
  69         _find_tests($fullpath) if -d $fullpath;
  70         push @ARGV, $fullpath if $f =~ /\.t$/;
  71     }
  72 }
  73
  74 unless (@ARGV) {
  75     foreach my $dir (qw(base comp cmd run io op uni)) {
  76         _find_tests($dir);
  77     }
  78     _find_tests("lib") unless $core;
  79     my $mani = File::Spec->catdir($updir, "MANIFEST");
  80     if (open(MANI, $mani)) {
  81         while (<MANI>) { # similar code in t/harness
  82             if (m!^(ext/\S+/([^/]+\.t|test\.pl)|lib/\S+?(\.t|test\.pl))\s!) {
  83                 $t = $1;
  84                 if (!$core || $t =~ m!^lib/[a-z]!)
  85                 {
  86                     $path = File::Spec->catdir($updir, $t);
  87                     push @ARGV, $path;
  88                     $name{$path} = $t;
  89                 }
  90             }
  91         }
  92     } else {
  93         warn "$0: cannot open $mani: $!\n";
  94     }
  95     _find_tests('pod');
  96 }
  97
  98 # Tests known to cause infinite loops for the perlcc tests.
  99 # %infinite = ( 'comp/require.t', 1, 'op/bop.t', 1, 'lib/hostname.t', 1 );
 100 %infinite = ();
 101
 102 if ($deparse) {
 103     _testprogs('deparse', '',   @ARGV);
 104 }
 105 elsif( $compile || $byte_compile ) {
 106     _testprogs('compile', '',   @ARGV) if $compile;
 107     _testprogs('compile', '-B', @ARGV) if $byte_compile;
 108 }
 109 else {
 110     _testprogs('compile', '',   @ARGV) if -e "../testcompile";
 111     _testprogs('perl',    '',   @ARGV);
 112 }
 113
 114 sub _testprogs {
 115     $type = shift @_;
 116     $args = shift;
 117     @tests = @_;
 118
 119     print <<'EOT' if ($type eq 'compile');
 120 ------------------------------------------------------------------------------
 121 TESTING COMPILER
 122 ------------------------------------------------------------------------------
 123 EOT
 124
 125     print <<'EOT' if ($type eq 'deparse');
 126 ------------------------------------------------------------------------------
 127 TESTING DEPARSER
 128 ------------------------------------------------------------------------------
 129 EOT
 130
 131     $ENV{PERLCC_TIMEOUT} = 120
 132           if ($type eq 'compile' && !$ENV{PERLCC_TIMEOUT});
 133
 134     $bad = 0;
 135     $good = 0;
 136     $total = @tests;
 137     $files  = 0;
 138     $totmax = 0;
 139
 140     foreach (@tests) {
 141         $name{$_} = File::Spec->catdir('t',$_) unless exists $name{$_};
 142     }
 143     my $maxlen = 0;
 144     foreach (@name{@tests}) {
 145         s/\.\w+\z/./;
 146         my $len = length ;
 147         $maxlen = $len if $len > $maxlen;
 148     }
 149     # + 3 : we want three dots between the test name and the "ok"
 150     $dotdotdot = $maxlen + 3 ;
 151     while ($test = shift @tests) {
 152
 153         if ( $infinite{$test} && $type eq 'compile' ) {
 154             print STDERR "$test creates infinite loop! Skipping.\n";
 155             next;
 156         }
 157         if ($test =~ /^$/) {
 158             next;
 159         }
 160         if ($type eq 'deparse') {
 161             if ($test eq "comp/redef.t") {
 162                 # Redefinition happens at compile time
 163                 next;
 164             }
 165             elsif ($test eq "lib/switch.t") {
 166                 # B::Deparse doesn't support source filtering
 167                 next;
 168             }
 169         }
 170         $te = $name{$test};
 171         print "$te" . '.' x ($dotdotdot - length($te));
 172
 173         $test = $OVER{$test} if exists $OVER{$test};
 174
 175         open(SCRIPT,"<$test") or die "Can't run $test.\n";
 176         $_ = <SCRIPT>;
 177         close(SCRIPT) unless ($type eq 'deparse');
 178         if (/#!.*\bperl.*-\w*([tT])/) {
 179             $switch = qq{"-$1"};
 180         }
 181         else {
 182             $switch = '';
 183         }
 184
 185         my $test_executable; # for 'compile' tests
 186         my $file_opts = "";
 187         if ($type eq 'deparse') {
 188             # Look for #line directives which change the filename
 189             while (<SCRIPT>) {
 190                 $file_opts .= ",-f$3$4"
 191                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 192             }
 193             close(SCRIPT);
 194         }
 195
 196         my $utf = $with_utf ? '-I../lib -Mutf8' : '';
 197         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
 198         if ($type eq 'deparse') {
 199             my $deparse =
 200                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,".
 201                 "-l$deparse_opts$file_opts ".
 202                 "$test > $test.dp ".
 203                 "&& ./perl $testswitch $switch -I../lib $test.dp |";
 204             open(RESULTS, $deparse)
 205                 or print "can't deparse '$deparse': $!.\n";
 206         }
 207         elsif ($type eq 'perl') {
 208             my $perl = $ENV{PERL} || './perl';
 209             my $run = "$perl $testswitch $switch $utf $test |";
 210             open(RESULTS,$run) or print "can't run '$run': $!.\n";
 211         }
 212         else {
 213             my $compile;
 214             my $pl2c = "$testswitch -I../lib ../utils/perlcc --testsuite " .
 215               # -O9 for good measure, -fcog is broken ATM
 216                        "$switch -Wb=-O9,-fno-cog -L .. " .
 217                        "-I \".. ../lib/CORE\" $args $utf $test -o ";
 218
 219             if( $^O eq 'MSWin32' ) {
 220                 $test_executable = "$test.exe";
 221                 # hopefully unused name...
 222                 open HACK, "> xweghyz.pl";
 223                 print HACK <<EOT;
 224 #!./perl
 225
 226 open HACK, '.\\perl $pl2c $test_executable |';
 227 # cl.exe prints the name of the .c file on stdout (\%^\$^#)
 228 while(<HACK>) {m/^\w+\.[cC]\$/ && next;print}
 229 open HACK, '$test_executable |';
 230 while(<HACK>) {print}
 231 EOT
 232                 close HACK;
 233                 $compile = 'xweghyz.pl |';
 234             }
 235             else {
 236                 $test_executable = "$test.plc";
 237                 $compile = "./perl $pl2c $test_executable && $test_executable |";
 238             }
 239             unlink $test_executable if -f $test_executable;
 240             open(RESULTS, $compile)
 241                 or print "can't compile '$compile': $!.\n";
 242         }
 243
 244         $ok = 0;
 245         $next = 0;
 246         while (<RESULTS>) {
 247             if ($verbose) {
 248                 print $_;
 249             }
 250             unless (/^#/) {
 251                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 252                     $max = $1;
 253                     %todo = map { $_ => 1 } split / /, $3 if $3;
 254                     $totmax += $max;
 255                     $files += 1;
 256                     $next = 1;
 257                     $ok = 1;
 258                 }
 259                 else {
 260                     if (/^(not )?ok (\d+)[^#]*(\s*#.*)?/ &&
 261                         $2 == $next)
 262                     {
 263                         my($not, $num, $extra) = ($1, $2, $3);
 264                         my($istodo) = $extra =~ /^\s*#\s*TODO/ if $extra;
 265                         $istodo = 1 if $todo{$num};
 266
 267                         if( $not && !$istodo ) {
 268                             $ok = 0;
 269                             $next = $num;
 270                             last;
 271                         }
 272                         else {
 273                             $next = $next + 1;
 274                         }
 275                     }
 276                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 277                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 278                     }
 279                     else {
 280                         $ok = 0;
 281                     }
 282                 }
 283             }
 284         }
 285         close RESULTS;
 286         if ($type eq 'deparse') {
 287             unlink "./$test.dp";
 288         }
 289         if ($ENV{PERL_3LOG}) {
 290             my $tpp = $test;
 291             $tpp =~ s:^../::;
 292             $tpp =~ s:/:_:g;
 293             $tpp =~ s:\.t$::;
 294             rename("perl.3log", "perl.3log.$tpp") ||
 295                 die "rename: perl3.log to perl.3log.$tpp: $!\n";
 296         }
 297         $next = $next - 1;
 298         # test if the compiler compiled something
 299         if( $type eq 'compile' && !-e "$test_executable" ) {
 300             $ok = 0;
 301             print "Test did not compile\n";
 302         }
 303         if ($ok && $next == $max ) {
 304             if ($max) {
 305                 print "ok\n";
 306                 $good = $good + 1;
 307             }
 308             else {
 309                 print "skipping test on this platform\n";
 310                 $files -= 1;
 311             }
 312         }
 313         else {
 314             $next += 1;
 315             print "FAILED at test $next\n";
 316             $bad = $bad + 1;
 317             $_ = $test;
 318             if (/^base/) {
 319                 die "Failed a basic test--cannot continue.\n";
 320             }
 321         }
 322     }
 323
 324     if ($bad == 0) {
 325         if ($ok) {
 326             print "All tests successful.\n";
 327             # XXX add mention of 'perlbug -ok' ?
 328         }
 329         else {
 330             die "FAILED--no tests were run for some reason.\n";
 331         }
 332     }
 333     else {
 334         $pct = $files ? sprintf("%.2f", ($files - $bad) / $files * 100) : "0.00";
 335         if ($bad == 1) {
 336             warn "Failed 1 test script out of $files, $pct% okay.\n";
 337         }
 338         else {
 339             warn "Failed $bad test scripts out of $files, $pct% okay.\n";
 340         }
 341         warn <<'SHRDLU_1';
 342    ### Since not all tests were successful, you may want to run some of
 343    ### them individually and examine any diagnostic messages they produce.
 344    ### See the INSTALL document's section on "make test".
 345 SHRDLU_1
 346         warn <<'SHRDLU_2' if $good / $total > 0.8;
 347    ### You have a good chance to get more information by running
 348    ###     ./perl harness
 349    ### in the 't' directory since most (>=80%) of the tests succeeded.
 350 SHRDLU_2
 351         if (eval {require Config; import Config; 1}) {
 352             if ($Config{usedl} && (my $p = $Config{ldlibpthname})) {
 353                 warn <<SHRDLU_3;
 354    ### You may have to set your dynamic library search path,
 355    ### $p, to point to the build directory:
 356 SHRDLU_3
 357                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 358                     warn <<SHRDLU_4a;
 359    ###     setenv $p `pwd`:\$$p; cd t; ./perl harness
 360    ###     $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 361    ###     export $p=`pwd`:\$$p; cd t; ./perl harness
 362 SHRDLU_4a
 363                 } else {
 364                     warn <<SHRDLU_4b;
 365    ###     setenv $p `pwd`; cd t; ./perl harness
 366    ###     $p=`pwd`; export $p; cd t; ./perl harness
 367    ###     export $p=`pwd`; cd t; ./perl harness
 368 SHRDLU_4b
 369                 }
 370                 warn <<SHRDLU_5;
 371    ### for csh-style shells, like tcsh; or for traditional/modern
 372    ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 373 SHRDLU_5
 374             }
 375         }
 376     }
 377     ($user,$sys,$cuser,$csys) = times;
 378     print sprintf("u=%g  s=%g  cu=%g  cs=%g  scripts=%d  tests=%d\n",
 379         $user,$sys,$cuser,$csys,$files,$totmax);
 380 }
 381 exit ($bad != 0);