t/746sybase.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_ase';
   2
   3 use strict;
   4 use warnings;
   5 no warnings 'uninitialized';
   6
   7 use Test::More;
   8 use Test::Exception;
   9 use lib qw(t/lib);
  10 use DBICTest;
  11
  12 my @storage_types = (
  13   'DBI::Sybase::ASE',
  14   'DBI::Sybase::ASE::NoBindVars',
  15 );
  16 eval "require DBIx::Class::Storage::$_;" or die $@
  17   for @storage_types;
  18
  19 my $schema;
  20 my $storage_idx = -1;
  21
  22 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  23
  24 sub get_schema {
  25   DBICTest::Schema->connect($dsn, $user, $pass, {
  26     on_connect_call => [
  27       [ blob_setup => log_on_update => 1 ], # this is a safer option
  28     ],
  29   });
  30 }
  31
  32 my $ping_count = 0;
  33 {
  34   my $ping = DBIx::Class::Storage::DBI::Sybase::ASE->can('_ping');
  35   *DBIx::Class::Storage::DBI::Sybase::ASE::_ping = sub {
  36     $ping_count++;
  37     goto $ping;
  38   };
  39 }
  40
  41 for my $storage_type (@storage_types) {
  42   $storage_idx++;
  43
  44   unless ($storage_type eq 'DBI::Sybase::ASE') { # autodetect
  45     DBICTest::Schema->storage_type("::$storage_type");
  46   }
  47
  48   $schema = get_schema();
  49
  50   $schema->storage->ensure_connected;
  51
  52   if ($storage_idx == 0 &&
  53       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars')) {
  54       # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  55       skip "Skipping entire test for $storage_type - no placeholder support", 1;
  56       next;
  57   }
  58
  59   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  60
  61   $schema->storage->_dbh->disconnect;
  62   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  63
  64   $schema->storage->dbh_do (sub {
  65       my ($storage, $dbh) = @_;
  66       eval { $dbh->do("DROP TABLE artist") };
  67       $dbh->do(<<'SQL');
  68 CREATE TABLE artist (
  69    artistid INT IDENTITY PRIMARY KEY,
  70    name VARCHAR(100),
  71    rank INT DEFAULT 13 NOT NULL,
  72    charfield CHAR(10) NULL
  73 )
  74 SQL
  75   });
  76
  77   my %seen_id;
  78
  79 # so we start unconnected
  80   $schema->storage->disconnect;
  81
  82 # test primary key handling
  83   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  84   like $new->artistid, qr/^\d+\z/, 'Auto-PK returned a number';
  85   ok($new->artistid > 0, "Auto-PK worked");
  86
  87   $seen_id{$new->artistid}++;
  88
  89 # check redispatch to storage-specific insert when auto-detected storage
  90   if ($storage_type eq 'DBI::Sybase::ASE') {
  91     DBICTest::Schema->storage_type('::DBI');
  92     $schema = get_schema();
  93   }
  94
  95   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
  96   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
  97   $seen_id{$new->artistid}++;
  98
  99 # inserts happen in a txn, so we make sure it still works inside a txn too
 100   $schema->txn_begin;
 101
 102   for (2..6) {
 103     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 104     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 105     $seen_id{$new->artistid}++;
 106   }
 107
 108   $schema->txn_commit;
 109
 110 # test simple count
 111   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 112
 113 # test LIMIT support
 114   my $it = $schema->resultset('Artist')->search({
 115     artistid => { '>' => 0 }
 116   }, {
 117     rows => 3,
 118     order_by => 'artistid',
 119   });
 120
 121   is( $it->count, 3, "LIMIT count ok" );
 122
 123   is( $it->next->name, "foo", "iterator->next ok" );
 124   $it->next;
 125   is( $it->next->name, "Artist 2", "iterator->next ok" );
 126   is( $it->next, undef, "next past end of resultset ok" );
 127
 128 # now try with offset
 129   $it = $schema->resultset('Artist')->search({}, {
 130     rows => 3,
 131     offset => 3,
 132     order_by => 'artistid',
 133   });
 134
 135   is( $it->count, 3, "LIMIT with offset count ok" );
 136
 137   is( $it->next->name, "Artist 3", "iterator->next ok" );
 138   $it->next;
 139   is( $it->next->name, "Artist 5", "iterator->next ok" );
 140   is( $it->next, undef, "next past end of resultset ok" );
 141
 142 # now try a grouped count
 143   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 144     for (1..6);
 145
 146   $it = $schema->resultset('Artist')->search({}, {
 147     group_by => 'name'
 148   });
 149
 150   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 151
 152 # do an IDENTITY_INSERT
 153   {
 154     no warnings 'redefine';
 155
 156     my @debug_out;
 157     local $schema->storage->{debug} = 1;
 158     local $schema->storage->debugobj->{callback} = sub {
 159       push @debug_out, $_[1];
 160     };
 161
 162     my $txn_used = 0;
 163     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 164     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 165       $txn_used = 1;
 166       goto &$txn_commit;
 167     };
 168
 169     $schema->resultset('Artist')
 170       ->create({ artistid => 999, name => 'mtfnpy' });
 171
 172     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT used');
 173
 174     SKIP: {
 175       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 176         if $storage_type =~ /NoBindVars/i;
 177
 178       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 179     }
 180   }
 181
 182 # do an IDENTITY_UPDATE
 183   {
 184     my @debug_out;
 185     local $schema->storage->{debug} = 1;
 186     local $schema->storage->debugobj->{callback} = sub {
 187       push @debug_out, $_[1];
 188     };
 189
 190     lives_and {
 191       $schema->resultset('Artist')
 192         ->find(999)->update({ artistid => 555 });
 193       ok((grep /IDENTITY_UPDATE/i, @debug_out));
 194     } 'IDENTITY_UPDATE used';
 195     $ping_count-- if $@;
 196   }
 197
 198   my $bulk_rs = $schema->resultset('Artist')->search({
 199     name => { -like => 'bulk artist %' }
 200   });
 201
 202 # test _insert_bulk using populate.
 203   SKIP: {
 204     skip '_insert_bulk not supported', 4
 205       unless $storage_type !~ /NoBindVars/i;
 206
 207     lives_ok {
 208       $schema->resultset('Artist')->populate([
 209         {
 210           name => 'bulk artist 1',
 211           charfield => 'foo',
 212         },
 213         {
 214           name => 'bulk artist 2',
 215           charfield => 'foo',
 216         },
 217         {
 218           name => 'bulk artist 3',
 219           charfield => 'foo',
 220         },
 221       ]);
 222     } '_insert_bulk via populate';
 223
 224     is $bulk_rs->count, 3, 'correct number inserted via _insert_bulk';
 225
 226     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 227       'column set correctly via _insert_bulk');
 228
 229     my %bulk_ids;
 230     @bulk_ids{map $_->artistid, $bulk_rs->all} = ();
 231
 232     is ((scalar keys %bulk_ids), 3,
 233       'identities generated correctly in _insert_bulk');
 234
 235     $bulk_rs->delete;
 236   }
 237
 238 # make sure _insert_bulk works a second time on the same connection
 239   SKIP: {
 240     skip '_insert_bulk not supported', 3
 241       unless $storage_type !~ /NoBindVars/i;
 242
 243     lives_ok {
 244       $schema->resultset('Artist')->populate([
 245         {
 246           name => 'bulk artist 1',
 247           charfield => 'bar',
 248         },
 249         {
 250           name => 'bulk artist 2',
 251           charfield => 'bar',
 252         },
 253         {
 254           name => 'bulk artist 3',
 255           charfield => 'bar',
 256         },
 257       ]);
 258     } '_insert_bulk via populate called a second time';
 259
 260     is $bulk_rs->count, 3,
 261       'correct number inserted via _insert_bulk';
 262
 263     is ((grep $_->charfield eq 'bar', $bulk_rs->all), 3,
 264       'column set correctly via _insert_bulk');
 265
 266     $bulk_rs->delete;
 267   }
 268
 269 # test invalid _insert_bulk (missing required column)
 270 #
 271   throws_ok {
 272     $schema->resultset('Artist')->populate([
 273       {
 274         charfield => 'foo',
 275       }
 276     ]);
 277   }
 278 # The second pattern is the error from fallback to regular array insert on
 279 # incompatible charset.
 280 # The third is for ::NoBindVars with no syb_has_blk.
 281   qr/
 282     \Qno value or default\E
 283       |
 284     \Qdoes not allow null\E
 285       |
 286     \QUnable to invoke fast-path insert without storage placeholder support\E
 287   /xi,
 288   '_insert_bulk with missing required column throws error';
 289
 290 # now test _insert_bulk with IDENTITY_INSERT
 291   SKIP: {
 292     skip '_insert_bulk not supported', 3
 293       unless $storage_type !~ /NoBindVars/i;
 294
 295     lives_ok {
 296       $schema->resultset('Artist')->populate([
 297         {
 298           artistid => 2001,
 299           name => 'bulk artist 1',
 300           charfield => 'foo',
 301         },
 302         {
 303           artistid => 2002,
 304           name => 'bulk artist 2',
 305           charfield => 'foo',
 306         },
 307         {
 308           artistid => 2003,
 309           name => 'bulk artist 3',
 310           charfield => 'foo',
 311         },
 312       ]);
 313     } '_insert_bulk with IDENTITY_INSERT via populate';
 314
 315     is $bulk_rs->count, 3,
 316       'correct number inserted via _insert_bulk with IDENTITY_INSERT';
 317
 318     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 319       'column set correctly via _insert_bulk with IDENTITY_INSERT');
 320
 321     $bulk_rs->delete;
 322   }
 323
 324 # test correlated subquery
 325   my $subq = $schema->resultset('Artist')->search({ artistid => { '>' => 3 } })
 326     ->get_column('artistid')
 327     ->as_query;
 328   my $subq_rs = $schema->resultset('Artist')->search({
 329     artistid => { -in => $subq }
 330   });
 331   is $subq_rs->count, 11, 'correlated subquery';
 332
 333 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 334   SKIP: {
 335     skip 'TEXT/IMAGE support does not work with FreeTDS', 22
 336       if $schema->storage->_using_freetds;
 337
 338     my $dbh = $schema->storage->_dbh;
 339     {
 340       local $SIG{__WARN__} = sub {};
 341       eval { $dbh->do('DROP TABLE bindtype_test') };
 342
 343       $dbh->do(qq[
 344         CREATE TABLE bindtype_test
 345         (
 346           id     INT   IDENTITY PRIMARY KEY,
 347           bytea  IMAGE NULL,
 348           blob   IMAGE NULL,
 349           clob   TEXT  NULL,
 350           a_memo IMAGE NULL
 351         )
 352       ],{ RaiseError => 1, PrintError => 0 });
 353     }
 354
 355     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 356     $binstr{'large'} = $binstr{'small'} x 1024;
 357
 358     my $maxloblen = length $binstr{'large'};
 359
 360     if (not $schema->storage->_using_freetds) {
 361       $dbh->{'LongReadLen'} = $maxloblen * 2;
 362     } else {
 363       $dbh->do("set textsize ".($maxloblen * 2));
 364     }
 365
 366     my $rs = $schema->resultset('BindType');
 367     my $last_id;
 368
 369     foreach my $type (qw(blob clob)) {
 370       foreach my $size (qw(small large)) {
 371         no warnings 'uninitialized';
 372
 373         my $created;
 374         lives_ok {
 375           $created = $rs->create( { $type => $binstr{$size} } )
 376         } "inserted $size $type without dying";
 377
 378         $last_id = $created->id if $created;
 379
 380         lives_and {
 381           ok($rs->find($last_id)->$type eq $binstr{$size})
 382         } "verified inserted $size $type";
 383       }
 384     }
 385
 386     $rs->delete;
 387
 388     # blob insert with explicit PK
 389     # also a good opportunity to test IDENTITY_INSERT
 390     lives_ok {
 391       $rs->create( { id => 1, blob => $binstr{large} } )
 392     } 'inserted large blob without dying with manual PK';
 393
 394     lives_and {
 395       ok($rs->find(1)->blob eq $binstr{large})
 396     } 'verified inserted large blob with manual PK';
 397
 398     # try a blob update
 399     my $new_str = $binstr{large} . 'mtfnpy';
 400
 401     # check redispatch to storage-specific update when auto-detected storage
 402     if ($storage_type eq 'DBI::Sybase::ASE') {
 403       DBICTest::Schema->storage_type('::DBI');
 404       $schema = get_schema();
 405     }
 406
 407     lives_ok {
 408       $rs->search({ id => 1 })->update({ blob => $new_str })
 409     } 'updated blob successfully';
 410
 411     lives_and {
 412       ok($rs->find(1)->blob eq $new_str)
 413     } 'verified updated blob';
 414
 415     # try a blob update with IDENTITY_UPDATE
 416     lives_and {
 417       $new_str = $binstr{large} . 'hlagh';
 418       $rs->find(1)->update({ id => 999, blob => $new_str });
 419       ok($rs->find(999)->blob eq $new_str);
 420     } 'verified updated blob with IDENTITY_UPDATE';
 421
 422     ## try multi-row blob update
 423     # first insert some blobs
 424     $new_str = $binstr{large} . 'foo';
 425     lives_and {
 426       $rs->delete;
 427       $rs->create({ blob => $binstr{large} }) for (1..2);
 428       $rs->update({ blob => $new_str });
 429       is((grep $_->blob eq $new_str, $rs->all), 2);
 430     } 'multi-row blob update';
 431
 432     $rs->delete;
 433
 434     # now try _insert_bulk with blobs and only blobs
 435     $new_str = $binstr{large} . 'bar';
 436     lives_ok {
 437       $rs->populate([
 438         {
 439           blob => $binstr{large},
 440           clob => $new_str,
 441         },
 442         {
 443           blob => $binstr{large},
 444           clob => $new_str,
 445         },
 446       ]);
 447     } '_insert_bulk with blobs does not die';
 448
 449     is((grep $_->blob eq $binstr{large}, $rs->all), 2,
 450       'IMAGE column set correctly via _insert_bulk');
 451
 452     is((grep $_->clob eq $new_str, $rs->all), 2,
 453       'TEXT column set correctly via _insert_bulk');
 454
 455     # now try _insert_bulk with blobs and a non-blob which also happens to be an
 456     # identity column
 457     SKIP: {
 458       skip 'no _insert_bulk without placeholders', 4
 459         if $storage_type =~ /NoBindVars/i;
 460
 461       $rs->delete;
 462       $new_str = $binstr{large} . 'bar';
 463       lives_ok {
 464         $rs->populate([
 465           {
 466             id => 1,
 467             bytea => 1,
 468             blob => $binstr{large},
 469             clob => $new_str,
 470             a_memo => 2,
 471           },
 472           {
 473             id => 2,
 474             bytea => 1,
 475             blob => $binstr{large},
 476             clob => $new_str,
 477             a_memo => 2,
 478           },
 479         ]);
 480       } '_insert_bulk with blobs and explicit identity does NOT die';
 481
 482       is((grep $_->blob eq $binstr{large}, $rs->all), 2,
 483         'IMAGE column set correctly via _insert_bulk with identity');
 484
 485       is((grep $_->clob eq $new_str, $rs->all), 2,
 486         'TEXT column set correctly via _insert_bulk with identity');
 487
 488       is_deeply [ map $_->id, $rs->all ], [ 1,2 ],
 489         'explicit identities set correctly via _insert_bulk with blobs';
 490     }
 491
 492     lives_and {
 493       $rs->delete;
 494       $rs->create({ blob => $binstr{large} }) for (1..2);
 495       $rs->update({ blob => undef });
 496       is((grep !defined($_->blob), $rs->all), 2);
 497     } 'blob update to NULL';
 498   }
 499
 500 # test MONEY column support (and some other misc. stuff)
 501   $schema->storage->dbh_do (sub {
 502       my ($storage, $dbh) = @_;
 503       eval { $dbh->do("DROP TABLE money_test") };
 504       $dbh->do(<<'SQL');
 505 CREATE TABLE money_test (
 506    id INT IDENTITY PRIMARY KEY,
 507    amount MONEY DEFAULT $999.99 NULL
 508 )
 509 SQL
 510   });
 511
 512   my $rs = $schema->resultset('Money');
 513
 514 # test insert with defaults
 515   lives_and {
 516     $rs->create({});
 517     is((grep $_->amount == 999.99, $rs->all), 1);
 518   } 'insert with all defaults works';
 519   $rs->delete;
 520
 521 # test insert transaction when there's an active cursor
 522   {
 523     my $artist_rs = $schema->resultset('Artist');
 524     $artist_rs->first;
 525     lives_ok {
 526       my $row = $schema->resultset('Money')->create({ amount => 100 });
 527       $row->delete;
 528     } 'inserted a row with an active cursor';
 529     $ping_count-- if $@; # dbh_do calls ->connected
 530   }
 531
 532 # test insert in an outer transaction when there's an active cursor
 533   {
 534     local $TODO = 'this should work once we have eager cursors';
 535
 536 # clear state, or we get a deadlock on $row->delete
 537 # XXX figure out why this happens
 538     $schema->storage->disconnect;
 539
 540     lives_ok {
 541       $schema->txn_do(sub {
 542         my $artist_rs = $schema->resultset('Artist');
 543         $artist_rs->first;
 544         my $row = $schema->resultset('Money')->create({ amount => 100 });
 545         $row->delete;
 546       });
 547     } 'inserted a row with an active cursor in outer txn';
 548     $ping_count-- if $@; # dbh_do calls ->connected
 549   }
 550
 551 # Now test money values.
 552   my $row;
 553   lives_ok {
 554     $row = $rs->create({ amount => 100 });
 555   } 'inserted a money value';
 556
 557   cmp_ok eval { $rs->find($row->id)->amount }, '==', 100,
 558     'money value round-trip';
 559
 560   lives_ok {
 561     $row->update({ amount => 200 });
 562   } 'updated a money value';
 563
 564   cmp_ok eval { $rs->find($row->id)->amount }, '==', 200,
 565     'updated money value round-trip';
 566
 567   lives_ok {
 568     $row->update({ amount => undef });
 569   } 'updated a money value to NULL';
 570
 571   lives_and {
 572     my $null_amount = $rs->find($row->id)->amount;
 573     is $null_amount, undef;
 574   } 'updated money value to NULL round-trip';
 575
 576 # Test computed columns and timestamps
 577   $schema->storage->dbh_do (sub {
 578       my ($storage, $dbh) = @_;
 579       eval { $dbh->do("DROP TABLE computed_column_test") };
 580       $dbh->do(<<'SQL');
 581 CREATE TABLE computed_column_test (
 582    id INT IDENTITY PRIMARY KEY,
 583    a_computed_column AS getdate(),
 584    a_timestamp timestamp,
 585    charfield VARCHAR(20) DEFAULT 'foo'
 586 )
 587 SQL
 588   });
 589
 590   require DBICTest::Schema::ComputedColumn;
 591   $schema->register_class(
 592     ComputedColumn => 'DBICTest::Schema::ComputedColumn'
 593   );
 594
 595   ok (($rs = $schema->resultset('ComputedColumn')),
 596     'got rs for ComputedColumn');
 597
 598   lives_ok { $row = $rs->create({}) }
 599     'empty insert for a table with computed columns survived';
 600
 601   lives_ok {
 602     $row->update({ charfield => 'bar' })
 603   } 'update of a table with computed columns survived';
 604 }
 605
 606 is $ping_count, 0, 'no pings';
 607
 608 # if tests passed and did so under a non-C lang - let's rerun the test
 609 if (Test::Builder->new->is_passing and $ENV{LANG} and $ENV{LANG} ne 'C') {
 610   my $oldlang = $ENV{LANG};
 611   local $ENV{LANG} = 'C';
 612
 613   pass ("Your lang is set to $oldlang - retesting with C");
 614
 615   local $ENV{PATH};
 616   my @cmd = map { $_ =~ /(.+)/ } ($^X, __FILE__);
 617
 618   # this is cheating, and may even hang here and there (testing on windows passed fine)
 619   # will be replaced with Test::SubExec::Noninteractive in due course
 620   require IPC::Open2;
 621   IPC::Open2::open2(my $out, undef, @cmd);
 622   while (my $ln = <$out>) {
 623     print "   $ln";
 624   }
 625
 626   wait;
 627   ok (! $?, "Wstat $? from: @cmd");
 628 }
 629
 630 done_testing;
 631
 632 # clean up our mess
 633 END {
 634   if (my $dbh = eval { $schema->storage->_dbh }) {
 635     eval { $dbh->do("DROP TABLE $_") }
 636       for qw/artist bindtype_test money_test computed_column_test/;
 637   }
 638
 639   undef $schema;
 640 }