t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  11
  12 my $TESTS = 35 + 2;
  13
  14 if (not ($dsn && $user)) {
  15   plan skip_all =>
  16     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  17     "\nWarning: This test drops and creates the tables " .
  18     "'artist' and 'bindtype_test'";
  19 } else {
  20   plan tests => $TESTS*2;
  21 }
  22
  23 my @storage_types = (
  24   'DBI::Sybase',
  25   'DBI::Sybase::NoBindVars',
  26 );
  27 my $schema;
  28 my $storage_idx = -1;
  29
  30 for my $storage_type (@storage_types) {
  31   $storage_idx++;
  32 # this is so we can set ->storage_type before connecting
  33   my $schema = DBICTest::Schema->clone;
  34
  35   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  36     $schema->storage_type("::$storage_type");
  37   }
  38
  39   $schema->connection($dsn, $user, $pass, {
  40     AutoCommit => 1,
  41     on_connect_call => [
  42       [ blob_setup => log_on_update => 1 ], # this is a safer option
  43     ],
  44   });
  45
  46   $schema->storage->ensure_connected;
  47
  48   if ($storage_idx == 0 &&
  49       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  50 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  51       my $tb = Test::More->builder;
  52       $tb->skip('no placeholders') for 1..$TESTS;
  53       next;
  54   }
  55
  56   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  57
  58   $schema->storage->_dbh->disconnect;
  59   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  60
  61   $schema->storage->dbh_do (sub {
  62       my ($storage, $dbh) = @_;
  63       eval { $dbh->do("DROP TABLE artist") };
  64       $dbh->do(<<'SQL');
  65 CREATE TABLE artist (
  66    artistid INT IDENTITY PRIMARY KEY,
  67    name VARCHAR(100),
  68    rank INT DEFAULT 13 NOT NULL,
  69    charfield CHAR(10) NULL
  70 )
  71 SQL
  72   });
  73
  74   my %seen_id;
  75
  76 # so we start unconnected
  77   $schema->storage->disconnect;
  78
  79 # inserts happen in a txn, so we make sure it still works inside a txn too
  80   $schema->txn_begin;
  81
  82 # test primary key handling
  83   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  84   ok($new->artistid > 0, "Auto-PK worked");
  85
  86   $seen_id{$new->artistid}++;
  87
  88   for (1..6) {
  89     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  90     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  91     $seen_id{$new->artistid}++;
  92   }
  93
  94   $schema->txn_commit;
  95
  96 # test simple count
  97   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
  98
  99 # test LIMIT support
 100   my $it = $schema->resultset('Artist')->search({
 101     artistid => { '>' => 0 }
 102   }, {
 103     rows => 3,
 104     order_by => 'artistid',
 105   });
 106
 107   is( $it->count, 3, "LIMIT count ok" );
 108
 109   is( $it->next->name, "foo", "iterator->next ok" );
 110   $it->next;
 111   is( $it->next->name, "Artist 2", "iterator->next ok" );
 112   is( $it->next, undef, "next past end of resultset ok" );
 113
 114 # now try with offset
 115   $it = $schema->resultset('Artist')->search({}, {
 116     rows => 3,
 117     offset => 3,
 118     order_by => 'artistid',
 119   });
 120
 121   is( $it->count, 3, "LIMIT with offset count ok" );
 122
 123   is( $it->next->name, "Artist 3", "iterator->next ok" );
 124   $it->next;
 125   is( $it->next->name, "Artist 5", "iterator->next ok" );
 126   is( $it->next, undef, "next past end of resultset ok" );
 127
 128 # now try a grouped count
 129   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 130     for (1..6);
 131
 132   $it = $schema->resultset('Artist')->search({}, {
 133     group_by => 'name'
 134   });
 135
 136   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 137
 138 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 139   SKIP: {
 140     skip 'TEXT/IMAGE support does not work with FreeTDS', 12
 141       if $schema->storage->using_freetds;
 142
 143     my $dbh = $schema->storage->dbh;
 144     {
 145       local $SIG{__WARN__} = sub {};
 146       eval { $dbh->do('DROP TABLE bindtype_test') };
 147
 148       $dbh->do(qq[
 149         CREATE TABLE bindtype_test
 150         (
 151           id    INT   IDENTITY PRIMARY KEY,
 152           bytea INT   NULL,
 153           blob  IMAGE NULL,
 154           clob  TEXT  NULL
 155         )
 156       ],{ RaiseError => 1, PrintError => 0 });
 157     }
 158
 159     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 160     $binstr{'large'} = $binstr{'small'} x 1024;
 161
 162     my $maxloblen = length $binstr{'large'};
 163
 164     if (not $schema->storage->using_freetds) {
 165       $dbh->{'LongReadLen'} = $maxloblen * 2;
 166     } else {
 167       $dbh->do("set textsize ".($maxloblen * 2));
 168     }
 169
 170     my $rs = $schema->resultset('BindType');
 171     my $last_id;
 172
 173     foreach my $type (qw(blob clob)) {
 174       foreach my $size (qw(small large)) {
 175         no warnings 'uninitialized';
 176
 177         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 178         ok(!$@, "inserted $size $type without dying");
 179         diag $@ if $@;
 180
 181         $last_id = $created->id if $created;
 182
 183         my $got = eval {
 184           $rs->find($last_id)->$type
 185         };
 186         diag $@ if $@;
 187         ok($got eq $binstr{$size}, "verified inserted $size $type");
 188       }
 189     }
 190
 191     # blob insert with explicit PK
 192     # also a good opportunity to test IDENTITY_INSERT
 193     {
 194       local $SIG{__WARN__} = sub {};
 195       eval { $dbh->do('DROP TABLE bindtype_test') };
 196
 197       $dbh->do(qq[
 198         CREATE TABLE bindtype_test
 199         (
 200           id    INT   IDENTITY PRIMARY KEY,
 201           bytea INT   NULL,
 202           blob  IMAGE NULL,
 203           clob  TEXT  NULL
 204         )
 205       ],{ RaiseError => 1, PrintError => 0 });
 206     }
 207     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 208     ok(!$@, "inserted large blob without dying with manual PK");
 209     diag $@ if $@;
 210
 211     my $got = eval {
 212       $rs->find(1)->blob
 213     };
 214     diag $@ if $@;
 215     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 216
 217     # try a blob update
 218     my $new_str = $binstr{large} . 'mtfnpy';
 219     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 220     ok !$@, 'updated blob successfully';
 221     diag $@ if $@;
 222     $got = eval {
 223       $rs->find(1)->blob
 224     };
 225     diag $@ if $@;
 226     ok($got eq $new_str, "verified updated blob");
 227   }
 228
 229 # test MONEY column support
 230   $schema->storage->dbh_do (sub {
 231       my ($storage, $dbh) = @_;
 232       eval { $dbh->do("DROP TABLE money_test") };
 233       $dbh->do(<<'SQL');
 234 CREATE TABLE money_test (
 235    id INT IDENTITY PRIMARY KEY,
 236    amount MONEY NULL
 237 )
 238 SQL
 239   });
 240
 241   my $rs = $schema->resultset('Money');
 242
 243   my $row;
 244   lives_ok {
 245     $row = $rs->create({ amount => 100 });
 246   } 'inserted a money value';
 247
 248   is eval { $rs->find($row->id)->amount }, 100, 'money value round-trip';
 249
 250   lives_ok {
 251     $row->update({ amount => 200 });
 252   } 'updated a money value';
 253
 254   is eval { $rs->find($row->id)->amount },
 255     200, 'updated money value round-trip';
 256
 257   lives_ok {
 258     $row->update({ amount => undef });
 259   } 'updated a money value to NULL';
 260
 261   my $null_amount = eval { $rs->find($row->id)->amount };
 262   ok(
 263     (($null_amount == undef) && (not $@)),
 264     'updated money value to NULL round-trip'
 265   );
 266   diag $@ if $@;
 267 }
 268
 269 # clean up our mess
 270 END {
 271   if (my $dbh = eval { $schema->storage->_dbh }) {
 272     eval { $dbh->do("DROP TABLE $_") }
 273       for qw/artist bindtype_test money_test/;
 274   }
 275 }