t/76select.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest ':DiffSQL';
   8
   9 my $schema = DBICTest->init_schema();
  10
  11 my $rs = $schema->resultset('CD')->search({},
  12     {
  13         '+select'   => \ 'COUNT(*)',
  14         '+as'       => 'count'
  15     }
  16 );
  17 lives_ok(sub { $rs->first->get_column('count') }, 'additional count rscolumn present');
  18 dies_ok(sub { $rs->first->get_column('nonexistent_column') }, 'nonexistant column requests still throw exceptions');
  19
  20 $rs = $schema->resultset('CD')->search({},
  21     {
  22         '+select'   => [ \ 'COUNT(*)', 'title' ],
  23         '+as'       => [ 'count', 'addedtitle' ]
  24     }
  25 );
  26 lives_ok(sub { $rs->first->get_column('count') }, 'multiple +select/+as columns, 1st rscolumn present');
  27 lives_ok(sub { $rs->first->get_column('addedtitle') }, 'multiple +select/+as columns, 2nd rscolumn present');
  28
  29 $rs = $schema->resultset('CD')->search({},
  30     {
  31         '+select'   => [ \ 'COUNT(*)', 'title' ],
  32         '+as'       => [ 'count', 'addedtitle' ]
  33     }
  34 )->search({},
  35     {
  36         '+select'   => 'title',
  37         '+as'       => 'addedtitle2'
  38     }
  39 );
  40 lives_ok(sub { $rs->first->get_column('count') }, '+select/+as chained search 1st rscolumn present');
  41 lives_ok(sub { $rs->first->get_column('addedtitle') }, '+select/+as chained search 1st rscolumn present');
  42 lives_ok(sub { $rs->first->get_column('addedtitle2') }, '+select/+as chained search 3rd rscolumn present');
  43
  44
  45 # test the from search attribute (gets between the FROM and WHERE keywords, allows arbitrary subselects)
  46 # also shows that outer select attributes are ok (i.e. order_by)
  47 #
  48 # from doesn't seem to be useful without using a scalarref - there were no initial tests >:(
  49 #
  50 my $cds = $schema->resultset ('CD')->search ({}, { order_by => 'me.cdid'}); # make sure order is consistent
  51 cmp_ok ($cds->count, '>', 2, 'Initially populated with more than 2 CDs');
  52
  53 my $table = $cds->result_source->name;
  54 $table = $$table if ref $table eq 'SCALAR';
  55 my $subsel = $cds->search ({}, {
  56     columns => [qw/cdid title/],
  57     from => \ "(SELECT cdid, title FROM $table LIMIT 2) me",
  58 });
  59
  60 is ($subsel->count, 2, 'Subselect correctly limited the rs to 2 cds');
  61 is ($subsel->next->title, $cds->next->title, 'First CD title match');
  62 is ($subsel->next->title, $cds->next->title, 'Second CD title match');
  63
  64 is($schema->resultset('CD')->current_source_alias, "me", '$rs->current_source_alias returns "me"');
  65
  66
  67
  68 $rs = $schema->resultset('CD')->search({},
  69     {
  70         'join' => 'artist',
  71         'columns' => ['cdid', 'title', 'artist.name'],
  72     }
  73 );
  74
  75 is_same_sql_bind (
  76   $rs->as_query,
  77   '(SELECT me.cdid, me.title, artist.name FROM cd me  JOIN artist artist ON artist.artistid = me.artist)',
  78   [],
  79   'Use of columns attribute results in proper sql'
  80 );
  81
  82 lives_ok(sub {
  83   $rs->first->get_column('cdid')
  84 }, 'columns 1st rscolumn present');
  85
  86 lives_ok(sub {
  87   $rs->first->get_column('title')
  88 }, 'columns 2nd rscolumn present');
  89
  90 lives_ok(sub {
  91   $rs->first->artist->get_column('name')
  92 }, 'columns 3rd rscolumn present');
  93
  94
  95
  96 $rs = $schema->resultset('CD')->search({},
  97     {
  98         'join' => 'artist',
  99         '+columns' => ['cdid', 'title', 'artist.name'],
 100     }
 101 );
 102
 103 is_same_sql_bind (
 104   $rs->as_query,
 105   '(SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track, artist.name FROM cd me  JOIN artist artist ON artist.artistid = me.artist)',
 106   [],
 107   'Use of columns attribute results in proper sql'
 108 );
 109
 110 lives_ok(sub {
 111   $rs->first->get_column('cdid')
 112 }, 'columns 1st rscolumn present');
 113
 114 lives_ok(sub {
 115   $rs->first->get_column('title')
 116 }, 'columns 2nd rscolumn present');
 117
 118 lives_ok(sub {
 119   $rs->first->artist->get_column('name')
 120 }, 'columns 3rd rscolumn present');
 121
 122
 123 $rs = $schema->resultset('CD')->search({'tracks.position' => { -in => [2] } },
 124   {
 125     join => 'tracks',
 126     columns => [qw/me.cdid me.title/],
 127     '+select' => ['tracks.position'],
 128     '+as' => ['track_position'],
 129
 130     # get a hashref of CD1 only (the first with a second track)
 131     result_class => 'DBIx::Class::ResultClass::HashRefInflator',
 132     order_by => 'cdid',
 133     rows => 1,
 134   }
 135 );
 136
 137 is_deeply (
 138   $rs->single,
 139   {
 140     cdid => 1,
 141     track_position => 2,
 142     title => 'Spoonful of bees',
 143   },
 144   'limited prefetch via column works on a multi-relationship',
 145 );
 146
 147 my $sub_rs = $rs->search ({},
 148   {
 149     columns => [qw/artist tracks.trackid/],    # columns should not be merged but override $rs columns
 150     '+select' => ['tracks.title'],
 151     '+as' => ['tracks.title'],
 152   }
 153 );
 154
 155 is_deeply(
 156   $sub_rs->single,
 157   {
 158     artist         => 1,
 159     tracks => {
 160       title => 'Apiary',
 161       trackid => 17,
 162     },
 163   },
 164   'columns/select/as fold properly on sub-searches',
 165 );
 166
 167 # *very* esoteric use-case, yet valid (the "empty" object should not be undef):
 168 $rs = $schema->resultset('Artist');
 169 $rs->create({ artistid => 69, name => 'Ranetki' });
 170
 171 my $relations_or_1_count =
 172   $rs->search_related('cds')->count
 173     +
 174   $rs->search({ 'cds.cdid' => undef }, { join => 'cds' })->count
 175 ;
 176
 177 my $weird_rs = $rs->search({}, {
 178   order_by => { -desc => [ 'me.artistid', 'cds.cdid' ] },
 179   columns => [{ cd_title => 'cds.title', cd_year => 'cds.year' }],
 180   join => 'cds',
 181 });
 182
 183 my $weird_rs_hri = $weird_rs->search({}, { result_class => 'DBIx::Class::ResultClass::HashRefInflator' });
 184
 185 for my $rs ($weird_rs, $weird_rs_hri) {
 186   is ($rs->count, $relations_or_1_count, 'count on rhs data injection matches');
 187
 188   my @all;
 189   while (my $r = $rs->next) {
 190     push @all, $r;
 191   }
 192
 193   is (scalar @all, $relations_or_1_count, 'object count on rhs data injection matches');
 194   is_deeply (
 195     ( $rs->result_class eq 'DBIx::Class::ResultClass::HashRefInflator'
 196         ? \@all
 197         : [ map { +{$_->get_columns} } @all ]
 198     ),
 199     [
 200       {
 201         cd_title => undef,
 202         cd_year => undef,
 203       },
 204       {
 205         cd_title => "Come Be Depressed With Us",
 206         cd_year => 1998,
 207       },
 208       {
 209         cd_title => "Generic Manufactured Singles",
 210         cd_year => 2001,
 211       },
 212       {
 213         cd_title => "Caterwaulin' Blues",
 214         cd_year => 1997,
 215       },
 216       {
 217         cd_title => "Forkful of bees",
 218         cd_year => 2001,
 219       },
 220       {
 221         cd_title => "Spoonful of bees",
 222         cd_year => 1999,
 223       },
 224     ],
 225     'Correct data retrieved'
 226   );
 227
 228   is_deeply( [ $rs->all ], \@all, '->all matches' );
 229 }
 230
 231 done_testing;