t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.
   5
   6 $| = 1;
   7
   8 # Let tests know they're running in the perl core.  Useful for modules
   9 # which live dual lives on CPAN.
  10 $ENV{PERL_CORE} = 1;
  11
  12 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
  13 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
  14
  15 # Cheesy version of Getopt::Std.  Maybe we should replace it with that.
  16 @argv = ();
  17 if ($#ARGV >= 0) {
  18     foreach my $idx (0..$#ARGV) {
  19         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
  20         $core    = 1 if $1 eq 'core';
  21         $verbose = 1 if $1 eq 'v';
  22         $torture = 1 if $1 eq 'torture';
  23         $with_utf= 1 if $1 eq 'utf8';
  24         $bytecompile = 1 if $1 eq 'bytecompile';
  25         $compile = 1 if $1 eq 'compile';
  26         if ($1 =~ /^deparse(,.+)?$/) {
  27             $deparse = 1;
  28             $deparse_opts = $1;
  29         }
  30     }
  31 }
  32 @ARGV = @argv;
  33
  34 chdir 't' if -f 't/TEST';
  35
  36 die "You need to run \"make test\" first to set things up.\n"
  37   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
  38
  39 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
  40     unless (-x 'perl.third') {
  41         unless (-x '../perl.third') {
  42             die "You need to run \"make perl.third first.\n";
  43         }
  44         else {
  45             print "Symlinking ../perl.third as perl.third...\n";
  46             die "Failed to symlink: $!\n"
  47                 unless symlink("../perl.third", "perl.third");
  48             die "Symlinked but no executable perl.third: $!\n"
  49                 unless -x 'perl.third';
  50         }
  51     }
  52 }
  53
  54 # check leakage for embedders
  55 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
  56
  57 $ENV{EMXSHELL} = 'sh';        # For OS/2
  58
  59 # Roll your own File::Find!
  60 use TestInit;
  61 use File::Spec;
  62 my $curdir = File::Spec->curdir;
  63 my $updir  = File::Spec->updir;
  64
  65 sub _find_tests {
  66     my($dir) = @_;
  67     opendir DIR, $dir || die "Trouble opening $dir: $!";
  68     foreach my $f (sort { $a cmp $b } readdir DIR) {
  69         next if $f eq $curdir or $f eq $updir;
  70
  71         my $fullpath = File::Spec->catfile($dir, $f);
  72
  73         _find_tests($fullpath) if -d $fullpath;
  74         $fullpath = VMS::Filespec::unixify($fullpath) if $^O eq 'VMS';
  75         push @ARGV, $fullpath if $f =~ /\.t$/;
  76     }
  77 }
  78
  79 sub _quote_args {
  80     my ($args) = @_;
  81     my $argstring = '';
  82
  83     foreach (split(/\s+/,$args)) {
  84        # In VMS protect with doublequotes because otherwise
  85        # DCL will lowercase -- unless already doublequoted.
  86        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
  87        $argstring .= ' ' . $_;
  88     }
  89     return $argstring;
  90 }
  91
  92 unless (@ARGV) {
  93     foreach my $dir (qw(base comp cmd run io op uni)) {
  94         _find_tests($dir);
  95     }
  96     _find_tests("lib") unless $core;
  97     my $mani = File::Spec->catfile($updir, "MANIFEST");
  98     if (open(MANI, $mani)) {
  99         while (<MANI>) { # similar code in t/harness
 100             if (m!^(ext/\S+/?(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 101                 $t = $1;
 102                 if (!$core || $t =~ m!^lib/[a-z]!)
 103                 {
 104                     $path = File::Spec->catfile($updir, $t);
 105                     push @ARGV, $path;
 106                     $name{$path} = $t;
 107                 }
 108             }
 109         }
 110         close MANI;
 111     } else {
 112         warn "$0: cannot open $mani: $!\n";
 113     }
 114     unless ($core) {
 115         _find_tests('pod');
 116         _find_tests('x2p');
 117         _find_tests('japh') if $torture;
 118     }
 119 }
 120
 121 # Tests known to cause infinite loops for the perlcc tests.
 122 # %infinite = ( 'comp/require.t', 1, 'op/bop.t', 1, 'lib/hostname.t', 1 );
 123 %infinite = ();
 124
 125 if ($deparse) {
 126     _testprogs('deparse', '',   @ARGV);
 127 }
 128 elsif( $compile ) {
 129     _testprogs('compile', '',   @ARGV);
 130 }
 131 elsif( $bytecompile ) {
 132     _testprogs('bytecompile', '', @ARGV);
 133 }
 134 else {
 135     _testprogs('compile', '',   @ARGV) if -e "../testcompile";
 136     _testprogs('perl',    '',   @ARGV);
 137 }
 138
 139 sub _testprogs {
 140     $type = shift @_;
 141     $args = shift;
 142     @tests = @_;
 143
 144     print <<'EOT' if ($type eq 'compile');
 145 ------------------------------------------------------------------------------
 146 TESTING COMPILER
 147 ------------------------------------------------------------------------------
 148 EOT
 149
 150     print <<'EOT' if ($type eq 'deparse');
 151 ------------------------------------------------------------------------------
 152 TESTING DEPARSER
 153 ------------------------------------------------------------------------------
 154 EOT
 155
 156     print <<'EOT' if ($type eq 'bytecompile');
 157 ------------------------------------------------------------------------------
 158 TESTING BYTECODE COMPILER
 159 ------------------------------------------------------------------------------
 160 EOT
 161
 162     $ENV{PERLCC_TIMEOUT} = 120
 163           if ($type eq 'compile' && !$ENV{PERLCC_TIMEOUT});
 164
 165     $bad = 0;
 166     $good = 0;
 167     $total = @tests;
 168     $files  = 0;
 169     $totmax = 0;
 170
 171     foreach my $t (@tests) {
 172       unless (exists $name{$t}) {
 173         my $tname = File::Spec->catfile('t',$t);
 174         $tname = VMS::Filespec::unixify($tname) if $^O eq 'VMS';
 175         $name{$t} = $tname;
 176       }
 177     }
 178     my $maxlen = 0;
 179     foreach (@name{@tests}) {
 180         s/\.\w+\z/./;
 181         my $len = length ;
 182         $maxlen = $len if $len > $maxlen;
 183     }
 184     # + 3 : we want three dots between the test name and the "ok"
 185     $dotdotdot = $maxlen + 3 ;
 186     while ($test = shift @tests) {
 187
 188         if ( $infinite{$test} && $type eq 'compile' ) {
 189             print STDERR "$test creates infinite loop! Skipping.\n";
 190             next;
 191         }
 192         if ($test =~ /^$/) {
 193             next;
 194         }
 195         if ($type eq 'deparse') {
 196             if ($test eq "comp/redef.t") {
 197                 # Redefinition happens at compile time
 198                 next;
 199             }
 200             elsif ($test eq "lib/switch.t") {
 201                 # B::Deparse doesn't support source filtering
 202                 next;
 203             }
 204         }
 205         $te = $name{$test} . '.' x ($dotdotdot - length($name{$test}));
 206
 207         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 208             print $te;
 209             $te = '';
 210         }
 211
 212         $test = $OVER{$test} if exists $OVER{$test};
 213
 214         open(SCRIPT,"<$test") or die "Can't run $test.\n";
 215         $_ = <SCRIPT>;
 216         close(SCRIPT) unless ($type eq 'deparse');
 217         if (/#!.*\bperl.*\s-\w*([tT])/) {
 218             $switch = qq{"-$1"};
 219         }
 220         else {
 221             $switch = '';
 222         }
 223
 224         my $test_executable; # for 'compile' tests
 225         my $file_opts = "";
 226         if ($type eq 'deparse') {
 227             # Look for #line directives which change the filename
 228             while (<SCRIPT>) {
 229                 $file_opts .= ",-f$3$4"
 230                         if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 231             }
 232             close(SCRIPT);
 233         }
 234
 235         my $utf = $with_utf ? '-I../lib -Mutf8' : '';
 236         my $testswitch = '-I. -MTestInit'; # -T will strict . from @INC
 237         if ($type eq 'deparse') {
 238             my $deparse =
 239                 "./perl $testswitch $switch -I../lib -MO=-qq,Deparse,-sv1.,".
 240                 "-l$deparse_opts$file_opts ".
 241                 "$test > $test.dp ".
 242                 "&& ./perl $testswitch $switch -I../lib $test.dp |";
 243             open(RESULTS, $deparse)
 244                 or print "can't deparse '$deparse': $!.\n";
 245         }
 246         elsif ($type eq 'bytecompile') {
 247             my $perl = $ENV{PERL} || './perl';
 248             my $redir = ($^O eq 'VMS' ? '2>&1' : '');
 249             my $bswitch = "-MO=Bytecode,-H,-s,-TD`pwd`,";
 250             $bswitch .= "-TF,"
 251                 if $test =~ m(chdir|pod/|CGI/t/carp|lib/DB);
 252             $bswitch .= "-k,"
 253                 if $test =~ m(deparse|terse|ext/Storable/t/code);
 254             $bswitch .= "-k,"
 255                 if $] < 5.009 && $test =~ m(avhv|hashwarn);
 256             $bswitch .= "-b,"
 257                 if $test =~ m(op/getpid);
 258             my $bytecompile =
 259                 "$perl $testswitch $switch -I../lib $bswitch".
 260                 "-o$test.plc $test 2>/dev/null &&".
 261                 "$perl $testswitch $switch $utf $test.plc $redir|";
 262             open(RESULTS,$bytecompile)
 263                 or print "can't byte-compile '$bytecompile': $!.\n";
 264         }
 265         elsif ($type eq 'perl') {
 266             my $perl = $ENV{PERL} || './perl';
 267             my $redir = ($^O eq 'VMS' ? '2>&1' : '');
 268             my $run = "$perl" . _quote_args("$testswitch $switch $utf") . " $test $redir|";
 269             open(RESULTS,$run) or print "can't run '$run': $!.\n";
 270         }
 271         else {
 272             my $compile;
 273             my $pl2c = "$testswitch -I../lib ../utils/perlcc --testsuite " .
 274               # -O9 for good measure, -fcog is broken ATM
 275                        "$switch -Wb=-O9,-fno-cog -L .. " .
 276                        "-I \".. ../lib/CORE\" $args $utf $test -o ";
 277
 278             if( $^O eq 'MSWin32' ) {
 279                 $test_executable = "$test.exe";
 280                 # hopefully unused name...
 281                 open HACK, "> xweghyz.pl";
 282                 print HACK <<EOT;
 283 #!./perl
 284
 285 open HACK, '.\\perl $pl2c $test_executable |';
 286 # cl.exe prints the name of the .c file on stdout (\%^\$^#)
 287 while(<HACK>) {m/^\\w+\\.[cC]\$/ && next;print}
 288 open HACK, '$test_executable |';
 289 while(<HACK>) {print}
 290 EOT
 291                 close HACK;
 292                 $compile = 'xweghyz.pl |';
 293             }
 294             else {
 295                 $test_executable = "$test.plc";
 296                 $compile = "./perl $pl2c $test_executable && $test_executable |";
 297             }
 298             unlink $test_executable if -f $test_executable;
 299             open(RESULTS, $compile)
 300                 or print "can't compile '$compile': $!.\n";
 301         }
 302
 303         $ok = 0;
 304         $next = 0;
 305         while (<RESULTS>) {
 306             next if /^\s*$/; # skip blank lines
 307             if ($verbose) {
 308                 print $_;
 309             }
 310             unless (/^#/) {
 311                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 312                     $max = $1;
 313                     %todo = map { $_ => 1 } split / /, $3 if $3;
 314                     $totmax += $max;
 315                     $files += 1;
 316                     $next = 1;
 317                     $ok = 1;
 318                 }
 319                 else {
 320                     if (/^(not )?ok (\d+)[^#]*(\s*#.*)?/ &&
 321                         $2 == $next)
 322                     {
 323                         my($not, $num, $extra) = ($1, $2, $3);
 324                         my($istodo) = $extra =~ /^\s*#\s*TODO/ if $extra;
 325                         $istodo = 1 if $todo{$num};
 326
 327                         if( $not && !$istodo ) {
 328                             $ok = 0;
 329                             $next = $num;
 330                             last;
 331                         }
 332                         else {
 333                             $next = $next + 1;
 334                         }
 335                     }
 336                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 337                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 338                     }
 339                     else {
 340                         $ok = 0;
 341                     }
 342                 }
 343             }
 344         }
 345         close RESULTS;
 346         if ($type eq 'deparse') {
 347             unlink "./$test.dp";
 348         }
 349         if ($ENV{PERL_3LOG}) {
 350             my $tpp = $test;
 351             $tpp =~ s:^\.\./::;
 352             $tpp =~ s:/:_:g;
 353             $tpp =~ s:\.t$:.3log:;
 354             rename("perl.3log", $tpp) ||
 355                 die "rename: perl3.log to $tpp: $!\n";
 356         }
 357         $next = $next - 1;
 358         # test if the compiler compiled something
 359         if( $type eq 'compile' && !-e "$test_executable" ) {
 360             $ok = 0;
 361             print "Test did not compile\n";
 362         }
 363         if ($ok && $next == $max ) {
 364             if ($max) {
 365                 print "${te}ok\n";
 366                 $good = $good + 1;
 367             }
 368             else {
 369                 print "${te}skipping test on this platform\n";
 370                 $files -= 1;
 371             }
 372         }
 373         else {
 374             $next += 1;
 375             print "${te}FAILED at test $next\n";
 376             $bad = $bad + 1;
 377             $_ = $test;
 378             if (/^base/) {
 379                 die "Failed a basic test--cannot continue.\n";
 380             }
 381         }
 382     }
 383
 384     if ($bad == 0) {
 385         if ($ok) {
 386             print "All tests successful.\n";
 387             # XXX add mention of 'perlbug -ok' ?
 388         }
 389         else {
 390             die "FAILED--no tests were run for some reason.\n";
 391         }
 392     }
 393     else {
 394         $pct = $files ? sprintf("%.2f", ($files - $bad) / $files * 100) : "0.00";
 395         if ($bad == 1) {
 396             warn "Failed 1 test script out of $files, $pct% okay.\n";
 397         }
 398         else {
 399             warn "Failed $bad test scripts out of $files, $pct% okay.\n";
 400         }
 401         warn <<'SHRDLU_1';
 402 ### Since not all tests were successful, you may want to run some of
 403 ### them individually and examine any diagnostic messages they produce.
 404 ### See the INSTALL document's section on "make test".
 405 SHRDLU_1
 406         warn <<'SHRDLU_2' if $good / $total > 0.8;
 407 ### You have a good chance to get more information by running
 408 ###   ./perl harness
 409 ### in the 't' directory since most (>=80%) of the tests succeeded.
 410 SHRDLU_2
 411         if (eval {require Config; import Config; 1}) {
 412             if ($Config{usedl} && (my $p = $Config{ldlibpthname})) {
 413                 warn <<SHRDLU_3;
 414 ### You may have to set your dynamic library search path,
 415 ### $p, to point to the build directory:
 416 SHRDLU_3
 417                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 418                     warn <<SHRDLU_4a;
 419 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 420 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 421 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 422 SHRDLU_4a
 423                 } else {
 424                     warn <<SHRDLU_4b;
 425 ###   setenv $p `pwd`; cd t; ./perl harness
 426 ###   $p=`pwd`; export $p; cd t; ./perl harness
 427 ###   export $p=`pwd`; cd t; ./perl harness
 428 SHRDLU_4b
 429                 }
 430                 warn <<SHRDLU_5;
 431 ### for csh-style shells, like tcsh; or for traditional/modern
 432 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 433 SHRDLU_5
 434             }
 435         }
 436     }
 437     ($user,$sys,$cuser,$csys) = times;
 438     print sprintf("u=%g  s=%g  cu=%g  cs=%g  scripts=%d  tests=%d\n",
 439         $user,$sys,$cuser,$csys,$files,$totmax);
 440 }
 441 exit ($bad != 0);