t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.
   5
   6 $| = 1;
   7
   8 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
   9 if ($#ARGV >= 0) {
  10     foreach my $idx (0..$#ARGV) {
  11         next unless $ARGV[$idx] =~ /^-(\S+)$/;
  12         $verbose = 1 if $1 eq 'v';
  13         $with_utf= 1 if $1 eq 'utf8';
  14         if ($1 =~ /^deparse(,.+)?$/) {
  15             $deparse = 1;
  16             $deparse_opts = $1;
  17         }
  18         splice(@ARGV, $idx, 1);
  19     }
  20 }
  21
  22 chdir 't' if -f 't/TEST';
  23
  24 die "You need to run \"make test\" first to set things up.\n"
  25   unless -e 'perl' or -e 'perl.exe';
  26
  27 if ($ENV{PERL_3LOG}) {
  28     unless (-x 'perl.third') {
  29         unless (-x '../perl.third') {
  30             die "You need to run \"make perl.third first.\n";
  31         }
  32         else {
  33             print "Symlinking ../perl.third as perl.third...\n";
  34             die "Failed to symlink: $!\n"
  35                 unless symlink("../perl.third", "perl.third");
  36             die "Symlinked but no executable perl.third: $!\n"
  37                 unless -x 'perl.third';
  38         }
  39     }
  40 }
  41
  42 # check leakage for embedders
  43 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
  44
  45 $ENV{EMXSHELL} = 'sh';        # For OS/2
  46
  47
  48 # Roll your own File::Find!
  49 use TestInit;
  50 use File::Spec;
  51 my $curdir = File::Spec->curdir;
  52 my $updir  = File::Spec->updir;
  53
  54 sub _find_tests {
  55     my($dir) = @_;
  56     opendir DIR, $dir || die "Trouble opening $dir: $!";
  57     foreach my $f (readdir DIR) {
  58         next if $f eq $curdir or $f eq $updir;
  59
  60         my $fullpath = File::Spec->catdir($dir, $f);
  61
  62         _find_tests($fullpath) if -d $fullpath;
  63         push @ARGV, $fullpath if $f =~ /\.t$/;
  64     }
  65 }
  66
  67 unless (@ARGV) {
  68     foreach my $dir (qw(base comp cmd run io op pragma lib pod)) {
  69         _find_tests($dir);
  70     }
  71 }
  72
  73 # %infinite = ( 'comp/require.t', 1, 'op/bop.t', 1, 'lib/hostname.t', 1 );
  74 %infinite = ();
  75
  76 if ($deparse) {
  77     _testprogs('deparse', @ARGV);
  78 } else {
  79     _testprogs('perl', @ARGV);
  80     _testprogs('compile', @ARGV) if (-e "../testcompile");
  81 }
  82
  83 sub _testprogs {
  84     $type = shift @_;
  85     @tests = @_;
  86
  87
  88     print <<'EOT' if ($type eq 'compile');
  89 --------------------------------------------------------------------------------
  90 TESTING COMPILER
  91 --------------------------------------------------------------------------------
  92 EOT
  93
  94     print <<'EOT' if ($type eq 'deparse');
  95 --------------------------------------------------------------------------------
  96 TESTING DEPARSER
  97 --------------------------------------------------------------------------------
  98 EOT
  99
 100     $ENV{PERLCC_TIMEOUT} = 120
 101           if ($type eq 'compile' && !$ENV{PERLCC_TIMEOUT});
 102
 103     $bad = 0;
 104     $good = 0;
 105     $total = @tests;
 106     $files  = 0;
 107     $totmax = 0;
 108     $maxlen = 0;
 109     foreach (@tests) {
 110         $len = length;
 111         $maxlen = $len if $len > $maxlen;
 112     }
 113     # +3 : we want three dots between the test name and the "ok"
 114     # -2 : the .t suffix
 115     $dotdotdot = $maxlen + 3 - 2;
 116     while ($test = shift @tests) {
 117
 118         if ( $infinite{$test} && $type eq 'compile' ) {
 119             print STDERR "$test creates infinite loop! Skipping.\n";
 120             next;
 121         }
 122         if ($test =~ /^$/) {
 123             next;
 124         }
 125         if ($type eq 'deparse') {
 126             if ($test eq "comp/redef.t") {
 127                 # Redefinition happens at compile time
 128                 next;
 129             }
 130             elsif ($test eq "lib/switch.t") {
 131                 # B::Deparse doesn't support source filtering
 132                 next;
 133             }
 134         }
 135         $te = $test;
 136         chop($te);
 137         print "$te" . '.' x ($dotdotdot - length($te));
 138
 139         open(SCRIPT,"<$test") or die "Can't run $test.\n";
 140         $_ = <SCRIPT>;
 141         close(SCRIPT) unless ($type eq 'deparse');
 142         if (/#!.*perl(.*)$/) {
 143             $switch = $1;
 144             if ($^O eq 'VMS') {
 145                 # Must protect uppercase switches with "" on command line
 146                 $switch =~ s/-([A-Z]\S*)/"-$1"/g;
 147             }
 148         }
 149         else {
 150             $switch = '';
 151         }
 152
 153         my $file_opts = "";
 154         if ($type eq 'deparse') {
 155             # Look for #line directives which change the filename
 156             while (<SCRIPT>) {
 157                 $file_opts .= ",-f$3$4"
 158                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 159             }
 160             close(SCRIPT);
 161         }
 162         my $utf = $with_utf ? '-I../lib -Mutf8'
 163                             : '';
 164         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
 165         if ($type eq 'deparse') {
 166             my $deparse =
 167                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,".
 168                 "-l$deparse_opts$file_opts ".
 169                 "./$test > ./$test.dp ".
 170                 "&& ./perl $testswitch $switch -I../lib ./$test.dp |";
 171             open(RESULTS, $deparse)
 172                 or print "can't deparse '$deparse': $!.\n";
 173         }
 174         elsif ($type eq 'perl') {
 175             my $run = "./perl $testswitch $switch $utf $test |";
 176             open(RESULTS,$run) or print "can't run '$run': $!.\n";
 177         }
 178         else {
 179             my $compile =
 180                 "./perl $testswitch -I../lib ../utils/perlcc -o ".
 181                 "./$test.plc $utf ./$test ".
 182                 " && ./$test.plc |";
 183             open(RESULTS, $compile)
 184                 or print "can't compile '$compile': $!.\n";
 185             unlink "./$test.plc";
 186         }
 187
 188         $ok = 0;
 189         $next = 0;
 190         while (<RESULTS>) {
 191             if ($verbose) {
 192                 print $_;
 193             }
 194             unless (/^#/) {
 195                 if (/^1\.\.([0-9]+)/) {
 196                     $max = $1;
 197                     $totmax += $max;
 198                     $files += 1;
 199                     $next = 1;
 200                     $ok = 1;
 201                 }
 202                 else {
 203                     if (/^(not )?ok (\d+)(\s*#.*)?/ &&
 204                         $2 == $next)
 205                     {
 206                         my($not, $num, $extra) = ($1, $2, $3);
 207                         my($istodo) = $extra =~ /^\s*#\s*TODO/ if $extra;
 208
 209                         if( $not && !$istodo ) {
 210                             $ok = 0;
 211                             $next = $num;
 212                             last;
 213                         }
 214                         else {
 215                             $next = $next + 1;
 216                         }
 217                     }
 218                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 219                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 220                     }
 221                     else {
 222                         $ok = 0;
 223                     }
 224                 }
 225             }
 226         }
 227         close RESULTS;
 228         if ($type eq 'deparse') {
 229             unlink "./$test.dp";
 230         }
 231         if ($ENV{PERL_3LOG}) {
 232             my $tpp = $test;
 233             $tpp =~ s:/:_:g;
 234             $tpp =~ s:\.t$::;
 235             rename("perl.3log", "perl.3log.$tpp");
 236         }
 237         $next = $next - 1;
 238         if ($ok && $next == $max) {
 239             if ($max) {
 240                 print "ok\n";
 241                 $good = $good + 1;
 242             }
 243             else {
 244                 print "skipping test on this platform\n";
 245                 $files -= 1;
 246             }
 247         }
 248         else {
 249             $next += 1;
 250             print "FAILED at test $next\n";
 251             $bad = $bad + 1;
 252             $_ = $test;
 253             if (/^base/) {
 254                 die "Failed a basic test--cannot continue.\n";
 255             }
 256         }
 257     }
 258
 259     if ($bad == 0) {
 260         if ($ok) {
 261             print "All tests successful.\n";
 262             # XXX add mention of 'perlbug -ok' ?
 263         }
 264         else {
 265             die "FAILED--no tests were run for some reason.\n";
 266         }
 267     }
 268     else {
 269         $pct = $files ? sprintf("%.2f", ($files - $bad) / $files * 100) : "0.00";
 270         if ($bad == 1) {
 271             warn "Failed 1 test script out of $files, $pct% okay.\n";
 272         }
 273         else {
 274             warn "Failed $bad test scripts out of $files, $pct% okay.\n";
 275         }
 276         warn <<'SHRDLU';
 277    ### Since not all tests were successful, you may want to run some
 278    ### of them individually and examine any diagnostic messages they
 279    ### produce.  See the INSTALL document's section on "make test".
 280    ### If you are testing the compiler, then ignore this message
 281    ### and run
 282    ###      ./perl harness
 283    ### in the directory ./t.
 284 SHRDLU
 285         warn <<'SHRDLU' if $good / $total > 0.8;
 286    ###
 287    ### Since most tests were successful, you have a good chance to
 288    ### get information with better granularity by running
 289    ###     ./perl harness
 290    ### in directory ./t.
 291 SHRDLU
 292     }
 293     ($user,$sys,$cuser,$csys) = times;
 294     print sprintf("u=%g  s=%g  cu=%g  cs=%g  scripts=%d  tests=%d\n",
 295         $user,$sys,$cuser,$csys,$files,$totmax);
 296 }
 297 exit ($bad != 0);