t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # I think in the end I'd like "not absolute" to be the default", as it saves
  27 # some fakery within TestInit which can peturb tests, and takes CPU.
  28 my %no_abs =
  29     ('../cpan/Pod-Parser' => 1,
  30     );
  31
  32 my %temp_no_core =
  33     ('../cpan/B-Debug' => 1,
  34      '../cpan/Compress-Raw-Bzip2' => 1,
  35      '../cpan/Compress-Raw-Zlib' => 1,
  36      '../cpan/Devel-PPPort' => 1,
  37      '../cpan/Getopt-Long' => 1,
  38      '../cpan/IO-Compress' => 1,
  39      '../cpan/Math-BigInt' => 1,
  40      '../cpan/Math-BigRat' => 1,
  41      '../cpan/MIME-Base64' => 1,
  42      '../cpan/NEXT' => 1,
  43      '../cpan/parent' => 1,
  44      '../cpan/Parse-CPAN-Meta' => 1,
  45      '../cpan/Pod-Simple' => 1,
  46      '../cpan/podlators' => 1,
  47      '../cpan/Test-Simple' => 1,
  48      '../cpan/Tie-RefHash' => 1,
  49      '../cpan/Time-HiRes' => 1,
  50      '../cpan/Unicode-Collate' => 1,
  51      '../cpan/Unicode-Normalize' => 1,
  52     );
  53
  54 if ($::do_nothing) {
  55     return 1;
  56 }
  57
  58 # Location to put the Valgrind log.
  59 my $Valgrind_Log = 'current.valgrind';
  60
  61 $| = 1;
  62
  63 # for testing TEST only
  64 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
  65 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
  66
  67 delete $ENV{PERL5LIB};
  68 delete $ENV{PERLLIB};
  69 delete $ENV{PERL5OPT};
  70
  71 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  72 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  73 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
  74
  75 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
  76 # can't rely on require working.
  77 {
  78     my @argv = ();
  79     foreach my $idx (0..$#ARGV) {
  80         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  81         $::benchmark = 1 if $1 eq 'benchmark';
  82         $::core    = 1 if $1 eq 'core';
  83         $::verbose = 1 if $1 eq 'v';
  84         $::torture = 1 if $1 eq 'torture';
  85         $::with_utf8 = 1 if $1 eq 'utf8';
  86         $::with_utf16 = 1 if $1 eq 'utf16';
  87         $::taintwarn = 1 if $1 eq 'taintwarn';
  88         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
  89         if ($1 =~ /^deparse(,.+)?$/) {
  90             $::deparse = 1;
  91             $::deparse_opts = $1;
  92         }
  93     }
  94     @ARGV = @argv;
  95 }
  96
  97 chdir 't' if -f 't/TEST';
  98 if (-f 'TEST' && -f 'harness' && -d '../lib') {
  99     @INC = '../lib';
 100 }
 101
 102 die "You need to run \"make test\" first to set things up.\n"
 103   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 104
 105 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 106     unless (-x 'perl.third') {
 107         unless (-x '../perl.third') {
 108             die "You need to run \"make perl.third first.\n";
 109         }
 110         else {
 111             print "Symlinking ../perl.third as perl.third...\n";
 112             die "Failed to symlink: $!\n"
 113                 unless symlink("../perl.third", "perl.third");
 114             die "Symlinked but no executable perl.third: $!\n"
 115                 unless -x 'perl.third';
 116         }
 117     }
 118 }
 119
 120 # check leakage for embedders
 121 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 122
 123 $ENV{EMXSHELL} = 'sh';        # For OS/2
 124
 125 if ($show_elapsed_time) { require Time::HiRes }
 126
 127 my %skip = (
 128             '.' => 1,
 129             '..' => 1,
 130             'CVS' => 1,
 131             'RCS' => 1,
 132             'SCCS' => 1,
 133             '.svn' => 1,
 134            );
 135
 136 # Roll your own File::Find!
 137 sub _find_tests {
 138     my($dir) = @_;
 139     opendir DIR, $dir or die "Trouble opening $dir: $!";
 140     foreach my $f (sort { $a cmp $b } readdir DIR) {
 141         next if $skip{$f};
 142
 143         my $fullpath = "$dir/$f";
 144
 145         if (-d $fullpath) {
 146             _find_tests($fullpath);
 147         } elsif ($f =~ /\.t$/) {
 148             push @ARGV, $fullpath;
 149         }
 150     }
 151 }
 152
 153
 154 # Scan the text of the test program to find switches and special options
 155 # we might need to apply.
 156 sub _scan_test {
 157     my($test, $type) = @_;
 158
 159     open(my $script, "<", $test) or die "Can't read $test.\n";
 160     my $first_line = <$script>;
 161
 162     $first_line =~ tr/\0//d if $::with_utf16;
 163
 164     my $switch = "";
 165     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 166         $switch = "-$1";
 167     } else {
 168         if ($::taintwarn) {
 169             # not all tests are expected to pass with this option
 170             $switch = '-t';
 171         } else {
 172             $switch = '';
 173         }
 174     }
 175
 176     my $file_opts = "";
 177     if ($type eq 'deparse') {
 178         # Look for #line directives which change the filename
 179         while (<$script>) {
 180             $file_opts = $file_opts . ",-f$3$4"
 181               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 182         }
 183     }
 184
 185     close $script;
 186
 187     my $perl = './perl';
 188     my $lib  = '../lib';
 189     my $run_dir;
 190     my $return_dir;
 191
 192     $test =~ /^(.+)\/[^\/]+/;
 193     my $dir = $1;
 194     my $testswitch = $dir_to_switch{$dir};
 195     if (!defined $testswitch) {
 196         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 197             $run_dir = $1;
 198             $return_dir = '../../t';
 199             $lib = '../../lib';
 200             $perl = '../../t/perl';
 201             $testswitch = "-I../.. -MTestInit=U2T";
 202             if ($2 eq 'cpan') {
 203                 if(!$no_abs{$run_dir}) {
 204                     $testswitch = $testswitch . ',A';
 205                 }
 206                 if ($temp_no_core{$run_dir}) {
 207                     $testswitch = $testswitch . ',NC';
 208                 }
 209             }
 210         } else {
 211             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 212         }
 213     }
 214
 215     my $utf8 = $::with_utf8 ? "-I$lib -Mutf8" : '';
 216
 217     my %options = (
 218         perl => $perl,
 219         lib => $lib,
 220         test => $test,
 221         run_dir => $run_dir,
 222         return_dir => $return_dir,
 223         testswitch => $testswitch,
 224         utf8 => $utf8,
 225         file => $file_opts,
 226         switch => $switch,
 227     );
 228
 229     return \%options;
 230 }
 231
 232 sub _cmd {
 233     my($options, $type) = @_;
 234
 235     my $test = $options->{test};
 236
 237     my $cmd;
 238     if ($type eq 'deparse') {
 239         my $perl = "$options->{perl} $options->{testswitch}";
 240         my $lib = $options->{lib};
 241
 242         $cmd = (
 243           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 244           "-l$::deparse_opts$options->{file} ".
 245           "$test > $test.dp ".
 246           "&& $perl $options->{switch} -I$lib $test.dp"
 247         );
 248     }
 249     elsif ($type eq 'perl') {
 250         my $perl = $options->{perl};
 251         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 252
 253         if ($ENV{PERL_VALGRIND}) {
 254             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 255             my $vg_opts = $ENV{VG_OPTS}
 256               //  "--suppressions=perl.supp --leak-check=yes "
 257                 . "--leak-resolution=high --show-reachable=yes "
 258                   . "--num-callers=50";
 259             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 260             $redir = "3>$Valgrind_Log";
 261         }
 262
 263         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 264         $cmd = $perl . _quote_args($args) . " $test $redir";
 265     }
 266
 267     return $cmd;
 268 }
 269
 270 sub _before_fork {
 271     my ($options) = @_;
 272
 273     if ($options->{run_dir}) {
 274         my $run_dir = $options->{run_dir};
 275         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 276     }
 277
 278     return;
 279 }
 280
 281 sub _after_fork {
 282     my ($options) = @_;
 283
 284     if ($options->{return_dir}) {
 285         my $return_dir = $options->{return_dir};
 286         chdir $return_dir
 287            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 288     }
 289
 290     return;
 291 }
 292
 293 sub _run_test {
 294     my ($test, $type) = @_;
 295
 296     my $options = _scan_test($test, $type);
 297     # $test might have changed if we're in ext/Foo, so don't use it anymore
 298     # from now on. Use $options->{test} instead.
 299
 300     _before_fork($options);
 301
 302     my $cmd = _cmd($options, $type);
 303
 304     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 305
 306     _after_fork($options);
 307
 308     # Our environment may force us to use UTF-8, but we can't be sure that
 309     # anything we're reading from will be generating (well formed) UTF-8
 310     # This may not be the best way - possibly we should unset ${^OPEN} up
 311     # top?
 312     binmode $results;
 313
 314     return $results;
 315 }
 316
 317 sub _quote_args {
 318     my ($args) = @_;
 319     my $argstring = '';
 320
 321     foreach (split(/\s+/,$args)) {
 322        # In VMS protect with doublequotes because otherwise
 323        # DCL will lowercase -- unless already doublequoted.
 324        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 325        $argstring = $argstring . ' ' . $_;
 326     }
 327     return $argstring;
 328 }
 329
 330 sub _populate_hash {
 331     return unless defined $_[0];
 332     return map {$_, 1} split /\s+/, $_[0];
 333 }
 334
 335 sub _tests_from_manifest {
 336     my ($extensions, $known_extensions) = @_;
 337     my %skip;
 338     my %extensions = _populate_hash($extensions);
 339     my %known_extensions = _populate_hash($known_extensions);
 340
 341     foreach (keys %known_extensions) {
 342         $skip{$_} = 1 unless $extensions{$_};
 343     }
 344
 345     my @results;
 346     my $mani = '../MANIFEST';
 347     if (open(MANI, $mani)) {
 348         while (<MANI>) {
 349             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 350                 my $t = $1;
 351                 my $extension = $2;
 352                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 353                     if (defined $extension) {
 354                         $extension =~ s!/t$!!;
 355                         # XXX Do I want to warn that I'm skipping these?
 356                         next if $skip{$extension};
 357                         my $flat_extension = $extension;
 358                         $flat_extension =~ s!-!/!g;
 359                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 360                     }
 361                     my $path = "../$t";
 362                     push @results, $path;
 363                     $::path_to_name{$path} = $t;
 364                 }
 365             }
 366         }
 367         close MANI;
 368     } else {
 369         warn "$0: cannot open $mani: $!\n";
 370     }
 371     return @results;
 372 }
 373
 374 unless (@ARGV) {
 375     # base first, as TEST bails out if that can't run
 376     # then comp, to validate that require works
 377     # then run, to validate that -M works
 378     # then we know we can -MTestInit for everything else, making life simpler
 379     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 380         _find_tests($dir);
 381     }
 382     _find_tests("lib") unless $::core;
 383     # Config.pm may be broken for make minitest. And this is only a refinement
 384     # for skipping tests on non-default builds, so it is allowed to fail.
 385     # What we want to to is make a list of extensions which we did not build.
 386     my $configsh = '../config.sh';
 387     my ($extensions, $known_extensions);
 388     if (-f $configsh) {
 389         open FH, $configsh or die "Can't open $configsh: $!";
 390         while (<FH>) {
 391             if (/^extensions=['"](.*)['"]$/) {
 392                 $extensions = $1;
 393             }
 394             elsif (/^known_extensions=['"](.*)['"]$/) {
 395                 $known_extensions = $1;
 396             }
 397         }
 398         if (!defined $known_extensions) {
 399             warn "No known_extensions line found in $configsh";
 400         }
 401         if (!defined $extensions) {
 402             warn "No extensions line found in $configsh";
 403         }
 404     }
 405     # The "complex" constructions of list return from a subroutine, and push of
 406     # a list, might fail if perl is really hosed, but they aren't needed for
 407     # make minitest, and the building of extensions will likely also fail if
 408     # something is that badly wrong.
 409     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 410     unless ($::core) {
 411         _find_tests('x2p');
 412         _find_tests('porting');
 413         _find_tests('japh') if $::torture;
 414         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 415     }
 416 }
 417
 418 if ($::deparse) {
 419     _testprogs('deparse', '',   @ARGV);
 420 }
 421 elsif ($::with_utf16) {
 422     for my $e (0, 1) {
 423         for my $b (0, 1) {
 424             print STDERR "# ENDIAN $e BOM $b\n";
 425             my @UARGV;
 426             for my $a (@ARGV) {
 427                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 428                 my $f = $e ? "v" : "n";
 429                 push @UARGV, $u;
 430                 unlink($u);
 431                 if (open(A, $a)) {
 432                     if (open(U, ">$u")) {
 433                         print U pack("$f", 0xFEFF) if $b;
 434                         while (<A>) {
 435                             print U pack("$f*", unpack("C*", $_));
 436                         }
 437                         close(U);
 438                     }
 439                     close(A);
 440                 }
 441             }
 442             _testprogs('perl', '', @UARGV);
 443             unlink(@UARGV);
 444         }
 445     }
 446 }
 447 else {
 448     _testprogs('perl',    '',   @ARGV);
 449 }
 450
 451 sub _testprogs {
 452     my ($type, $args, @tests) = @_;
 453
 454     print <<'EOT' if ($type eq 'deparse');
 455 ------------------------------------------------------------------------------
 456 TESTING DEPARSER
 457 ------------------------------------------------------------------------------
 458 EOT
 459
 460     $::bad_files = 0;
 461
 462     foreach my $t (@tests) {
 463       unless (exists $::path_to_name{$t}) {
 464         my $tname = "t/$t";
 465         $::path_to_name{$t} = $tname;
 466       }
 467     }
 468     my $maxlen = 0;
 469     foreach (@::path_to_name{@tests}) {
 470         s/\.\w+\z/./;
 471         my $len = length ;
 472         $maxlen = $len if $len > $maxlen;
 473     }
 474     # + 3 : we want three dots between the test name and the "ok"
 475     my $dotdotdot = $maxlen + 3 ;
 476     my $valgrind = 0;
 477     my $total_files = @tests;
 478     my $good_files = 0;
 479     my $tested_files  = 0;
 480     my $totmax = 0;
 481     my %failed_tests;
 482
 483     while (my $test = shift @tests) {
 484         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 485
 486         if ($test =~ /^$/) {
 487             next;
 488         }
 489         if ($type eq 'deparse') {
 490             if ($test eq "comp/redef.t") {
 491                 # Redefinition happens at compile time
 492                 next;
 493             }
 494             elsif ($test =~ m{lib/Switch/t/}) {
 495                 # B::Deparse doesn't support source filtering
 496                 next;
 497             }
 498         }
 499         my $te = $::path_to_name{$test} . '.'
 500                     x ($dotdotdot - length($::path_to_name{$test}));
 501
 502         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 503             print $te;
 504             $te = '';
 505         }
 506
 507         my $results = _run_test($test, $type);
 508
 509         my $failure;
 510         my $next = 0;
 511         my $seen_leader = 0;
 512         my $seen_ok = 0;
 513         my $trailing_leader = 0;
 514         my $max;
 515         my %todo;
 516         while (<$results>) {
 517             next if /^\s*$/; # skip blank lines
 518             if (/^1..$/ && ($^O eq 'VMS')) {
 519                 # VMS pipe bug inserts blank lines.
 520                 my $l2 = <RESULTS>;
 521                 if ($l2 =~ /^\s*$/) {
 522                     $l2 = <RESULTS>;
 523                 }
 524                 $_ = '1..' . $l2;
 525             }
 526             if ($::verbose) {
 527                 print $_;
 528             }
 529             unless (/^\#/) {
 530                 if ($trailing_leader) {
 531                     # shouldn't be anything following a postfix 1..n
 532                     $failure = 'FAILED--extra output after trailing 1..n';
 533                     last;
 534                 }
 535                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 536                     if ($seen_leader) {
 537                         $failure = 'FAILED--seen duplicate leader';
 538                         last;
 539                     }
 540                     $max = $1;
 541                     %todo = map { $_ => 1 } split / /, $3 if $3;
 542                     $totmax = $totmax + $max;
 543                     $tested_files = $tested_files + 1;
 544                     if ($seen_ok) {
 545                         # 1..n appears at end of file
 546                         $trailing_leader = 1;
 547                         if ($next != $max) {
 548                             $failure = "FAILED--expected $max tests, saw $next";
 549                             last;
 550                         }
 551                     }
 552                     else {
 553                         $next = 0;
 554                     }
 555                     $seen_leader = 1;
 556                 }
 557                 else {
 558                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 559                         unless ($seen_leader) {
 560                             unless ($seen_ok) {
 561                                 $next = 0;
 562                             }
 563                         }
 564                         $seen_ok = 1;
 565                         $next = $next + 1;
 566                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 567                         $num = $next unless $num;
 568
 569                         if ($num == $next) {
 570
 571                             # SKIP is essentially the same as TODO for t/TEST
 572                             # this still conforms to TAP:
 573                             # http://search.cpan.org/dist/TAP/TAP.pm
 574                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 575                             $istodo = 1 if $todo{$num};
 576
 577                             if( $not && !$istodo ) {
 578                                 $failure = "FAILED at test $num";
 579                                 last;
 580                             }
 581                         }
 582                         else {
 583                             $failure ="FAILED--expected test $next, saw test $num";
 584                             last;
 585                         }
 586                     }
 587                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 588                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 589                     }
 590                     else {
 591                         # module tests are allowed extra output,
 592                         # because Test::Harness allows it
 593                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 594                         $failure = "FAILED--unexpected output at test $next";
 595                         last;
 596                     }
 597                 }
 598             }
 599         }
 600         close $results;
 601
 602         if (not defined $failure) {
 603             $failure = 'FAILED--no leader found' unless $seen_leader;
 604         }
 605
 606         if ($ENV{PERL_VALGRIND}) {
 607             my @valgrind;
 608             if (-e $Valgrind_Log) {
 609                 if (open(V, $Valgrind_Log)) {
 610                     @valgrind = <V>;
 611                     close V;
 612                 } else {
 613                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 614                 }
 615             }
 616             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 617                 if (rename $Valgrind_Log, "$test.valgrind") {
 618                     $valgrind = $valgrind + 1;
 619                 } else {
 620                     warn "$0: Failed to create '$test.valgrind': $!\n";
 621                 }
 622             }
 623             elsif (@valgrind) {
 624                 my $leaks = 0;
 625                 my $errors = 0;
 626                 for my $i (0..$#valgrind) {
 627                     local $_ = $valgrind[$i];
 628                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 629                         $errors = $errors + $1;   # there may be multiple error summaries
 630                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 631                         for my $off (1 .. 4) {
 632                             if ($valgrind[$i+$off] =~
 633                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 634                                 $leaks = $leaks + $1;
 635                             }
 636                         }
 637                     }
 638                 }
 639                 if ($errors or $leaks) {
 640                     if (rename $Valgrind_Log, "$test.valgrind") {
 641                         $valgrind = $valgrind + 1;
 642                     } else {
 643                         warn "$0: Failed to create '$test.valgrind': $!\n";
 644                     }
 645                 }
 646             } else {
 647                 warn "No valgrind output?\n";
 648             }
 649             if (-e $Valgrind_Log) {
 650                 unlink $Valgrind_Log
 651                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 652             }
 653         }
 654         if ($type eq 'deparse') {
 655             unlink "./$test.dp";
 656         }
 657         if ($ENV{PERL_3LOG}) {
 658             my $tpp = $test;
 659             $tpp =~ s:^\.\./::;
 660             $tpp =~ s:/:_:g;
 661             $tpp =~ s:\.t$:.3log:;
 662             rename("perl.3log", $tpp) ||
 663                 die "rename: perl3.log to $tpp: $!\n";
 664         }
 665         if (not defined $failure and $next != $max) {
 666             $failure="FAILED--expected $max tests, saw $next";
 667         }
 668
 669         if( !defined $failure  # don't mask a test failure
 670             and $? )
 671         {
 672             $failure = "FAILED--non-zero wait status: $?";
 673         }
 674
 675         if (defined $failure) {
 676             print "${te}$failure\n";
 677             $::bad_files = $::bad_files + 1;
 678             if ($test =~ /^base/) {
 679                 die "Failed a basic test ($test) -- cannot continue.\n";
 680             }
 681             $failed_tests{$test} = 1;
 682         }
 683         else {
 684             if ($max) {
 685                 my $elapsed;
 686                 if ( $show_elapsed_time ) {
 687                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 688                 }
 689                 else {
 690                     $elapsed = "";
 691                 }
 692                 print "${te}ok$elapsed\n";
 693                 $good_files = $good_files + 1;
 694             }
 695             else {
 696                 print "${te}skipped\n";
 697                 $tested_files = $tested_files - 1;
 698             }
 699         }
 700     } # while tests
 701
 702     if ($::bad_files == 0) {
 703         if ($good_files) {
 704             print "All tests successful.\n";
 705             # XXX add mention of 'perlbug -ok' ?
 706         }
 707         else {
 708             die "FAILED--no tests were run for some reason.\n";
 709         }
 710     }
 711     else {
 712         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 713         my $s = $::bad_files == 1 ? "" : "s";
 714         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 715         for my $test ( sort keys %failed_tests ) {
 716             print "\t$test\n";
 717         }
 718         warn <<'SHRDLU_1';
 719 ### Since not all tests were successful, you may want to run some of
 720 ### them individually and examine any diagnostic messages they produce.
 721 ### See the INSTALL document's section on "make test".
 722 SHRDLU_1
 723         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 724 ### You have a good chance to get more information by running
 725 ###   ./perl harness
 726 ### in the 't' directory since most (>=80%) of the tests succeeded.
 727 SHRDLU_2
 728         if (eval {require Config; import Config; 1}) {
 729             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 730                 warn <<SHRDLU_3;
 731 ### You may have to set your dynamic library search path,
 732 ### $p, to point to the build directory:
 733 SHRDLU_3
 734                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 735                     warn <<SHRDLU_4a;
 736 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 737 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 738 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 739 SHRDLU_4a
 740                 } else {
 741                     warn <<SHRDLU_4b;
 742 ###   setenv $p `pwd`; cd t; ./perl harness
 743 ###   $p=`pwd`; export $p; cd t; ./perl harness
 744 ###   export $p=`pwd`; cd t; ./perl harness
 745 SHRDLU_4b
 746                 }
 747                 warn <<SHRDLU_5;
 748 ### for csh-style shells, like tcsh; or for traditional/modern
 749 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 750 SHRDLU_5
 751             }
 752         }
 753     }
 754     my ($user,$sys,$cuser,$csys) = times;
 755     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 756         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 757     if ($ENV{PERL_VALGRIND}) {
 758         my $s = $valgrind == 1 ? '' : 's';
 759         print "$valgrind valgrind report$s created.\n", ;
 760     }
 761 }
 762 exit ($::bad_files != 0);
 763
 764 # ex: set ts=8 sts=4 sw=4 noet: