t/85utf8.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Warn;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9 {
  10   package A::Comp;
  11   use base 'DBIx::Class';
  12   sub store_column { shift->next::method (@_) };
  13   1;
  14 }
  15
  16 {
  17   package A::SubComp;
  18   use base 'A::Comp';
  19
  20   1;
  21 }
  22
  23 warnings_are (
  24   sub {
  25     local $ENV{DBIC_UTF8COLUMNS_OK} = 1;
  26     package A::Test1;
  27     use base 'DBIx::Class::Core';
  28     __PACKAGE__->load_components(qw(Core +A::Comp Ordered UTF8Columns));
  29     __PACKAGE__->load_components(qw(Ordered +A::SubComp Row UTF8Columns Core));
  30     sub store_column { shift->next::method (@_) };
  31     1;
  32   },
  33   [],
  34   'no spurious warnings issued',
  35 );
  36
  37 warnings_like (
  38   sub {
  39     local $ENV{DBIC_UTF8COLUMNS_OK};
  40     package A::Test1Loud;
  41     use base 'DBIx::Class::Core';
  42     __PACKAGE__->load_components(qw(Core +A::Comp Ordered UTF8Columns));
  43     __PACKAGE__->load_components(qw(Ordered +A::SubComp Row UTF8Columns Core));
  44     sub store_column { shift->next::method (@_) };
  45     1;
  46   },
  47   [qr/Use of DBIx::Class::UTF8Columns is strongly discouraged/],
  48   'issued deprecation warning',
  49 );
  50
  51
  52 my $test1_mro;
  53 my $idx = 0;
  54 for (@{mro::get_linear_isa ('A::Test1')} ) {
  55   $test1_mro->{$_} = $idx++;
  56 }
  57
  58 cmp_ok ($test1_mro->{'A::SubComp'}, '<', $test1_mro->{'A::Comp'}, 'mro of Test1 correct (A::SubComp before A::Comp)' );
  59 cmp_ok ($test1_mro->{'A::Comp'}, '<', $test1_mro->{'DBIx::Class::UTF8Columns'}, 'mro of Test1 correct (A::Comp before UTF8Col)' );
  60 cmp_ok ($test1_mro->{'DBIx::Class::UTF8Columns'}, '<', $test1_mro->{'DBIx::Class::Core'}, 'mro of Test1 correct (UTF8Col before Core)' );
  61 cmp_ok ($test1_mro->{'DBIx::Class::Core'}, '<', $test1_mro->{'DBIx::Class::Row'}, 'mro of Test1 correct (Core before Row)' );
  62
  63 warnings_like (
  64   sub {
  65     package A::Test2;
  66     use base 'DBIx::Class::Core';
  67     __PACKAGE__->load_components(qw(UTF8Columns +A::Comp));
  68     sub store_column { shift->next::method (@_) };
  69     1;
  70   },
  71   [qr/Incorrect loading order of DBIx::Class::UTF8Columns.+affect other components overriding 'store_column' \(A::Comp\)/],
  72   'incorrect order warning issued (violator defines)',
  73 );
  74
  75 warnings_like (
  76   sub {
  77     package A::Test3;
  78     use base 'DBIx::Class::Core';
  79     __PACKAGE__->load_components(qw(UTF8Columns +A::SubComp));
  80     sub store_column { shift->next::method (@_) };
  81     1;
  82   },
  83   [qr/Incorrect loading order of DBIx::Class::UTF8Columns.+affect other components overriding 'store_column' \(A::SubComp \(via A::Comp\)\)/],
  84   'incorrect order warning issued (violator inherits)',
  85 );
  86
  87 my $schema = DBICTest->init_schema();
  88 DBICTest::Schema::CD->load_components('UTF8Columns');
  89 DBICTest::Schema::CD->utf8_columns('title');
  90 Class::C3->reinitialize() if DBIx::Class::_ENV_::OLD_MRO;
  91
  92 # as per http://search.cpan.org/dist/Test-Simple/lib/Test/More.pm#utf8
  93 binmode (Test::More->builder->$_, ':utf8') for qw/output failure_output todo_output/;
  94
  95 my $bytestream_title = my $utf8_title = "weird \x{466} stuff";
  96 utf8::encode($bytestream_title);
  97 cmp_ok ($bytestream_title, 'ne', $utf8_title, 'unicode/raw differ (sanity check)');
  98
  99 my $cd;
 100 {
 101   local $TODO = "This has been broken since rev 1191, Mar 2006";
 102
 103   $schema->is_executed_sql_bind( sub {
 104     $cd = $schema->resultset('CD')->create( { artist => 1, title => $utf8_title, year => '2048' } )
 105   }, [[
 106     'INSERT INTO cd ( artist, title, year) VALUES ( ?, ?, ? )',
 107      [ { dbic_colname => "artist", sqlt_datatype => "integer" }
 108         => 1 ],
 109      [ { dbic_colname => "title", sqlt_datatype => "varchar", sqlt_size => 100 }
 110         => $bytestream_title ],
 111      [ { dbic_colname => "year", sqlt_datatype => "varchar", sqlt_size => 100 }
 112         => 2048 ],
 113   ]], 'INSERT: raw bytes sent to the database' );
 114 };
 115
 116 # this should be using the cursor directly, no inflation/processing of any sort
 117 my ($raw_db_title) = $schema->resultset('CD')
 118                              ->search ($cd->ident_condition)
 119                                ->get_column('title')
 120                                 ->_resultset
 121                                  ->cursor
 122                                   ->next;
 123
 124 is ($raw_db_title, $bytestream_title, 'INSERT: raw bytes retrieved from database');
 125
 126 for my $reloaded (0, 1) {
 127   my $test = $reloaded ? 'reloaded' : 'stored';
 128   $cd->discard_changes if $reloaded;
 129
 130   ok( utf8::is_utf8( $cd->title ), "got $test title with utf8 flag" );
 131   ok(! utf8::is_utf8( $cd->{_column_data}{title} ), "in-object $test title without utf8" );
 132
 133   ok(! utf8::is_utf8( $cd->year ), "got $test year without utf8 flag" );
 134   ok(! utf8::is_utf8( $cd->{_column_data}{year} ), "in-object $test year without utf8" );
 135 }
 136
 137 $cd->title('nonunicode');
 138 ok(! utf8::is_utf8( $cd->title ), 'update title without utf8 flag' );
 139 ok(! utf8::is_utf8( $cd->{_column_data}{title} ), 'store utf8-less title' );
 140
 141 $cd->update;
 142 $cd->discard_changes;
 143 ok(! utf8::is_utf8( $cd->title ), 'reloaded title without utf8 flag' );
 144 ok(! utf8::is_utf8( $cd->{_column_data}{title} ), 'reloaded utf8-less title' );
 145
 146 $bytestream_title = $utf8_title = "something \x{219} else";
 147 utf8::encode($bytestream_title);
 148
 149 $schema->is_executed_sql_bind( sub {
 150   $cd->update ({ title => $utf8_title });
 151 }, [
 152   [ 'BEGIN' ],
 153   [
 154     'UPDATE cd SET title = ? WHERE cdid = ?',
 155     [ { dbic_colname => "title", sqlt_datatype => "varchar", sqlt_size => 100 }
 156       => $bytestream_title ],
 157     [ { dbic_colname => "cdid", sqlt_datatype => "integer" }
 158       => 6 ],
 159   ],
 160   [ 'COMMIT' ],
 161 ], 'UPDATE: raw bytes sent to the database');
 162
 163 ($raw_db_title) = $schema->resultset('CD')
 164                              ->search ($cd->ident_condition)
 165                                ->get_column('title')
 166                                 ->_resultset
 167                                  ->cursor
 168                                   ->next;
 169 is ($raw_db_title, $bytestream_title, 'UPDATE: raw bytes retrieved from database');
 170
 171 $cd->discard_changes;
 172 $cd->title($utf8_title);
 173 ok( !$cd->is_column_changed('title'), 'column is not dirty after setting the same unicode value' );
 174
 175 $cd->update ({ title => $utf8_title });
 176 $cd->title('something_else');
 177 ok( $cd->is_column_changed('title'), 'column is dirty after setting to something completely different');
 178
 179 {
 180   local $TODO = 'There is currently no way to propagate aliases to inflate_result()';
 181   $cd = $schema->resultset('CD')->find ({ title => $utf8_title }, { select => 'title', as => 'name' });
 182   ok (utf8::is_utf8( $cd->get_column ('name') ), 'utf8 flag propagates via as');
 183 }
 184
 185 done_testing;