t/89dbicadmin.t

   1 # vim: filetype=perl
   2 use strict;
   3 use warnings;
   4
   5 use Test::More;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9
  10 eval 'require JSON::Any';
  11 plan skip_all => 'Install JSON::Any to run this test' if ($@);
  12
  13 eval 'require Text::CSV_XS';
  14 if ($@) {
  15     eval 'require Text::CSV_PP';
  16     plan skip_all => 'Install Text::CSV_XS or Text::CSV_PP to run this test' if ($@);
  17 }
  18
  19 my @json_backends = qw/XS JSON DWIW Syck/;
  20 my $tests_per_run = 5;
  21
  22 plan tests => $tests_per_run * @json_backends;
  23
  24 use JSON::Any;
  25 for my $js (@json_backends) {
  26
  27     eval {JSON::Any->import ($js) };
  28     SKIP: {
  29         skip ("Json backend $js is not available, skip testing", $tests_per_run) if $@;
  30
  31         $ENV{JSON_ANY_ORDER} = $js;
  32         eval { test_dbicadmin () };
  33         diag $@ if $@;
  34     }
  35 }
  36
  37 sub test_dbicadmin {
  38     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  39
  40     my $employees = $schema->resultset('Employee');
  41
  42     system( _prepare_system_args( qw|--op=insert --set={"name":"Matt"}| ) );
  43     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: insert count" );
  44
  45     my $employee = $employees->find(1);
  46     ok( ($employee->name() eq 'Matt'), "$ENV{JSON_ANY_ORDER}: insert valid" );
  47
  48     system( _prepare_system_args( qw|--op=update --set={"name":"Trout"}| ) );
  49     $employee = $employees->find(1);
  50     ok( ($employee->name() eq 'Trout'), "$ENV{JSON_ANY_ORDER}: update" );
  51
  52     system( _prepare_system_args( qw|--op=insert --set={"name":"Aran"}| ) );
  53
  54     SKIP: {
  55         skip ("MSWin32 doesn't support -| either", 1) if $^O eq 'MSWin32';
  56
  57         open(my $fh, "-|",  _prepare_system_args( qw|--op=select --attrs={"order_by":"name"}| ) ) or die $!;
  58         my $data = do { local $/; <$fh> };
  59         close($fh);
  60         ok( ($data=~/Aran.*Trout/s), "$ENV{JSON_ANY_ORDER}: select with attrs" );
  61     }
  62
  63     system( _prepare_system_args( qw|--op=delete --where={"name":"Trout"}| ) );
  64     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: delete" );
  65 }
  66
  67 # Why do we need this crap? Apparently MSWin32 can not pass through quotes properly
  68 # (sometimes it will and sometimes not, depending on what compiler was used to build
  69 # perl). So we go the extra mile to escape all the quotes. We can't also use ' instead
  70 # of ", because JSON::XS (proudly) does not support "malformed JSON" as the author
  71 # calls it. Bleh.
  72 #
  73 sub _prepare_system_args {
  74     my $perl = $^X;
  75     my @args = (
  76         qw|script/dbicadmin --quiet --schema=DBICTest::Schema --class=Employee --tlibs|,
  77         q|--connect=["dbi:SQLite:dbname=t/var/DBIxClass.db","","",{"AutoCommit":1}]|,
  78         qw|--force --tlibs|,
  79         @_,
  80     );
  81
  82     if ( $^O eq 'MSWin32' ) {
  83         $perl = qq|"$perl"|;    # execution will fail if $^X contains paths
  84         for (@args) {
  85             $_ =~ s/"/\\"/g;
  86         }
  87     }
  88
  89     return ($perl, @args);
  90 }