t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # I think in the end I'd like "not absolute" to be the default", as it saves
  27 # some fakery within TestInit which can peturb tests, and takes CPU.
  28 my %no_abs =
  29     ('../ext/Pod-Parser' => 1,
  30     );
  31
  32 my %temp_no_core =
  33     ('../ext/B-Debug' => 1,
  34      '../ext/Compress-Raw-Bzip2' => 1,
  35      '../ext/Compress-Raw-Zlib' => 1,
  36      '../cpan/Devel-PPPort' => 1,
  37      '../cpan/Getopt-Long' => 1,
  38      '../ext/IO-Compress' => 1,
  39      '../cpan/IPC-SysV' => 1,
  40      '../ext/Math-BigInt' => 1,
  41      '../ext/Math-BigRat' => 1,
  42      '../ext/MIME-Base64' => 1,
  43      '../cpan/NEXT' => 1,
  44      '../ext/parent' => 1,
  45      '../cpan/Parse-CPAN-Meta' => 1,
  46      '../ext/Pod-Simple' => 1,
  47      '../cpan/podlators' => 1,
  48      '../ext/Test-Simple' => 1,
  49      '../cpan/Tie-RefHash' => 1,
  50      '../ext/Time-HiRes' => 1,
  51      '../ext/Unicode-Collate' => 1,
  52      '../ext/Unicode-Normalize' => 1,
  53     );
  54
  55 if ($::do_nothing) {
  56     return 1;
  57 }
  58
  59 # Location to put the Valgrind log.
  60 my $Valgrind_Log = 'current.valgrind';
  61
  62 $| = 1;
  63
  64 # for testing TEST only
  65 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
  66 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
  67
  68 delete $ENV{PERL5LIB};
  69 delete $ENV{PERLLIB};
  70 delete $ENV{PERL5OPT};
  71
  72 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  73 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  74 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
  75
  76 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
  77 # can't rely on require working.
  78 {
  79     my @argv = ();
  80     foreach my $idx (0..$#ARGV) {
  81         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  82         $::benchmark = 1 if $1 eq 'benchmark';
  83         $::core    = 1 if $1 eq 'core';
  84         $::verbose = 1 if $1 eq 'v';
  85         $::torture = 1 if $1 eq 'torture';
  86         $::with_utf8 = 1 if $1 eq 'utf8';
  87         $::with_utf16 = 1 if $1 eq 'utf16';
  88         $::taintwarn = 1 if $1 eq 'taintwarn';
  89         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
  90         if ($1 =~ /^deparse(,.+)?$/) {
  91             $::deparse = 1;
  92             $::deparse_opts = $1;
  93         }
  94     }
  95     @ARGV = @argv;
  96 }
  97
  98 chdir 't' if -f 't/TEST';
  99 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 100     @INC = '../lib';
 101 }
 102
 103 die "You need to run \"make test\" first to set things up.\n"
 104   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 105
 106 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 107     unless (-x 'perl.third') {
 108         unless (-x '../perl.third') {
 109             die "You need to run \"make perl.third first.\n";
 110         }
 111         else {
 112             print "Symlinking ../perl.third as perl.third...\n";
 113             die "Failed to symlink: $!\n"
 114                 unless symlink("../perl.third", "perl.third");
 115             die "Symlinked but no executable perl.third: $!\n"
 116                 unless -x 'perl.third';
 117         }
 118     }
 119 }
 120
 121 # check leakage for embedders
 122 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 123
 124 $ENV{EMXSHELL} = 'sh';        # For OS/2
 125
 126 if ($show_elapsed_time) { require Time::HiRes }
 127
 128 my %skip = (
 129             '.' => 1,
 130             '..' => 1,
 131             'CVS' => 1,
 132             'RCS' => 1,
 133             'SCCS' => 1,
 134             '.svn' => 1,
 135            );
 136
 137 # Roll your own File::Find!
 138 sub _find_tests {
 139     my($dir) = @_;
 140     opendir DIR, $dir or die "Trouble opening $dir: $!";
 141     foreach my $f (sort { $a cmp $b } readdir DIR) {
 142         next if $skip{$f};
 143
 144         my $fullpath = "$dir/$f";
 145
 146         if (-d $fullpath) {
 147             _find_tests($fullpath);
 148         } elsif ($f =~ /\.t$/) {
 149             push @ARGV, $fullpath;
 150         }
 151     }
 152 }
 153
 154
 155 # Scan the text of the test program to find switches and special options
 156 # we might need to apply.
 157 sub _scan_test {
 158     my($test, $type) = @_;
 159
 160     open(my $script, "<", $test) or die "Can't read $test.\n";
 161     my $first_line = <$script>;
 162
 163     $first_line =~ tr/\0//d if $::with_utf16;
 164
 165     my $switch = "";
 166     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 167         $switch = "-$1";
 168     } else {
 169         if ($::taintwarn) {
 170             # not all tests are expected to pass with this option
 171             $switch = '-t';
 172         } else {
 173             $switch = '';
 174         }
 175     }
 176
 177     my $file_opts = "";
 178     if ($type eq 'deparse') {
 179         # Look for #line directives which change the filename
 180         while (<$script>) {
 181             $file_opts .= ",-f$3$4"
 182               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 183         }
 184     }
 185
 186     close $script;
 187
 188     my $perl = './perl';
 189     my $lib  = '../lib';
 190     my $run_dir;
 191     my $return_dir;
 192
 193     $test =~ /^(.+)\/[^\/]+/;
 194     my $dir = $1;
 195     my $testswitch = $dir_to_switch{$dir};
 196     if (!defined $testswitch) {
 197         if ($test =~ s!^(\.\./(?:cpan|ext)/[^/]+)/t!t!) {
 198             $run_dir = $1;
 199             $return_dir = '../../t';
 200             $lib = '../../lib';
 201             $perl = '../../t/perl';
 202             $testswitch = "-I../.. -MTestInit=U2T";
 203             if (!$no_abs{$run_dir}) {
 204                 $testswitch = $testswitch . ',A';
 205             }
 206             if ($temp_no_core{$run_dir}) {
 207                 $testswitch = $testswitch . ',NC';
 208             }
 209         } else {
 210             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 211         }
 212     }
 213
 214     my $utf8 = $::with_utf8 ? "-I$lib -Mutf8" : '';
 215
 216     my %options = (
 217         perl => $perl,
 218         lib => $lib,
 219         test => $test,
 220         run_dir => $run_dir,
 221         return_dir => $return_dir,
 222         testswitch => $testswitch,
 223         utf8 => $utf8,
 224         file => $file_opts,
 225         switch => $switch,
 226     );
 227
 228     return \%options;
 229 }
 230
 231 sub _cmd {
 232     my($options, $type) = @_;
 233
 234     my $test = $options->{test};
 235
 236     my $cmd;
 237     if ($type eq 'deparse') {
 238         my $perl = "$options->{perl} $options->{testswitch}";
 239         my $lib = $options->{lib};
 240
 241         $cmd = (
 242           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 243           "-l$::deparse_opts$options->{file} ".
 244           "$test > $test.dp ".
 245           "&& $perl $options->{switch} -I$lib $test.dp"
 246         );
 247     }
 248     elsif ($type eq 'perl') {
 249         my $perl = $options->{perl};
 250         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 251
 252         if ($ENV{PERL_VALGRIND}) {
 253             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 254             my $vg_opts = $ENV{VG_OPTS}
 255               //  "--suppressions=perl.supp --leak-check=yes "
 256                 . "--leak-resolution=high --show-reachable=yes "
 257                   . "--num-callers=50";
 258             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 259             $redir = "3>$Valgrind_Log";
 260         }
 261
 262         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 263         $cmd = $perl . _quote_args($args) . " $test $redir";
 264     }
 265
 266     return $cmd;
 267 }
 268
 269 sub _before_fork {
 270     my ($options) = @_;
 271
 272     if ($options->{run_dir}) {
 273         my $run_dir = $options->{run_dir};
 274         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 275     }
 276
 277     return;
 278 }
 279
 280 sub _after_fork {
 281     my ($options) = @_;
 282
 283     if ($options->{return_dir}) {
 284         my $return_dir = $options->{return_dir};
 285         chdir $return_dir
 286            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 287     }
 288
 289     return;
 290 }
 291
 292 sub _run_test {
 293     my ($test, $type) = @_;
 294
 295     my $options = _scan_test($test, $type);
 296     # $test might have changed if we're in ext/Foo, so don't use it anymore
 297     # from now on. Use $options->{test} instead.
 298
 299     _before_fork($options);
 300
 301     my $cmd = _cmd($options, $type);
 302
 303     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 304
 305     _after_fork($options);
 306
 307     # Our environment may force us to use UTF-8, but we can't be sure that
 308     # anything we're reading from will be generating (well formed) UTF-8
 309     # This may not be the best way - possibly we should unset ${^OPEN} up
 310     # top?
 311     binmode $results;
 312
 313     return $results;
 314 }
 315
 316 sub _quote_args {
 317     my ($args) = @_;
 318     my $argstring = '';
 319
 320     foreach (split(/\s+/,$args)) {
 321        # In VMS protect with doublequotes because otherwise
 322        # DCL will lowercase -- unless already doublequoted.
 323        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 324        $argstring .= ' ' . $_;
 325     }
 326     return $argstring;
 327 }
 328
 329 sub _populate_hash {
 330     return unless defined $_[0];
 331     return map {$_, 1} split /\s+/, $_[0];
 332 }
 333
 334 sub _tests_from_manifest {
 335     my ($extensions, $known_extensions) = @_;
 336     my %skip;
 337     my %extensions = _populate_hash($extensions);
 338     my %known_extensions = _populate_hash($known_extensions);
 339
 340     foreach (keys %known_extensions) {
 341         $skip{$_}++ unless $extensions{$_};
 342     }
 343
 344     my @results;
 345     my $mani = '../MANIFEST';
 346     if (open(MANI, $mani)) {
 347         while (<MANI>) {
 348             if (m!^((?:cpan|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 349                 my $t = $1;
 350                 my $extension = $2;
 351                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 352                     if (defined $extension) {
 353                         $extension =~ s!/t$!!;
 354                         # XXX Do I want to warn that I'm skipping these?
 355                         next if $skip{$extension};
 356                         my $flat_extension = $extension;
 357                         $flat_extension =~ s!-!/!g;
 358                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 359                     }
 360                     my $path = "../$t";
 361                     push @results, $path;
 362                     $::path_to_name{$path} = $t;
 363                 }
 364             }
 365         }
 366         close MANI;
 367     } else {
 368         warn "$0: cannot open $mani: $!\n";
 369     }
 370     return @results;
 371 }
 372
 373 unless (@ARGV) {
 374     # base first, as TEST bails out if that can't run
 375     # then comp, to validate that require works
 376     # then run, to validate that -M works
 377     # then we know we can -MTestInit for everything else, making life simpler
 378     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 379         _find_tests($dir);
 380     }
 381     _find_tests("lib") unless $::core;
 382     # Config.pm may be broken for make minitest. And this is only a refinement
 383     # for skipping tests on non-default builds, so it is allowed to fail.
 384     # What we want to to is make a list of extensions which we did not build.
 385     my $configsh = '../config.sh';
 386     my ($extensions, $known_extensions);
 387     if (-f $configsh) {
 388         open FH, $configsh or die "Can't open $configsh: $!";
 389         while (<FH>) {
 390             if (/^extensions=['"](.*)['"]$/) {
 391                 $extensions = $1;
 392             }
 393             elsif (/^known_extensions=['"](.*)['"]$/) {
 394                 $known_extensions = $1;
 395             }
 396         }
 397         if (!defined $known_extensions) {
 398             warn "No known_extensions line found in $configsh";
 399         }
 400         if (!defined $extensions) {
 401             warn "No extensions line found in $configsh";
 402         }
 403     }
 404     # The "complex" constructions of list return from a subroutine, and push of
 405     # a list, might fail if perl is really hosed, but they aren't needed for
 406     # make minitest, and the building of extensions will likely also fail if
 407     # something is that badly wrong.
 408     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 409     unless ($::core) {
 410         _find_tests('pod');
 411         _find_tests('x2p');
 412         _find_tests('porting');
 413         _find_tests('japh') if $::torture;
 414         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 415     }
 416 }
 417
 418 if ($::deparse) {
 419     _testprogs('deparse', '',   @ARGV);
 420 }
 421 elsif ($::with_utf16) {
 422     for my $e (0, 1) {
 423         for my $b (0, 1) {
 424             print STDERR "# ENDIAN $e BOM $b\n";
 425             my @UARGV;
 426             for my $a (@ARGV) {
 427                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 428                 my $f = $e ? "v" : "n";
 429                 push @UARGV, $u;
 430                 unlink($u);
 431                 if (open(A, $a)) {
 432                     if (open(U, ">$u")) {
 433                         print U pack("$f", 0xFEFF) if $b;
 434                         while (<A>) {
 435                             print U pack("$f*", unpack("C*", $_));
 436                         }
 437                         close(U);
 438                     }
 439                     close(A);
 440                 }
 441             }
 442             _testprogs('perl', '', @UARGV);
 443             unlink(@UARGV);
 444         }
 445     }
 446 }
 447 else {
 448     _testprogs('perl',    '',   @ARGV);
 449 }
 450
 451 sub _testprogs {
 452     my ($type, $args, @tests) = @_;
 453
 454     print <<'EOT' if ($type eq 'deparse');
 455 ------------------------------------------------------------------------------
 456 TESTING DEPARSER
 457 ------------------------------------------------------------------------------
 458 EOT
 459
 460     $::bad_files = 0;
 461
 462     foreach my $t (@tests) {
 463       unless (exists $::path_to_name{$t}) {
 464         my $tname = "t/$t";
 465         $::path_to_name{$t} = $tname;
 466       }
 467     }
 468     my $maxlen = 0;
 469     foreach (@::path_to_name{@tests}) {
 470         s/\.\w+\z/./;
 471         my $len = length ;
 472         $maxlen = $len if $len > $maxlen;
 473     }
 474     # + 3 : we want three dots between the test name and the "ok"
 475     my $dotdotdot = $maxlen + 3 ;
 476     my $valgrind = 0;
 477     my $total_files = @tests;
 478     my $good_files = 0;
 479     my $tested_files  = 0;
 480     my $totmax = 0;
 481     my %failed_tests;
 482
 483     while (my $test = shift @tests) {
 484         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 485
 486         if ($test =~ /^$/) {
 487             next;
 488         }
 489         if ($type eq 'deparse') {
 490             if ($test eq "comp/redef.t") {
 491                 # Redefinition happens at compile time
 492                 next;
 493             }
 494             elsif ($test =~ m{lib/Switch/t/}) {
 495                 # B::Deparse doesn't support source filtering
 496                 next;
 497             }
 498         }
 499         my $te = $::path_to_name{$test} . '.'
 500                     x ($dotdotdot - length($::path_to_name{$test}));
 501
 502         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 503             print $te;
 504             $te = '';
 505         }
 506
 507         my $results = _run_test($test, $type);
 508
 509         my $failure;
 510         my $next = 0;
 511         my $seen_leader = 0;
 512         my $seen_ok = 0;
 513         my $trailing_leader = 0;
 514         my $max;
 515         my %todo;
 516         while (<$results>) {
 517             next if /^\s*$/; # skip blank lines
 518             if (/^1..$/ && ($^O eq 'VMS')) {
 519                 # VMS pipe bug inserts blank lines.
 520                 my $l2 = <RESULTS>;
 521                 if ($l2 =~ /^\s*$/) {
 522                     $l2 = <RESULTS>;
 523                 }
 524                 $_ = '1..' . $l2;
 525             }
 526             if ($::verbose) {
 527                 print $_;
 528             }
 529             unless (/^\#/) {
 530                 if ($trailing_leader) {
 531                     # shouldn't be anything following a postfix 1..n
 532                     $failure = 'FAILED--extra output after trailing 1..n';
 533                     last;
 534                 }
 535                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 536                     if ($seen_leader) {
 537                         $failure = 'FAILED--seen duplicate leader';
 538                         last;
 539                     }
 540                     $max = $1;
 541                     %todo = map { $_ => 1 } split / /, $3 if $3;
 542                     $totmax += $max;
 543                     $tested_files++;
 544                     if ($seen_ok) {
 545                         # 1..n appears at end of file
 546                         $trailing_leader = 1;
 547                         if ($next != $max) {
 548                             $failure = "FAILED--expected $max tests, saw $next";
 549                             last;
 550                         }
 551                     }
 552                     else {
 553                         $next = 0;
 554                     }
 555                     $seen_leader = 1;
 556                 }
 557                 else {
 558                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 559                         unless ($seen_leader) {
 560                             unless ($seen_ok) {
 561                                 $next = 0;
 562                             }
 563                         }
 564                         $seen_ok = 1;
 565                         $next++;
 566                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 567                         $num = $next unless $num;
 568
 569                         if ($num == $next) {
 570
 571                             # SKIP is essentially the same as TODO for t/TEST
 572                             # this still conforms to TAP:
 573                             # http://search.cpan.org/dist/TAP/TAP.pm
 574                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 575                             $istodo = 1 if $todo{$num};
 576
 577                             if( $not && !$istodo ) {
 578                                 $failure = "FAILED at test $num";
 579                                 last;
 580                             }
 581                         }
 582                         else {
 583                             $failure ="FAILED--expected test $next, saw test $num";
 584                             last;
 585                         }
 586                     }
 587                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 588                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 589                     }
 590                     else {
 591                         # module tests are allowed extra output,
 592                         # because Test::Harness allows it
 593                         next if $test =~ /^\W*(ext|lib)\b/;
 594                         $failure = "FAILED--unexpected output at test $next";
 595                         last;
 596                     }
 597                 }
 598             }
 599         }
 600         close $results;
 601
 602         if (not defined $failure) {
 603             $failure = 'FAILED--no leader found' unless $seen_leader;
 604         }
 605
 606         if ($ENV{PERL_VALGRIND}) {
 607             my @valgrind;
 608             if (-e $Valgrind_Log) {
 609                 if (open(V, $Valgrind_Log)) {
 610                     @valgrind = <V>;
 611                     close V;
 612                 } else {
 613                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 614                 }
 615             }
 616             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 617                 if (rename $Valgrind_Log, "$test.valgrind") {
 618                     $valgrind++;
 619                 } else {
 620                     warn "$0: Failed to create '$test.valgrind': $!\n";
 621                 }
 622             }
 623             elsif (@valgrind) {
 624                 my $leaks = 0;
 625                 my $errors = 0;
 626                 for my $i (0..$#valgrind) {
 627                     local $_ = $valgrind[$i];
 628                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 629                         $errors += $1;   # there may be multiple error summaries
 630                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 631                         for my $off (1 .. 4) {
 632                             if ($valgrind[$i+$off] =~
 633                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 634                                 $leaks += $1;
 635                             }
 636                         }
 637                     }
 638                 }
 639                 if ($errors or $leaks) {
 640                     if (rename $Valgrind_Log, "$test.valgrind") {
 641                         $valgrind++;
 642                     } else {
 643                         warn "$0: Failed to create '$test.valgrind': $!\n";
 644                     }
 645                 }
 646             } else {
 647                 warn "No valgrind output?\n";
 648             }
 649             if (-e $Valgrind_Log) {
 650                 unlink $Valgrind_Log
 651                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 652             }
 653         }
 654         if ($type eq 'deparse') {
 655             unlink "./$test.dp";
 656         }
 657         if ($ENV{PERL_3LOG}) {
 658             my $tpp = $test;
 659             $tpp =~ s:^\.\./::;
 660             $tpp =~ s:/:_:g;
 661             $tpp =~ s:\.t$:.3log:;
 662             rename("perl.3log", $tpp) ||
 663                 die "rename: perl3.log to $tpp: $!\n";
 664         }
 665         if (not defined $failure and $next != $max) {
 666             $failure="FAILED--expected $max tests, saw $next";
 667         }
 668
 669         if( !defined $failure  # don't mask a test failure
 670             and $? )
 671         {
 672             $failure = "FAILED--non-zero wait status: $?";
 673         }
 674
 675         if (defined $failure) {
 676             print "${te}$failure\n";
 677             $::bad_files++;
 678             if ($test =~ /^base/) {
 679                 die "Failed a basic test ($test) -- cannot continue.\n";
 680             }
 681             ++$failed_tests{$test};
 682         }
 683         else {
 684             if ($max) {
 685                 my $elapsed;
 686                 if ( $show_elapsed_time ) {
 687                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 688                 }
 689                 else {
 690                     $elapsed = "";
 691                 }
 692                 print "${te}ok$elapsed\n";
 693                 $good_files++;
 694             }
 695             else {
 696                 print "${te}skipped\n";
 697                 $tested_files -= 1;
 698             }
 699         }
 700     } # while tests
 701
 702     if ($::bad_files == 0) {
 703         if ($good_files) {
 704             print "All tests successful.\n";
 705             # XXX add mention of 'perlbug -ok' ?
 706         }
 707         else {
 708             die "FAILED--no tests were run for some reason.\n";
 709         }
 710     }
 711     else {
 712         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 713         my $s = $::bad_files == 1 ? "" : "s";
 714         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 715         for my $test ( sort keys %failed_tests ) {
 716             print "\t$test\n";
 717         }
 718         warn <<'SHRDLU_1';
 719 ### Since not all tests were successful, you may want to run some of
 720 ### them individually and examine any diagnostic messages they produce.
 721 ### See the INSTALL document's section on "make test".
 722 SHRDLU_1
 723         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 724 ### You have a good chance to get more information by running
 725 ###   ./perl harness
 726 ### in the 't' directory since most (>=80%) of the tests succeeded.
 727 SHRDLU_2
 728         if (eval {require Config; import Config; 1}) {
 729             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 730                 warn <<SHRDLU_3;
 731 ### You may have to set your dynamic library search path,
 732 ### $p, to point to the build directory:
 733 SHRDLU_3
 734                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 735                     warn <<SHRDLU_4a;
 736 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 737 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 738 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 739 SHRDLU_4a
 740                 } else {
 741                     warn <<SHRDLU_4b;
 742 ###   setenv $p `pwd`; cd t; ./perl harness
 743 ###   $p=`pwd`; export $p; cd t; ./perl harness
 744 ###   export $p=`pwd`; cd t; ./perl harness
 745 SHRDLU_4b
 746                 }
 747                 warn <<SHRDLU_5;
 748 ### for csh-style shells, like tcsh; or for traditional/modern
 749 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 750 SHRDLU_5
 751             }
 752         }
 753     }
 754     my ($user,$sys,$cuser,$csys) = times;
 755     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 756         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 757     if ($ENV{PERL_VALGRIND}) {
 758         my $s = $valgrind == 1 ? '' : 's';
 759         print "$valgrind valgrind report$s created.\n", ;
 760     }
 761 }
 762 exit ($::bad_files != 0);
 763
 764 # ex: set ts=8 sts=4 sw=4 noet: