t/89dbicadmin.t

   1 # vim: filetype=perl
   2 use strict;
   3 use warnings;
   4
   5 use Test::More;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9
  10 eval 'require JSON::Any';
  11 plan skip_all => 'Install JSON::Any to run this test' if ($@);
  12
  13 eval 'require Text::CSV_XS';
  14 if ($@) {
  15     eval 'require Text::CSV_PP';
  16     plan skip_all => 'Install Text::CSV_XS or Text::CSV_PP to run this test' if ($@);
  17 }
  18
  19 my @json_backends = qw/XS JSON DWIW Syck/;
  20 my $tests_per_run = 5;
  21
  22 plan tests => $tests_per_run * @json_backends;
  23
  24 use JSON::Any;
  25 for my $js (@json_backends) {
  26
  27     eval {JSON::Any->import ($js) };
  28     SKIP: {
  29         skip ("Json backend $js is not available, skip testing", $tests_per_run) if $@;
  30
  31         $ENV{JSON_ANY_ORDER} = $js;
  32         eval { test_dbicadmin () };
  33         diag $@ if $@;
  34     }
  35 }
  36
  37 sub test_dbicadmin {
  38     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  39
  40     my $employees = $schema->resultset('Employee');
  41     my @cmd = ($^X, qw|script/dbicadmin --quiet --schema=DBICTest::Schema --class=Employee --tlibs|, q|--connect=["dbi:SQLite:dbname=t/var/DBIxClass.db","","",{"AutoCommit":1}]|, qw|--force --tlibs|);
  42
  43     system(@cmd, qw|--op=insert --set={"name":"Matt"}|);
  44     ok( ($employees->count()==1), 'insert count' );
  45
  46     my $employee = $employees->find(1);
  47     ok( ($employee->name() eq 'Matt'), 'insert valid' );
  48
  49     system(@cmd, qw|--op=update --set={"name":"Trout"}|);
  50     $employee = $employees->find(1);
  51     ok( ($employee->name() eq 'Trout'), 'update' );
  52
  53     system(@cmd, qw|--op=insert --set={"name":"Aran"}|);
  54
  55     open(my $fh, "-|", @cmd, qw|--op=select --attrs={"order_by":"name"}|) or die $!;
  56     my $data = do { local $/; <$fh> };
  57     close($fh);
  58     ok( ($data=~/Aran.*Trout/s), 'select with attrs' );
  59
  60     system(@cmd, qw|--op=delete --where={"name":"Trout"}|);
  61     ok( ($employees->count()==1), 'delete' );
  62 }