t/93autocast.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 { # Fake storage driver for sqlite with autocast
   9     package DBICTest::SQLite::AutoCast;
  10     use base qw/
  11         DBIx::Class::Storage::DBI::AutoCast
  12         DBIx::Class::Storage::DBI::SQLite
  13     /;
  14     use mro 'c3';
  15
  16     my $type_map = {
  17       datetime => 'DateTime',
  18       integer => 'INT',
  19       int => undef, # no conversion
  20     };
  21
  22     sub _native_data_type {
  23       return $type_map->{$_[1]};
  24     }
  25 }
  26
  27 my $schema = DBICTest->init_schema (storage_type => 'DBICTest::SQLite::AutoCast');
  28
  29 # 'me.id' will be cast unlike the unqualified 'id'
  30 my $rs = $schema->resultset ('CD')->search ({
  31   cdid => { '>', 5 },
  32   'tracks.last_updated_at' => { '!=', undef },
  33   'tracks.last_updated_on' => { '<', 2009 },
  34   'tracks.position' => 4,
  35   'me.single_track' => \[ '= ?', [ single_track => 1 ] ],
  36 }, { join => 'tracks' });
  37
  38 my @bind = (
  39   [ { dbic_colname => "cdid", sqlt_datatype => "integer" }
  40       => 5 ],
  41   [ { dbic_colname => "single_track", sqlt_datatype => "integer" }
  42       => 1 ],
  43   [ { dbic_colname => "tracks.last_updated_on", sqlt_datatype => "datetime" }
  44       => 2009 ],
  45   [ { dbic_colname => "tracks.position", sqlt_datatype => "int" }
  46       => 4 ],
  47 );
  48
  49 $schema->is_executed_sql_bind( sub { $rs->all }, [[
  50   '
  51     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  52       FROM cd me
  53       LEFT JOIN track tracks ON tracks.cd = me.cdid
  54     WHERE
  55           cdid > ?
  56       AND me.single_track = ?
  57       AND tracks.last_updated_at IS NOT NULL
  58       AND tracks.last_updated_on < ?
  59       AND tracks.position = ?
  60   ',
  61   @bind,
  62 ]], 'expected sql with casting off' );
  63
  64 $schema->storage->auto_cast (1);
  65
  66 $schema->is_executed_sql_bind( sub { $rs->all }, [[
  67   '
  68     SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track
  69       FROM cd me
  70       LEFT JOIN track tracks ON tracks.cd = me.cdid
  71     WHERE
  72           cdid > CAST(? AS INT)
  73       AND me.single_track = CAST(? AS INT)
  74       AND tracks.last_updated_at IS NOT NULL
  75       AND tracks.last_updated_on < CAST (? AS DateTime)
  76       AND tracks.position = ?
  77   ',
  78   @bind,
  79 ]], 'expected sql with casting on' );
  80
  81 done_testing;