t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 $| = 1;
   9
  10 # for testing TEST only
  11 #BEGIN { require '../lib/strict.pm'; strict->import() };
  12 #BEGIN { require '../lib/warnings.pm'; warnings->import() };
  13
  14 # Let tests know they're running in the perl core.  Useful for modules
  15 # which live dual lives on CPAN.
  16 $ENV{PERL_CORE} = 1;
  17 delete $ENV{PERL5LIB};
  18
  19 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  20 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  21 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
  22
  23 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
  24 {
  25     my @argv = ();
  26     foreach my $idx (0..$#ARGV) {
  27         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  28         $::benchmark = 1 if $1 eq 'benchmark';
  29         $::core    = 1 if $1 eq 'core';
  30         $::verbose = 1 if $1 eq 'v';
  31         $::torture = 1 if $1 eq 'torture';
  32         $::with_utf8 = 1 if $1 eq 'utf8';
  33         $::with_utf16 = 1 if $1 eq 'utf16';
  34         $::taintwarn = 1 if $1 eq 'taintwarn';
  35         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
  36         if ($1 =~ /^deparse(,.+)?$/) {
  37             $::deparse = 1;
  38             $::deparse_opts = $1;
  39         }
  40     }
  41     @ARGV = @argv;
  42 }
  43
  44 chdir 't' if -f 't/TEST';
  45
  46 die "You need to run \"make test\" first to set things up.\n"
  47   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
  48
  49 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
  50     unless (-x 'perl.third') {
  51         unless (-x '../perl.third') {
  52             die "You need to run \"make perl.third first.\n";
  53         }
  54         else {
  55             print "Symlinking ../perl.third as perl.third...\n";
  56             die "Failed to symlink: $!\n"
  57                 unless symlink("../perl.third", "perl.third");
  58             die "Symlinked but no executable perl.third: $!\n"
  59                 unless -x 'perl.third';
  60         }
  61     }
  62 }
  63
  64 # check leakage for embedders
  65 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
  66
  67 $ENV{EMXSHELL} = 'sh';        # For OS/2
  68
  69 # Roll your own File::Find!
  70 use TestInit;
  71 use File::Spec;
  72 if ($show_elapsed_time) { require Time::HiRes }
  73 my $curdir = File::Spec->curdir;
  74 my $updir  = File::Spec->updir;
  75
  76 sub _find_tests {
  77     my($dir) = @_;
  78     opendir DIR, $dir or die "Trouble opening $dir: $!";
  79     foreach my $f (sort { $a cmp $b } readdir DIR) {
  80         next if $f eq $curdir or $f eq $updir or
  81             $f =~ /^(?:CVS|RCS|SCCS|\.svn)$/;
  82
  83         my $fullpath = File::Spec->catfile($dir, $f);
  84
  85         _find_tests($fullpath) if -d $fullpath;
  86         $fullpath = VMS::Filespec::unixify($fullpath) if $^O eq 'VMS';
  87         push @ARGV, $fullpath if $f =~ /\.t$/;
  88     }
  89 }
  90
  91 sub _quote_args {
  92     my ($args) = @_;
  93     my $argstring = '';
  94
  95     foreach (split(/\s+/,$args)) {
  96        # In VMS protect with doublequotes because otherwise
  97        # DCL will lowercase -- unless already doublequoted.
  98        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
  99        $argstring .= ' ' . $_;
 100     }
 101     return $argstring;
 102 }
 103
 104 sub _populate_hash {
 105     return map {$_, 1} split /\s+/, $_[0];
 106 }
 107
 108 unless (@ARGV) {
 109     foreach my $dir (qw(base comp cmd run io op uni mro)) {
 110         _find_tests($dir);
 111     }
 112     _find_tests("lib") unless $::core;
 113     # Config.pm may be broken for make minitest. And this is only a refinement
 114     # for skipping tests on non-default builds, so it is allowed to fail.
 115     # What we want to to is make a list of extensions which we did not build.
 116     my $configsh = File::Spec->catfile($updir, "config.sh");
 117     my %skip;
 118     if (-f $configsh) {
 119         my (%extensions, %known_extensions);
 120         open FH, $configsh or die "Can't open $configsh: $!";
 121         while (<FH>) {
 122             if (/^extensions=['"](.*)['"]$/) {
 123                 # Deliberate string interpolation to avoid triggering possible
 124                 # $1 resetting bugs.
 125                 %extensions = _populate_hash ("$1");
 126             }
 127             elsif (/^known_extensions=['"](.*)['"]$/) {
 128                 %known_extensions = _populate_hash ($1);
 129             }
 130         }
 131         if (%extensions) {
 132             if (%known_extensions) {
 133                 foreach (keys %known_extensions) {
 134                     $skip{$_}++ unless $extensions{$_};
 135                 }
 136             } else {
 137                 warn "No known_extensions line found in $configsh";
 138             }
 139         } else {
 140             warn "No extensions line found in $configsh";
 141         }
 142     }
 143     my $mani = File::Spec->catfile($updir, "MANIFEST");
 144     if (open(MANI, $mani)) {
 145         while (<MANI>) { # similar code in t/harness
 146             if (m!^(ext/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 147                 my $t = $1;
 148                 my $extension = $2;
 149                 if (!$::core || $t =~ m!^lib/[a-z]!)
 150                 {
 151                     if (defined $extension) {
 152                         $extension =~ s!/t$!!;
 153                         # XXX Do I want to warn that I'm skipping these?
 154                         next if $skip{$extension};
 155                         my $flat_extension = $extension;
 156                         $flat_extension =~ s!-!/!g;
 157                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 158                     }
 159                     my $path = File::Spec->catfile($updir, $t);
 160                     push @ARGV, $path;
 161                     $::path_to_name{$path} = $t;
 162                 }
 163             }
 164         }
 165         close MANI;
 166     } else {
 167         warn "$0: cannot open $mani: $!\n";
 168     }
 169     unless ($::core) {
 170         _find_tests('pod');
 171         _find_tests('x2p');
 172         _find_tests('porting');
 173         _find_tests('japh') if $::torture;
 174         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 175     }
 176 }
 177
 178 if ($::deparse) {
 179     _testprogs('deparse', '',   @ARGV);
 180 }
 181 elsif ($::with_utf16) {
 182     for my $e (0, 1) {
 183         for my $b (0, 1) {
 184             print STDERR "# ENDIAN $e BOM $b\n";
 185             my @UARGV;
 186             for my $a (@ARGV) {
 187                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 188                 my $f = $e ? "v" : "n";
 189                 push @UARGV, $u;
 190                 unlink($u);
 191                 if (open(A, $a)) {
 192                     if (open(U, ">$u")) {
 193                         print U pack("$f", 0xFEFF) if $b;
 194                         while (<A>) {
 195                             print U pack("$f*", unpack("C*", $_));
 196                         }
 197                         close(U);
 198                     }
 199                     close(A);
 200                 }
 201             }
 202             _testprogs('perl', '', @UARGV);
 203             unlink(@UARGV);
 204         }
 205     }
 206 }
 207 else {
 208     _testprogs('perl',    '',   @ARGV);
 209 }
 210
 211 sub _testprogs {
 212     my ($type, $args, @tests) = @_;
 213
 214     print <<'EOT' if ($type eq 'deparse');
 215 ------------------------------------------------------------------------------
 216 TESTING DEPARSER
 217 ------------------------------------------------------------------------------
 218 EOT
 219
 220     $::bad_files = 0;
 221
 222     foreach my $t (@tests) {
 223       unless (exists $::path_to_name{$t}) {
 224         my $tname = File::Spec->catfile('t',$t);
 225         $tname = VMS::Filespec::unixify($tname) if $^O eq 'VMS';
 226         $::path_to_name{$t} = $tname;
 227       }
 228     }
 229     my $maxlen = 0;
 230     foreach (@::path_to_name{@tests}) {
 231         s/\.\w+\z/./;
 232         my $len = length ;
 233         $maxlen = $len if $len > $maxlen;
 234     }
 235     # + 3 : we want three dots between the test name and the "ok"
 236     my $dotdotdot = $maxlen + 3 ;
 237     my $valgrind = 0;
 238     my $valgrind_log = 'current.valgrind';
 239     my $total_files = @tests;
 240     my $good_files = 0;
 241     my $tested_files  = 0;
 242     my $totmax = 0;
 243     my %failed_tests;
 244
 245     while (my $test = shift @tests) {
 246         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 247
 248         if ($test =~ /^$/) {
 249             next;
 250         }
 251         if ($type eq 'deparse') {
 252             if ($test eq "comp/redef.t") {
 253                 # Redefinition happens at compile time
 254                 next;
 255             }
 256             elsif ($test =~ m{lib/Switch/t/}) {
 257                 # B::Deparse doesn't support source filtering
 258                 next;
 259             }
 260         }
 261         my $te = $::path_to_name{$test} . '.'
 262                     x ($dotdotdot - length($::path_to_name{$test}));
 263
 264         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 265             print $te;
 266             $te = '';
 267         }
 268
 269         # XXX DAPM %OVER not defined anywhere
 270         # $test = $OVER{$test} if exists $OVER{$test};
 271
 272         open(SCRIPT,"<",$test) or die "Can't run $test.\n";
 273         $_ = <SCRIPT>;
 274         close(SCRIPT) unless ($type eq 'deparse');
 275         if ($::with_utf16) {
 276             $_ =~ tr/\0//d;
 277         }
 278         my $switch;
 279         if (/#!.*\bperl.*\s-\w*([tT])/) {
 280             $switch = qq{"-$1"};
 281         }
 282         else {
 283             if ($::taintwarn) {
 284                 # not all tests are expected to pass with this option
 285                 $switch = '"-t"';
 286             }
 287             else {
 288                 $switch = '';
 289             }
 290         }
 291
 292         my $file_opts = "";
 293         if ($type eq 'deparse') {
 294             # Look for #line directives which change the filename
 295             while (<SCRIPT>) {
 296                 $file_opts .= ",-f$3$4"
 297                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 298             }
 299             close(SCRIPT);
 300         }
 301
 302         my $utf8 = $::with_utf8 ? '-I../lib -Mutf8' : '';
 303         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
 304         if ($type eq 'deparse') {
 305             my $deparse_cmd =
 306                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,-sv1.,".
 307                 "-l$::deparse_opts$file_opts ".
 308                 "$test > $test.dp ".
 309                 "&& ./perl $testswitch $switch -I../lib $test.dp |";
 310             open(RESULTS, $deparse_cmd)
 311                 or print "can't deparse '$deparse_cmd': $!.\n";
 312         }
 313         elsif ($type eq 'perl') {
 314             my $perl = $ENV{PERL} || './perl';
 315             my $redir = $^O eq 'VMS' ? '2>&1' : '';
 316             if ($ENV{PERL_VALGRIND}) {
 317                 my $valgrind = $ENV{VALGRIND} // 'valgrind';
 318                 my $vg_opts = $ENV{VG_OPTS}
 319                     //  "--suppressions=perl.supp --leak-check=yes "
 320                         . "--leak-resolution=high --show-reachable=yes "
 321                         . "--num-callers=50";
 322                 $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 323                 $redir = "3>$valgrind_log";
 324             }
 325             my $run = "$perl" . _quote_args("$testswitch $switch $utf8")
 326                               . " $test $redir|";
 327             open(RESULTS,$run) or print "can't run '$run': $!.\n";
 328         }
 329         # Our environment may force us to use UTF-8, but we can't be sure that
 330         # anything we're reading from will be generating (well formed) UTF-8
 331         # This may not be the best way - possibly we should unset ${^OPEN} up
 332         # top?
 333         binmode RESULTS;
 334
 335         my $failure;
 336         my $next = 0;
 337         my $seen_leader = 0;
 338         my $seen_ok = 0;
 339         my $trailing_leader = 0;
 340         my $max;
 341         my %todo;
 342         while (<RESULTS>) {
 343             next if /^\s*$/; # skip blank lines
 344             if (/^1..$/ && ($^O eq 'VMS')) {
 345                 # VMS pipe bug inserts blank lines.
 346                 my $l2 = <RESULTS>;
 347                 if ($l2 =~ /^\s*$/) {
 348                     $l2 = <RESULTS>;
 349                 }
 350                 $_ = '1..' . $l2;
 351             }
 352             if ($::verbose) {
 353                 print $_;
 354             }
 355             unless (/^\#/) {
 356                 if ($trailing_leader) {
 357                     # shouldn't be anything following a postfix 1..n
 358                     $failure = 'FAILED--extra output after trailing 1..n';
 359                     last;
 360                 }
 361                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 362                     if ($seen_leader) {
 363                         $failure = 'FAILED--seen duplicate leader';
 364                         last;
 365                     }
 366                     $max = $1;
 367                     %todo = map { $_ => 1 } split / /, $3 if $3;
 368                     $totmax += $max;
 369                     $tested_files++;
 370                     if ($seen_ok) {
 371                         # 1..n appears at end of file
 372                         $trailing_leader = 1;
 373                         if ($next != $max) {
 374                             $failure = "FAILED--expected $max tests, saw $next";
 375                             last;
 376                         }
 377                     }
 378                     else {
 379                         $next = 0;
 380                     }
 381                     $seen_leader = 1;
 382                 }
 383                 else {
 384                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 385                         unless ($seen_leader) {
 386                             unless ($seen_ok) {
 387                                 $next = 0;
 388                             }
 389                         }
 390                         $seen_ok = 1;
 391                         $next++;
 392                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 393                         $num = $next unless $num;
 394
 395                         if ($num == $next) {
 396
 397                             # SKIP is essentially the same as TODO for t/TEST
 398                             # this still conforms to TAP:
 399                             # http://search.cpan.org/dist/TAP/TAP.pod
 400                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 401                             $istodo = 1 if $todo{$num};
 402
 403                             if( $not && !$istodo ) {
 404                                 $failure = "FAILED at test $num";
 405                                 last;
 406                             }
 407                         }
 408                         else {
 409                             $failure ="FAILED--expected test $next, saw test $num";
 410                             last;
 411                         }
 412                     }
 413                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 414                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 415                     }
 416                     else {
 417                         # module tests are allowed extra output,
 418                         # because Test::Harness allows it
 419                         next if $test =~ /^\W*(ext|lib)\b/;
 420                         $failure = "FAILED--unexpected output at test $next";
 421                         last;
 422                     }
 423                 }
 424             }
 425         }
 426         close RESULTS;
 427
 428         if (not defined $failure) {
 429             $failure = 'FAILED--no leader found' unless $seen_leader;
 430         }
 431
 432         if ($ENV{PERL_VALGRIND}) {
 433             my @valgrind;
 434             if (-e $valgrind_log) {
 435                 if (open(V, $valgrind_log)) {
 436                     @valgrind = <V>;
 437                     close V;
 438                 } else {
 439                     warn "$0: Failed to open '$valgrind_log': $!\n";
 440                 }
 441             }
 442             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 443                 if (rename $valgrind_log, "$test.valgrind") {
 444                     $valgrind++;
 445                 } else {
 446                     warn "$0: Failed to create '$test.valgrind': $!\n";
 447                 }
 448             }
 449             elsif (@valgrind) {
 450                 my $leaks = 0;
 451                 my $errors = 0;
 452                 for my $i (0..$#valgrind) {
 453                     local $_ = $valgrind[$i];
 454                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 455                         $errors += $1;   # there may be multiple error summaries
 456                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 457                         for my $off (1 .. 4) {
 458                             if ($valgrind[$i+$off] =~
 459                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 460                                 $leaks += $1;
 461                             }
 462                         }
 463                     }
 464                 }
 465                 if ($errors or $leaks) {
 466                     if (rename $valgrind_log, "$test.valgrind") {
 467                         $valgrind++;
 468                     } else {
 469                         warn "$0: Failed to create '$test.valgrind': $!\n";
 470                     }
 471                 }
 472             } else {
 473                 warn "No valgrind output?\n";
 474             }
 475             if (-e $valgrind_log) {
 476                 unlink $valgrind_log
 477                     or warn "$0: Failed to unlink '$valgrind_log': $!\n";
 478             }
 479         }
 480         if ($type eq 'deparse') {
 481             unlink "./$test.dp";
 482         }
 483         if ($ENV{PERL_3LOG}) {
 484             my $tpp = $test;
 485             $tpp =~ s:^\.\./::;
 486             $tpp =~ s:/:_:g;
 487             $tpp =~ s:\.t$:.3log:;
 488             rename("perl.3log", $tpp) ||
 489                 die "rename: perl3.log to $tpp: $!\n";
 490         }
 491         if (not defined $failure and $next != $max) {
 492             $failure="FAILED--expected $max tests, saw $next";
 493         }
 494
 495         if( !defined $failure  # don't mask a test failure
 496             and $? )
 497         {
 498             $failure = "FAILED--non-zero wait status: $?";
 499         }
 500
 501         if (defined $failure) {
 502             print "${te}$failure\n";
 503             $::bad_files++;
 504             if ($test =~ /^base/) {
 505                 die "Failed a basic test ($test) -- cannot continue.\n";
 506             }
 507             ++$failed_tests{$test};
 508         }
 509         else {
 510             if ($max) {
 511                 my $elapsed;
 512                 if ( $show_elapsed_time ) {
 513                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 514                 }
 515                 else {
 516                     $elapsed = "";
 517                 }
 518                 print "${te}ok$elapsed\n";
 519                 $good_files++;
 520             }
 521             else {
 522                 print "${te}skipped\n";
 523                 $tested_files -= 1;
 524             }
 525         }
 526     } # while tests
 527
 528     if ($::bad_files == 0) {
 529         if ($good_files) {
 530             print "All tests successful.\n";
 531             # XXX add mention of 'perlbug -ok' ?
 532         }
 533         else {
 534             die "FAILED--no tests were run for some reason.\n";
 535         }
 536     }
 537     else {
 538         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 539         my $s = $::bad_files == 1 ? "" : "s";
 540         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 541         for my $test ( sort keys %failed_tests ) {
 542             print "\t$test\n";
 543         }
 544         warn <<'SHRDLU_1';
 545 ### Since not all tests were successful, you may want to run some of
 546 ### them individually and examine any diagnostic messages they produce.
 547 ### See the INSTALL document's section on "make test".
 548 SHRDLU_1
 549         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 550 ### You have a good chance to get more information by running
 551 ###   ./perl harness
 552 ### in the 't' directory since most (>=80%) of the tests succeeded.
 553 SHRDLU_2
 554         if (eval {require Config; import Config; 1}) {
 555             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 556                 warn <<SHRDLU_3;
 557 ### You may have to set your dynamic library search path,
 558 ### $p, to point to the build directory:
 559 SHRDLU_3
 560                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 561                     warn <<SHRDLU_4a;
 562 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 563 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 564 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 565 SHRDLU_4a
 566                 } else {
 567                     warn <<SHRDLU_4b;
 568 ###   setenv $p `pwd`; cd t; ./perl harness
 569 ###   $p=`pwd`; export $p; cd t; ./perl harness
 570 ###   export $p=`pwd`; cd t; ./perl harness
 571 SHRDLU_4b
 572                 }
 573                 warn <<SHRDLU_5;
 574 ### for csh-style shells, like tcsh; or for traditional/modern
 575 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 576 SHRDLU_5
 577             }
 578         }
 579     }
 580     my ($user,$sys,$cuser,$csys) = times;
 581     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 582         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 583     if ($ENV{PERL_VALGRIND}) {
 584         my $s = $valgrind == 1 ? '' : 's';
 585         print "$valgrind valgrind report$s created.\n", ;
 586     }
 587 }
 588 exit ($::bad_files != 0);
 589
 590 # ex: set ts=8 sts=4 sw=4 noet: