t/85utf8.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Warn;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::DebugObj;
   9
  10 {
  11   package A::Comp;
  12   use base 'DBIx::Class';
  13   sub store_column { shift->next::method (@_) };
  14   1;
  15 }
  16
  17 {
  18   package A::SubComp;
  19   use base 'A::Comp';
  20
  21   1;
  22 }
  23
  24 warnings_are (
  25   sub {
  26     local $ENV{DBIC_UTF8COLUMNS_OK} = 1;
  27     package A::Test1;
  28     use base 'DBIx::Class::Core';
  29     __PACKAGE__->load_components(qw(Core +A::Comp Ordered UTF8Columns));
  30     __PACKAGE__->load_components(qw(Ordered +A::SubComp Row UTF8Columns Core));
  31     sub store_column { shift->next::method (@_) };
  32     1;
  33   },
  34   [],
  35   'no spurious warnings issued',
  36 );
  37
  38 my $test1_mro;
  39 my $idx = 0;
  40 for (@{mro::get_linear_isa ('A::Test1')} ) {
  41   $test1_mro->{$_} = $idx++;
  42 }
  43
  44 cmp_ok ($test1_mro->{'A::SubComp'}, '<', $test1_mro->{'A::Comp'}, 'mro of Test1 correct (A::SubComp before A::Comp)' );
  45 cmp_ok ($test1_mro->{'A::Comp'}, '<', $test1_mro->{'DBIx::Class::UTF8Columns'}, 'mro of Test1 correct (A::Comp before UTF8Col)' );
  46 cmp_ok ($test1_mro->{'DBIx::Class::UTF8Columns'}, '<', $test1_mro->{'DBIx::Class::Core'}, 'mro of Test1 correct (UTF8Col before Core)' );
  47 cmp_ok ($test1_mro->{'DBIx::Class::Core'}, '<', $test1_mro->{'DBIx::Class::Row'}, 'mro of Test1 correct (Core before Row)' );
  48
  49 warnings_like (
  50   sub {
  51     package A::Test2;
  52     use base 'DBIx::Class::Core';
  53     __PACKAGE__->load_components(qw(UTF8Columns +A::Comp));
  54     sub store_column { shift->next::method (@_) };
  55     1;
  56   },
  57   [qr/Incorrect loading order of DBIx::Class::UTF8Columns.+affect other components overriding 'store_column' \(A::Comp\)/],
  58   'incorrect order warning issued (violator defines)',
  59 );
  60
  61 warnings_like (
  62   sub {
  63     package A::Test3;
  64     use base 'DBIx::Class::Core';
  65     __PACKAGE__->load_components(qw(UTF8Columns +A::SubComp));
  66     sub store_column { shift->next::method (@_) };
  67     1;
  68   },
  69   [qr/Incorrect loading order of DBIx::Class::UTF8Columns.+affect other components overriding 'store_column' \(A::SubComp \(via A::Comp\)\)/],
  70   'incorrect order warning issued (violator inherits)',
  71 );
  72
  73 my $schema = DBICTest->init_schema();
  74 DBICTest::Schema::CD->load_components('UTF8Columns');
  75 DBICTest::Schema::CD->utf8_columns('title');
  76 Class::C3->reinitialize();
  77
  78 # as per http://search.cpan.org/dist/Test-Simple/lib/Test/More.pm#utf8
  79 binmode (Test::More->builder->$_, ':utf8') for qw/output failure_output todo_output/;
  80
  81 my $bytestream_title = my $utf8_title = "weird \x{466} stuff";
  82 utf8::encode($bytestream_title);
  83 cmp_ok ($bytestream_title, 'ne', $utf8_title, 'unicode/raw differ (sanity check)');
  84
  85 my $storage = $schema->storage;
  86 my ($sql, @bind);
  87 my $debugobj = DBIC::DebugObj->new (\$sql, \@bind);
  88 my ($orig_debug, $orig_debugobj) = ($storage->debug, $storage->debugobj);
  89 $storage->debugobj ($debugobj);
  90 $storage->debug (1);
  91
  92 my $cd = $schema->resultset('CD')->create( { artist => 1, title => $utf8_title, year => '2048' } );
  93
  94 $storage->debugobj ($orig_debugobj);
  95 $storage->debug ($orig_debug);
  96
  97 # bind values are always alphabetically ordered by column, thus [1]
  98 # the single quotes are an artefact of the debug-system
  99 TODO: {
 100   local $TODO = "This has been broken since rev 1191, Mar 2006";
 101   is ($bind[1], "'$bytestream_title'", 'INSERT: raw bytes sent to the database');
 102 }
 103
 104 # this should be using the cursor directly, no inflation/processing of any sort
 105 my ($raw_db_title) = $schema->resultset('CD')
 106                              ->search ($cd->ident_condition)
 107                                ->get_column('title')
 108                                 ->_resultset
 109                                  ->cursor
 110                                   ->next;
 111
 112 is ($raw_db_title, $bytestream_title, 'INSERT: raw bytes retrieved from database');
 113
 114 for my $reloaded (0, 1) {
 115   my $test = $reloaded ? 'reloaded' : 'stored';
 116   $cd->discard_changes if $reloaded;
 117
 118   ok( utf8::is_utf8( $cd->title ), "got $test title with utf8 flag" );
 119   ok(! utf8::is_utf8( $cd->{_column_data}{title} ), "in-object $test title without utf8" );
 120
 121   ok(! utf8::is_utf8( $cd->year ), "got $test year without utf8 flag" );
 122   ok(! utf8::is_utf8( $cd->{_column_data}{year} ), "in-object $test year without utf8" );
 123 }
 124
 125 $cd->title('nonunicode');
 126 ok(! utf8::is_utf8( $cd->title ), 'update title without utf8 flag' );
 127 ok(! utf8::is_utf8( $cd->{_column_data}{title} ), 'store utf8-less title' );
 128
 129 $cd->update;
 130 $cd->discard_changes;
 131 ok(! utf8::is_utf8( $cd->title ), 'reloaded title without utf8 flag' );
 132 ok(! utf8::is_utf8( $cd->{_column_data}{title} ), 'reloaded utf8-less title' );
 133
 134 $bytestream_title = $utf8_title = "something \x{219} else";
 135 utf8::encode($bytestream_title);
 136
 137
 138 $storage->debugobj ($debugobj);
 139 $storage->debug (1);
 140
 141 $cd->update ({ title => $utf8_title });
 142
 143 $storage->debugobj ($orig_debugobj);
 144 $storage->debug ($orig_debug);
 145
 146 is ($bind[0], "'$bytestream_title'", 'UPDATE: raw bytes sent to the database');
 147 ($raw_db_title) = $schema->resultset('CD')
 148                              ->search ($cd->ident_condition)
 149                                ->get_column('title')
 150                                 ->_resultset
 151                                  ->cursor
 152                                   ->next;
 153 is ($raw_db_title, $bytestream_title, 'UPDATE: raw bytes retrieved from database');
 154
 155 $cd->discard_changes;
 156 $cd->title($utf8_title);
 157 ok( !$cd->is_column_changed('title'), 'column is not dirty after setting the same unicode value' );
 158
 159 $cd->update ({ title => $utf8_title });
 160 $cd->title('something_else');
 161 ok( $cd->is_column_changed('title'), 'column is dirty after setting to something completely different');
 162
 163 TODO: {
 164   local $TODO = 'There is currently no way to propagate aliases to inflate_result()';
 165   $cd = $schema->resultset('CD')->find ({ title => $utf8_title }, { select => 'title', as => 'name' });
 166   ok (utf8::is_utf8( $cd->get_column ('name') ), 'utf8 flag propagates via as');
 167 }
 168
 169 done_testing;