t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 my %temp_no_core =
  27     ('../ext/Attribute-Handlers' => 1,
  28      '../ext/B-Debug' => 1,
  29      '../ext/Compress-Raw-Bzip2' => 1,
  30      '../ext/Compress-Raw-Zlib' => 1,
  31      '../ext/Devel-PPPort' => 1,
  32      '../ext/Encode' => 1,
  33      '../ext/Hash-Util' => 'fixme',
  34      '../ext/Hash-Util-FieldHash' => 'fixme',
  35      '../ext/I18N-Langinfo' => 'fixme',
  36      '../ext/IO-Compress' => 1,
  37      '../ext/IPC-SysV' => 1,
  38      '../ext/MIME-Base64' => 1,
  39      '../ext/Safe' => 'fixme',
  40      '../ext/Time-HiRes' => 1,
  41      '../ext/Unicode-Normalize' => 1,
  42     );
  43
  44 if ($::do_nothing) {
  45     return 1;
  46 }
  47
  48 # Location to put the Valgrind log.
  49 my $Valgrind_Log = 'current.valgrind';
  50
  51 $| = 1;
  52
  53 # for testing TEST only
  54 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
  55 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
  56
  57 delete $ENV{PERL5LIB};
  58 delete $ENV{PERLLIB};
  59 delete $ENV{PERL5OPT};
  60
  61 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  62 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  63 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
  64
  65 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
  66 # can't rely on require working.
  67 {
  68     my @argv = ();
  69     foreach my $idx (0..$#ARGV) {
  70         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  71         $::benchmark = 1 if $1 eq 'benchmark';
  72         $::core    = 1 if $1 eq 'core';
  73         $::verbose = 1 if $1 eq 'v';
  74         $::torture = 1 if $1 eq 'torture';
  75         $::with_utf8 = 1 if $1 eq 'utf8';
  76         $::with_utf16 = 1 if $1 eq 'utf16';
  77         $::taintwarn = 1 if $1 eq 'taintwarn';
  78         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
  79         if ($1 =~ /^deparse(,.+)?$/) {
  80             $::deparse = 1;
  81             $::deparse_opts = $1;
  82         }
  83     }
  84     @ARGV = @argv;
  85 }
  86
  87 chdir 't' if -f 't/TEST';
  88
  89 die "You need to run \"make test\" first to set things up.\n"
  90   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
  91
  92 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
  93     unless (-x 'perl.third') {
  94         unless (-x '../perl.third') {
  95             die "You need to run \"make perl.third first.\n";
  96         }
  97         else {
  98             print "Symlinking ../perl.third as perl.third...\n";
  99             die "Failed to symlink: $!\n"
 100                 unless symlink("../perl.third", "perl.third");
 101             die "Symlinked but no executable perl.third: $!\n"
 102                 unless -x 'perl.third';
 103         }
 104     }
 105 }
 106
 107 # check leakage for embedders
 108 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 109
 110 $ENV{EMXSHELL} = 'sh';        # For OS/2
 111
 112 if ($show_elapsed_time) { require Time::HiRes }
 113
 114 my %skip = (
 115             '.' => 1,
 116             '..' => 1,
 117             'CVS' => 1,
 118             'RCS' => 1,
 119             'SCCS' => 1,
 120             '.svn' => 1,
 121            );
 122
 123 # Roll your own File::Find!
 124 sub _find_tests {
 125     my($dir) = @_;
 126     opendir DIR, $dir or die "Trouble opening $dir: $!";
 127     foreach my $f (sort { $a cmp $b } readdir DIR) {
 128         next if $skip{$f};
 129
 130         my $fullpath = "$dir/$f";
 131
 132         if (-d $fullpath) {
 133             _find_tests($fullpath);
 134         } elsif ($f =~ /\.t$/) {
 135             push @ARGV, $fullpath;
 136         }
 137     }
 138 }
 139
 140
 141 # Scan the text of the test program to find switches and special options
 142 # we might need to apply.
 143 sub _scan_test {
 144     my($test, $type) = @_;
 145
 146     open(my $script, "<", $test) or die "Can't read $test.\n";
 147     my $first_line = <$script>;
 148
 149     $first_line =~ tr/\0//d if $::with_utf16;
 150
 151     my $switch = "";
 152     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 153         $switch = qq{"-$1"};
 154     } else {
 155         if ($::taintwarn) {
 156             # not all tests are expected to pass with this option
 157             $switch = '"-t"';
 158         } else {
 159             $switch = '';
 160         }
 161     }
 162
 163     my $file_opts = "";
 164     if ($type eq 'deparse') {
 165         # Look for #line directives which change the filename
 166         while (<$script>) {
 167             $file_opts .= ",-f$3$4"
 168               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 169         }
 170     }
 171
 172     return { file => $file_opts, switch => $switch };
 173 }
 174
 175 sub _run_test {
 176     my($harness, $test, $type) = @_;
 177     if (!defined $type) {
 178         # To conform to the interface expected by exec in TAP::Harness
 179         $type = 'perl';
 180     }
 181
 182     my $options = _scan_test($test, $type);
 183     my $return_dir;
 184
 185     my $perl = './perl';
 186     my $lib  = '../lib';
 187     $test =~ /^(.+)\/[^\/]+/;
 188     my $dir = $1;
 189     my $ext_dir;
 190
 191     my $testswitch = $dir_to_switch{$dir};
 192     if (!defined $testswitch) {
 193         if ($test =~ s!^(\.\./ext/[^/]+)/t!t!) {
 194             $ext_dir = $1;
 195             $return_dir = '../../t';
 196             $lib = '../../lib';
 197             $perl = '../../t/perl';
 198             $testswitch = "-I../.. -MTestInit=U2T,A";
 199             if ($temp_no_core{$ext_dir}) {
 200                 $testswitch = $testswitch . ',NC';
 201             }
 202             chdir $ext_dir or die "Can't chdir to '$ext_dir': $!";
 203         } else {
 204             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 205         }
 206     }
 207
 208     my $utf8 = $::with_utf8 ? '-I$lib -Mutf8' : '';
 209
 210     my $results;
 211     if ($type eq 'deparse') {
 212         my $deparse_cmd =
 213           "$perl $testswitch $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 214           "-l$::deparse_opts$options->{file} ".
 215           "$test > $test.dp ".
 216           "&& $perl $testswitch $options->{switch} -I$lib $test.dp |";
 217         open($results, $deparse_cmd)
 218           or print "can't deparse '$deparse_cmd': $!.\n";
 219     }
 220     elsif ($type eq 'perl') {
 221         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 222
 223         if ($ENV{PERL_VALGRIND}) {
 224             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 225             my $vg_opts = $ENV{VG_OPTS}
 226               //  "--suppressions=perl.supp --leak-check=yes "
 227                 . "--leak-resolution=high --show-reachable=yes "
 228                   . "--num-callers=50";
 229             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 230             $redir = "3>$Valgrind_Log";
 231         }
 232
 233         my $run = $perl . _quote_args("$testswitch $options->{switch} $utf8")
 234           . " $test $redir|";
 235         open($results, $run) or print "can't run '$run': $!.\n";
 236     }
 237
 238     if ($return_dir) {
 239         chdir $return_dir
 240             or die "Can't chdir from '$ext_dir' to '$return_dir': $!";
 241     }
 242
 243     # Our environment may force us to use UTF-8, but we can't be sure that
 244     # anything we're reading from will be generating (well formed) UTF-8
 245     # This may not be the best way - possibly we should unset ${^OPEN} up
 246     # top?
 247     binmode $results;
 248
 249     return $results;
 250 }
 251
 252 sub _quote_args {
 253     my ($args) = @_;
 254     my $argstring = '';
 255
 256     foreach (split(/\s+/,$args)) {
 257        # In VMS protect with doublequotes because otherwise
 258        # DCL will lowercase -- unless already doublequoted.
 259        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 260        $argstring .= ' ' . $_;
 261     }
 262     return $argstring;
 263 }
 264
 265 sub _populate_hash {
 266     return unless defined $_[0];
 267     return map {$_, 1} split /\s+/, $_[0];
 268 }
 269
 270 sub _tests_from_manifest {
 271     my ($extensions, $known_extensions) = @_;
 272     my %skip;
 273     my %extensions = _populate_hash($extensions);
 274     my %known_extensions = _populate_hash($known_extensions);
 275
 276     foreach (keys %known_extensions) {
 277         $skip{$_}++ unless $extensions{$_};
 278     }
 279
 280     my @results;
 281     my $mani = '../MANIFEST';
 282     if (open(MANI, $mani)) {
 283         while (<MANI>) {
 284             if (m!^(ext/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 285                 my $t = $1;
 286                 my $extension = $2;
 287                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 288                     if (defined $extension) {
 289                         $extension =~ s!/t$!!;
 290                         # XXX Do I want to warn that I'm skipping these?
 291                         next if $skip{$extension};
 292                         my $flat_extension = $extension;
 293                         $flat_extension =~ s!-!/!g;
 294                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 295                     }
 296                     my $path = "../$t";
 297                     push @results, $path;
 298                     $::path_to_name{$path} = $t;
 299                 }
 300             }
 301         }
 302         close MANI;
 303     } else {
 304         warn "$0: cannot open $mani: $!\n";
 305     }
 306     return @results;
 307 }
 308
 309 unless (@ARGV) {
 310     # base first, as TEST bails out if that can't run
 311     # then comp, to validate that require works
 312     # then run, to validate that -M works
 313     # then we know we can -MTestInit for everything else, making life simpler
 314     foreach my $dir (qw(base comp run cmd io op uni mro)) {
 315         _find_tests($dir);
 316     }
 317     _find_tests("lib") unless $::core;
 318     # Config.pm may be broken for make minitest. And this is only a refinement
 319     # for skipping tests on non-default builds, so it is allowed to fail.
 320     # What we want to to is make a list of extensions which we did not build.
 321     my $configsh = '../config.sh';
 322     my ($extensions, $known_extensions);
 323     if (-f $configsh) {
 324         open FH, $configsh or die "Can't open $configsh: $!";
 325         while (<FH>) {
 326             if (/^extensions=['"](.*)['"]$/) {
 327                 $extensions = $1;
 328             }
 329             elsif (/^known_extensions=['"](.*)['"]$/) {
 330                 $known_extensions = $1;
 331             }
 332         }
 333         if (!defined $known_extensions) {
 334             warn "No known_extensions line found in $configsh";
 335         }
 336         if (!defined $extensions) {
 337             warn "No extensions line found in $configsh";
 338         }
 339     }
 340     # The "complex" constructions of list return from a subroutine, and push of
 341     # a list, might fail if perl is really hosed, but they aren't needed for
 342     # make minitest, and the building of extensions will likely also fail if
 343     # something is that badly wrong.
 344     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 345     unless ($::core) {
 346         _find_tests('pod');
 347         _find_tests('x2p');
 348         _find_tests('porting');
 349         _find_tests('japh') if $::torture;
 350         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 351     }
 352 }
 353
 354 if ($::deparse) {
 355     _testprogs('deparse', '',   @ARGV);
 356 }
 357 elsif ($::with_utf16) {
 358     for my $e (0, 1) {
 359         for my $b (0, 1) {
 360             print STDERR "# ENDIAN $e BOM $b\n";
 361             my @UARGV;
 362             for my $a (@ARGV) {
 363                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 364                 my $f = $e ? "v" : "n";
 365                 push @UARGV, $u;
 366                 unlink($u);
 367                 if (open(A, $a)) {
 368                     if (open(U, ">$u")) {
 369                         print U pack("$f", 0xFEFF) if $b;
 370                         while (<A>) {
 371                             print U pack("$f*", unpack("C*", $_));
 372                         }
 373                         close(U);
 374                     }
 375                     close(A);
 376                 }
 377             }
 378             _testprogs('perl', '', @UARGV);
 379             unlink(@UARGV);
 380         }
 381     }
 382 }
 383 else {
 384     _testprogs('perl',    '',   @ARGV);
 385 }
 386
 387 sub _testprogs {
 388     my ($type, $args, @tests) = @_;
 389
 390     print <<'EOT' if ($type eq 'deparse');
 391 ------------------------------------------------------------------------------
 392 TESTING DEPARSER
 393 ------------------------------------------------------------------------------
 394 EOT
 395
 396     $::bad_files = 0;
 397
 398     foreach my $t (@tests) {
 399       unless (exists $::path_to_name{$t}) {
 400         my $tname = "t/$t";
 401         $::path_to_name{$t} = $tname;
 402       }
 403     }
 404     my $maxlen = 0;
 405     foreach (@::path_to_name{@tests}) {
 406         s/\.\w+\z/./;
 407         my $len = length ;
 408         $maxlen = $len if $len > $maxlen;
 409     }
 410     # + 3 : we want three dots between the test name and the "ok"
 411     my $dotdotdot = $maxlen + 3 ;
 412     my $valgrind = 0;
 413     my $total_files = @tests;
 414     my $good_files = 0;
 415     my $tested_files  = 0;
 416     my $totmax = 0;
 417     my %failed_tests;
 418
 419     while (my $test = shift @tests) {
 420         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 421
 422         if ($test =~ /^$/) {
 423             next;
 424         }
 425         if ($type eq 'deparse') {
 426             if ($test eq "comp/redef.t") {
 427                 # Redefinition happens at compile time
 428                 next;
 429             }
 430             elsif ($test =~ m{lib/Switch/t/}) {
 431                 # B::Deparse doesn't support source filtering
 432                 next;
 433             }
 434         }
 435         my $te = $::path_to_name{$test} . '.'
 436                     x ($dotdotdot - length($::path_to_name{$test}));
 437
 438         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 439             print $te;
 440             $te = '';
 441         }
 442
 443         my $results = _run_test(undef, $test, $type);
 444
 445         my $failure;
 446         my $next = 0;
 447         my $seen_leader = 0;
 448         my $seen_ok = 0;
 449         my $trailing_leader = 0;
 450         my $max;
 451         my %todo;
 452         while (<$results>) {
 453             next if /^\s*$/; # skip blank lines
 454             if (/^1..$/ && ($^O eq 'VMS')) {
 455                 # VMS pipe bug inserts blank lines.
 456                 my $l2 = <RESULTS>;
 457                 if ($l2 =~ /^\s*$/) {
 458                     $l2 = <RESULTS>;
 459                 }
 460                 $_ = '1..' . $l2;
 461             }
 462             if ($::verbose) {
 463                 print $_;
 464             }
 465             unless (/^\#/) {
 466                 if ($trailing_leader) {
 467                     # shouldn't be anything following a postfix 1..n
 468                     $failure = 'FAILED--extra output after trailing 1..n';
 469                     last;
 470                 }
 471                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 472                     if ($seen_leader) {
 473                         $failure = 'FAILED--seen duplicate leader';
 474                         last;
 475                     }
 476                     $max = $1;
 477                     %todo = map { $_ => 1 } split / /, $3 if $3;
 478                     $totmax += $max;
 479                     $tested_files++;
 480                     if ($seen_ok) {
 481                         # 1..n appears at end of file
 482                         $trailing_leader = 1;
 483                         if ($next != $max) {
 484                             $failure = "FAILED--expected $max tests, saw $next";
 485                             last;
 486                         }
 487                     }
 488                     else {
 489                         $next = 0;
 490                     }
 491                     $seen_leader = 1;
 492                 }
 493                 else {
 494                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 495                         unless ($seen_leader) {
 496                             unless ($seen_ok) {
 497                                 $next = 0;
 498                             }
 499                         }
 500                         $seen_ok = 1;
 501                         $next++;
 502                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 503                         $num = $next unless $num;
 504
 505                         if ($num == $next) {
 506
 507                             # SKIP is essentially the same as TODO for t/TEST
 508                             # this still conforms to TAP:
 509                             # http://search.cpan.org/dist/TAP/TAP.pod
 510                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 511                             $istodo = 1 if $todo{$num};
 512
 513                             if( $not && !$istodo ) {
 514                                 $failure = "FAILED at test $num";
 515                                 last;
 516                             }
 517                         }
 518                         else {
 519                             $failure ="FAILED--expected test $next, saw test $num";
 520                             last;
 521                         }
 522                     }
 523                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 524                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 525                     }
 526                     else {
 527                         # module tests are allowed extra output,
 528                         # because Test::Harness allows it
 529                         next if $test =~ /^\W*(ext|lib)\b/;
 530                         $failure = "FAILED--unexpected output at test $next";
 531                         last;
 532                     }
 533                 }
 534             }
 535         }
 536         close $results;
 537
 538         if (not defined $failure) {
 539             $failure = 'FAILED--no leader found' unless $seen_leader;
 540         }
 541
 542         if ($ENV{PERL_VALGRIND}) {
 543             my @valgrind;
 544             if (-e $Valgrind_Log) {
 545                 if (open(V, $Valgrind_Log)) {
 546                     @valgrind = <V>;
 547                     close V;
 548                 } else {
 549                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 550                 }
 551             }
 552             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 553                 if (rename $Valgrind_Log, "$test.valgrind") {
 554                     $valgrind++;
 555                 } else {
 556                     warn "$0: Failed to create '$test.valgrind': $!\n";
 557                 }
 558             }
 559             elsif (@valgrind) {
 560                 my $leaks = 0;
 561                 my $errors = 0;
 562                 for my $i (0..$#valgrind) {
 563                     local $_ = $valgrind[$i];
 564                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 565                         $errors += $1;   # there may be multiple error summaries
 566                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 567                         for my $off (1 .. 4) {
 568                             if ($valgrind[$i+$off] =~
 569                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 570                                 $leaks += $1;
 571                             }
 572                         }
 573                     }
 574                 }
 575                 if ($errors or $leaks) {
 576                     if (rename $Valgrind_Log, "$test.valgrind") {
 577                         $valgrind++;
 578                     } else {
 579                         warn "$0: Failed to create '$test.valgrind': $!\n";
 580                     }
 581                 }
 582             } else {
 583                 warn "No valgrind output?\n";
 584             }
 585             if (-e $Valgrind_Log) {
 586                 unlink $Valgrind_Log
 587                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 588             }
 589         }
 590         if ($type eq 'deparse') {
 591             unlink "./$test.dp";
 592         }
 593         if ($ENV{PERL_3LOG}) {
 594             my $tpp = $test;
 595             $tpp =~ s:^\.\./::;
 596             $tpp =~ s:/:_:g;
 597             $tpp =~ s:\.t$:.3log:;
 598             rename("perl.3log", $tpp) ||
 599                 die "rename: perl3.log to $tpp: $!\n";
 600         }
 601         if (not defined $failure and $next != $max) {
 602             $failure="FAILED--expected $max tests, saw $next";
 603         }
 604
 605         if( !defined $failure  # don't mask a test failure
 606             and $? )
 607         {
 608             $failure = "FAILED--non-zero wait status: $?";
 609         }
 610
 611         if (defined $failure) {
 612             print "${te}$failure\n";
 613             $::bad_files++;
 614             if ($test =~ /^base/) {
 615                 die "Failed a basic test ($test) -- cannot continue.\n";
 616             }
 617             ++$failed_tests{$test};
 618         }
 619         else {
 620             if ($max) {
 621                 my $elapsed;
 622                 if ( $show_elapsed_time ) {
 623                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 624                 }
 625                 else {
 626                     $elapsed = "";
 627                 }
 628                 print "${te}ok$elapsed\n";
 629                 $good_files++;
 630             }
 631             else {
 632                 print "${te}skipped\n";
 633                 $tested_files -= 1;
 634             }
 635         }
 636     } # while tests
 637
 638     if ($::bad_files == 0) {
 639         if ($good_files) {
 640             print "All tests successful.\n";
 641             # XXX add mention of 'perlbug -ok' ?
 642         }
 643         else {
 644             die "FAILED--no tests were run for some reason.\n";
 645         }
 646     }
 647     else {
 648         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 649         my $s = $::bad_files == 1 ? "" : "s";
 650         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 651         for my $test ( sort keys %failed_tests ) {
 652             print "\t$test\n";
 653         }
 654         warn <<'SHRDLU_1';
 655 ### Since not all tests were successful, you may want to run some of
 656 ### them individually and examine any diagnostic messages they produce.
 657 ### See the INSTALL document's section on "make test".
 658 SHRDLU_1
 659         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 660 ### You have a good chance to get more information by running
 661 ###   ./perl harness
 662 ### in the 't' directory since most (>=80%) of the tests succeeded.
 663 SHRDLU_2
 664         if (eval {require Config; import Config; 1}) {
 665             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 666                 warn <<SHRDLU_3;
 667 ### You may have to set your dynamic library search path,
 668 ### $p, to point to the build directory:
 669 SHRDLU_3
 670                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 671                     warn <<SHRDLU_4a;
 672 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 673 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 674 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 675 SHRDLU_4a
 676                 } else {
 677                     warn <<SHRDLU_4b;
 678 ###   setenv $p `pwd`; cd t; ./perl harness
 679 ###   $p=`pwd`; export $p; cd t; ./perl harness
 680 ###   export $p=`pwd`; cd t; ./perl harness
 681 SHRDLU_4b
 682                 }
 683                 warn <<SHRDLU_5;
 684 ### for csh-style shells, like tcsh; or for traditional/modern
 685 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 686 SHRDLU_5
 687             }
 688         }
 689     }
 690     my ($user,$sys,$cuser,$csys) = times;
 691     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 692         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 693     if ($ENV{PERL_VALGRIND}) {
 694         my $s = $valgrind == 1 ? '' : 's';
 695         print "$valgrind valgrind report$s created.\n", ;
 696     }
 697 }
 698 exit ($::bad_files != 0);
 699
 700 # ex: set ts=8 sts=4 sw=4 noet: