t/73oracle.t

   1 {
   2   package    # hide from PAUSE
   3     DBICTest::Schema::ArtistFQN;
   4
   5   use base 'DBIx::Class::Core';
   6
   7   __PACKAGE__->table(
   8     $ENV{DBICTEST_ORA_USER}
   9       ? (uc $ENV{DBICTEST_ORA_USER}) . '.artist'
  10       : '??_no_user_??'
  11   );
  12   __PACKAGE__->add_columns(
  13     'artistid' => {
  14       data_type         => 'integer',
  15       is_auto_increment => 1,
  16     },
  17     'name' => {
  18       data_type   => 'varchar',
  19       size        => 100,
  20       is_nullable => 1,
  21     },
  22     'autoinc_col' => {
  23       data_type         => 'integer',
  24       is_auto_increment => 1,
  25     },
  26   );
  27   __PACKAGE__->set_primary_key(qw/ artistid autoinc_col /);
  28
  29   1;
  30 }
  31
  32 use strict;
  33 use warnings;
  34
  35 use Test::Exception;
  36 use Test::More;
  37 use Sub::Name;
  38
  39 use lib qw(t/lib);
  40 use DBICTest;
  41 use DBIC::SqlMakerTest;
  42
  43 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_oracle')
  44   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_oracle');
  45
  46 $ENV{NLS_SORT} = "BINARY";
  47 $ENV{NLS_COMP} = "BINARY";
  48 $ENV{NLS_LANG} = "AMERICAN";
  49
  50 my ($dsn,  $user,  $pass)  = @ENV{map { "DBICTEST_ORA_${_}" }  qw/DSN USER PASS/};
  51
  52 # optional:
  53 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_ORA_EXTRAUSER_${_}" } qw/DSN USER PASS/};
  54
  55 plan skip_all => 'Set $ENV{DBICTEST_ORA_DSN}, _USER and _PASS to run this test.'
  56   unless ($dsn && $user && $pass);
  57
  58 DBICTest::Schema->load_classes('ArtistFQN');
  59
  60 # This is in Core now, but it's here just to test that it doesn't break
  61 DBICTest::Schema::Artist->load_components('PK::Auto');
  62 # These are compat shims for PK::Auto...
  63 DBICTest::Schema::CD->load_components('PK::Auto::Oracle');
  64 DBICTest::Schema::Track->load_components('PK::Auto::Oracle');
  65
  66
  67 ##########
  68 # recyclebin sometimes comes in the way
  69 my $on_connect_sql = ["ALTER SESSION SET recyclebin = OFF"];
  70
  71 # iterate all tests on following options
  72 my @tryopt = (
  73   { on_connect_do => $on_connect_sql },
  74   { quote_char => '"', on_connect_do => $on_connect_sql, },
  75 );
  76
  77 # keep a database handle open for cleanup
  78 my ($dbh, $dbh2);
  79
  80 # test insert returning
  81
  82 # check if we indeed do support stuff
  83 my $test_server_supports_insert_returning = do {
  84   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  85                    ->storage
  86                     ->_get_dbh
  87                      ->get_info(18);
  88   $v =~ /^(\d+)\.(\d+)/
  89     or die "Unparseable Oracle server version: $v\n";
  90
  91 # TODO find out which version supports the RETURNING syntax
  92 # 8i has it and earlier docs are a 404 on oracle.com
  93   ( $1 > 8 || ($1 == 8 && $2 >= 1) ) ? 1 : 0;
  94 };
  95 is (
  96   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
  97   $test_server_supports_insert_returning,
  98   'insert returning capability guessed correctly'
  99 );
 100
 101 my $schema;
 102 for my $use_insert_returning ($test_server_supports_insert_returning
 103   ? (1,0)
 104   : (0)
 105 ) {
 106
 107   no warnings qw/once/;
 108   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 109     my $s = shift->next::method (@_);
 110     $s->storage->_use_insert_returning ($use_insert_returning);
 111     $s;
 112   };
 113
 114   for my $opt (@tryopt) {
 115     # clean all cached sequences from previous run
 116     for (map { values %{DBICTest::Schema->source($_)->columns_info} } (qw/Artist CD Track/) ) {
 117       delete $_->{sequence};
 118     }
 119
 120     my $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opt);
 121
 122     $dbh = $schema->storage->dbh;
 123     my $q = $schema->storage->sql_maker->quote_char || '';
 124
 125     do_creates($dbh, $q);
 126
 127     _run_tests($schema, $opt);
 128   }
 129 }
 130
 131 sub _run_tests {
 132   my ($schema, $opt) = @_;
 133
 134   my $q = $schema->storage->sql_maker->quote_char || '';
 135
 136 # test primary key handling with multiple triggers
 137   my ($new, $seq);
 138
 139   my $new_artist = $schema->resultset('Artist')->create({ name => 'foo' });
 140   my $new_cd     = $schema->resultset('CD')->create({ artist => 1, title => 'EP C', year => '2003' });
 141
 142   SKIP: {
 143     skip 'not detecting sequences when using INSERT ... RETURNING', 4
 144       if $schema->storage->_use_insert_returning;
 145
 146     is($new_artist->artistid, 1, "Oracle Auto-PK worked for standard sqlt-like trigger");
 147     $seq = $new_artist->result_source->column_info('artistid')->{sequence};
 148     $seq = $$seq if ref $seq;
 149     like ($seq, qr/\.${q}artist_pk_seq${q}$/, 'Correct PK sequence selected for sqlt-like trigger');
 150
 151     is($new_cd->cdid, 1, 'Oracle Auto-PK worked - using scalar ref as table name/custom weird trigger');
 152     $seq = $new_cd->result_source->column_info('cdid')->{sequence};
 153     $seq = $$seq if ref $seq;
 154     like ($seq, qr/\.${q}cd_seq${q}$/, 'Correct PK sequence selected for custom trigger');
 155   }
 156
 157 # test PKs again with fully-qualified table name
 158   my $artistfqn_rs = $schema->resultset('ArtistFQN');
 159   my $artist_rsrc = $artistfqn_rs->result_source;
 160
 161   delete $artist_rsrc->column_info('artistid')->{sequence};
 162   $new = $artistfqn_rs->create( { name => 'bar' } );
 163
 164   is_deeply( {map { $_ => $new->$_ } $artist_rsrc->primary_columns},
 165     { artistid => 2, autoinc_col => 2},
 166     "Oracle Multi-Auto-PK worked with fully-qualified tablename" );
 167
 168
 169   delete $artist_rsrc->column_info('artistid')->{sequence};
 170   $new = $artistfqn_rs->create( { name => 'bar', autoinc_col => 1000 } );
 171
 172   is( $new->artistid, 3, "Oracle Auto-PK worked with fully-qualified tablename" );
 173   is( $new->autoinc_col, 1000, "Oracle Auto-Inc overruled with fully-qualified tablename");
 174
 175   SKIP: {
 176     skip 'not detecting sequences when using INSERT ... RETURNING', 1
 177       if $schema->storage->_use_insert_returning;
 178
 179     $seq = $new->result_source->column_info('artistid')->{sequence};
 180     $seq = $$seq if ref $seq;
 181     like ($seq, qr/\.${q}artist_pk_seq${q}$/, 'Correct PK sequence selected for sqlt-like trigger');
 182   }
 183
 184
 185 # test LIMIT support
 186   for (1..6) {
 187     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 188   }
 189   my $it = $schema->resultset('Artist')->search( { name => { -like => 'Artist %' } }, {
 190     rows => 3,
 191     offset => 4,
 192     order_by => 'artistid'
 193   });
 194
 195   is( $it->count, 2, "LIMIT count past end of RS ok" );
 196   is( $it->next->name, "Artist 5", "iterator->next ok" );
 197   is( $it->next->name, "Artist 6", "iterator->next ok" );
 198   is( $it->next, undef, "next past end of resultset ok" );
 199
 200
 201 # test identifiers over the 30 char limit
 202   lives_ok {
 203     my @results = $schema->resultset('CD')->search(undef, {
 204       prefetch => 'very_long_artist_relationship',
 205       rows => 3,
 206       offset => 0,
 207     })->all;
 208     ok( scalar @results > 0, 'limit with long identifiers returned something');
 209   } 'limit with long identifiers executed successfully';
 210
 211
 212 # test rel names over the 30 char limit
 213   my $query = $schema->resultset('Artist')->search({
 214     artistid => 1
 215   }, {
 216     prefetch => 'cds_very_very_very_long_relationship_name'
 217   });
 218
 219   lives_and {
 220     is $query->first->cds_very_very_very_long_relationship_name->first->cdid, 1
 221   } 'query with rel name over 30 chars survived and worked';
 222
 223   # rel name over 30 char limit with user condition
 224   # This requires walking the SQLA data structure.
 225   {
 226     local $TODO = 'user condition on rel longer than 30 chars';
 227
 228     $query = $schema->resultset('Artist')->search({
 229       'cds_very_very_very_long_relationship_name.title' => 'EP C'
 230     }, {
 231       prefetch => 'cds_very_very_very_long_relationship_name'
 232     });
 233
 234     lives_and {
 235       is $query->first->cds_very_very_very_long_relationship_name->first->cdid, 1
 236     } 'query with rel name over 30 chars and user condition survived and worked';
 237   }
 238
 239
 240 # test join with row count ambiguity
 241   my $cd = $schema->resultset('CD')->next;
 242   my $track = $cd->create_related('tracks', { position => 1, title => 'Track1'} );
 243   my $tjoin = $schema->resultset('Track')->search({ 'me.title' => 'Track1'}, {
 244     join => 'cd', rows => 2
 245   });
 246
 247   ok(my $row = $tjoin->next);
 248
 249   is($row->title, 'Track1', "ambiguous column ok");
 250
 251
 252
 253 # check count distinct with multiple columns
 254   my $other_track = $schema->resultset('Track')->create({ cd => $cd->cdid, position => 1, title => 'Track2' });
 255
 256   my $tcount = $schema->resultset('Track')->search(
 257     {},
 258     {
 259       select => [ qw/position title/ ],
 260       distinct => 1,
 261     }
 262   );
 263   is($tcount->count, 2, 'multiple column COUNT DISTINCT ok');
 264
 265   $tcount = $schema->resultset('Track')->search(
 266     {},
 267     {
 268       columns => [ qw/position title/ ],
 269       distinct => 1,
 270     }
 271   );
 272   is($tcount->count, 2, 'multiple column COUNT DISTINCT ok');
 273
 274   $tcount = $schema->resultset('Track')->search(
 275     {},
 276     {
 277       group_by => [ qw/position title/ ]
 278     }
 279   );
 280   is($tcount->count, 2, 'multiple column COUNT DISTINCT using column syntax ok');
 281
 282
 283 # check group_by
 284   my $g_rs = $schema->resultset('Track')->search( undef, { columns=>[qw/trackid position/], group_by=> [ qw/trackid position/ ] , rows => 2, offset => 1 });
 285   is( scalar $g_rs->all, 1, "Group by with limit OK" );
 286
 287
 288 # test with_deferred_fk_checks
 289   lives_ok {
 290     $schema->storage->with_deferred_fk_checks(sub {
 291       $schema->resultset('Track')->create({
 292         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 293       });
 294       $schema->resultset('CD')->create({
 295         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 296       });
 297     });
 298   } 'with_deferred_fk_checks code survived';
 299
 300   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 301     'code in with_deferred_fk_checks worked';
 302
 303   throws_ok {
 304     $schema->resultset('Track')->create({
 305       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 306     });
 307   } qr/constraint/i, 'with_deferred_fk_checks is off';
 308
 309
 310 # test auto increment using sequences WITHOUT triggers
 311   for (1..5) {
 312     my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 313     is($st->pkid1, $_, "Oracle Auto-PK without trigger: First primary key");
 314     is($st->pkid2, $_ + 9, "Oracle Auto-PK without trigger: Second primary key");
 315     is($st->nonpkid, $_ + 19, "Oracle Auto-PK without trigger: Non-primary key");
 316   }
 317   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 318   is($st->pkid1, 55, "Oracle Auto-PK without trigger: First primary key set manually");
 319
 320
 321 # test BLOBs
 322   SKIP: {
 323   TODO: {
 324     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 325     $binstr{'large'} = $binstr{'small'} x 1024;
 326
 327     my $maxloblen = length $binstr{'large'};
 328     note "Localizing LongReadLen to $maxloblen to avoid truncation of test data";
 329     local $dbh->{'LongReadLen'} = $maxloblen;
 330
 331     my $rs = $schema->resultset('BindType');
 332     my $id = 0;
 333
 334     if ($DBD::Oracle::VERSION eq '1.23') {
 335       throws_ok { $rs->create({ id => 1, blob => $binstr{large} }) }
 336         qr/broken/,
 337         'throws on blob insert with DBD::Oracle == 1.23';
 338
 339       skip 'buggy BLOB support in DBD::Oracle 1.23', 7;
 340     }
 341
 342     # disable BLOB mega-output
 343     my $orig_debug = $schema->storage->debug;
 344     $schema->storage->debug (0);
 345
 346     local $TODO = 'Something is confusing column bindtype assignment when quotes are active'
 347       if $q;
 348
 349     foreach my $type (qw( blob clob )) {
 350       foreach my $size (qw( small large )) {
 351         $id++;
 352
 353         lives_ok { $rs->create( { 'id' => $id, $type => $binstr{$size} } ) }
 354         "inserted $size $type without dying";
 355         ok($rs->find($id)->$type eq $binstr{$size}, "verified inserted $size $type" );
 356       }
 357     }
 358
 359     $schema->storage->debug ($orig_debug);
 360   }}
 361
 362 # test populate (identity, success and error handling)
 363   my $art_rs = $schema->resultset('Artist');
 364
 365   my $seq_pos = $art_rs->get_column('artistid')->max;
 366   ok($seq_pos, 'Starting with something in the artist table');
 367
 368
 369   my $pop_rs = $schema->resultset('Artist')->search(
 370     { name => { -like => 'pop_art_%' } },
 371     { order_by => 'artistid' }
 372   );
 373
 374   $art_rs->delete;
 375   lives_ok {
 376     $pop_rs->populate([
 377       map { +{ name => "pop_art_$_" } }
 378       (1,2,3)
 379     ]);
 380
 381     is_deeply (
 382       [ $pop_rs->get_column('artistid')->all ],
 383       [ map { $seq_pos + $_ } (1,2,3) ],
 384       'Sequence works after empty-table insertion'
 385     );
 386   } 'Populate without identity does not throw';
 387
 388   lives_ok {
 389     $pop_rs->populate([
 390       map { +{ artistid => $_, name => "pop_art_$_" } }
 391       (1,2,3)
 392     ]);
 393
 394     is_deeply (
 395       [ $pop_rs->get_column('artistid')->all ],
 396       [ 1,2,3, map { $seq_pos + $_ } (1,2,3) ],
 397       'Explicit id population works'
 398     );
 399   } 'Populate with identity does not throw';
 400
 401   throws_ok {
 402     $pop_rs->populate([
 403       map { +{ artistid => $_, name => "pop_art_$_" } }
 404       (200, 1, 300)
 405     ]);
 406   } qr/unique constraint.+populate slice.+name => "pop_art_1"/s, 'Partially failed populate throws';
 407
 408   is_deeply (
 409     [ $pop_rs->get_column('artistid')->all ],
 410     [ 1,2,3, map { $seq_pos + $_ } (1,2,3) ],
 411     'Partially failed populate did not alter table contents'
 412   );
 413
 414 # test sequence detection from a different schema
 415   SKIP: {
 416   TODO: {
 417     skip ((join '',
 418       'Set DBICTEST_ORA_EXTRAUSER_DSN, _USER and _PASS to a *DIFFERENT* Oracle user',
 419       ' to run the cross-schema sequence detection test.'),
 420     1) unless $dsn2 && $user2 && $user2 ne $user;
 421
 422     skip 'not detecting cross-schema sequence name when using INSERT ... RETURNING', 1
 423       if $schema->storage->_use_insert_returning;
 424
 425     # Oracle8i Reference Release 2 (8.1.6)
 426     #   http://download.oracle.com/docs/cd/A87860_01/doc/server.817/a76961/ch294.htm#993
 427     # Oracle Database Reference 10g Release 2 (10.2)
 428     #   http://download.oracle.com/docs/cd/B19306_01/server.102/b14237/statviews_2107.htm#sthref1297
 429     local $TODO = "On Oracle8i all_triggers view is empty, i don't yet know why..."
 430       if $schema->storage->_server_info->{normalized_dbms_version} < 9;
 431
 432     my $schema2 = $schema->connect($dsn2, $user2, $pass2, $opt);
 433     my $dbh2 = $schema2->storage->dbh;
 434
 435     # create identically named tables/sequences in the other schema
 436     do_creates($dbh2, $q);
 437
 438     # grand select privileges to the 2nd user
 439     $dbh->do("GRANT INSERT ON ${q}artist${q} TO " . uc $user2);
 440     $dbh->do("GRANT SELECT ON ${q}artist_pk_seq${q} TO " . uc $user2);
 441     $dbh->do("GRANT SELECT ON ${q}artist_autoinc_seq${q} TO " . uc $user2);
 442
 443     # test with a fully qualified table (user1/schema prepended)
 444     my $rs2 = $schema2->resultset('ArtistFQN');
 445     delete $rs2->result_source->column_info('artistid')->{sequence};
 446
 447     lives_and {
 448       my $row = $rs2->create({ name => 'From Different Schema' });
 449       ok $row->artistid;
 450     } 'used autoinc sequence across schemas';
 451
 452     # now quote the sequence name (do_creates always uses an lc name)
 453     my $q_seq = $q
 454       ? '"artist_pk_seq"'
 455       : '"ARTIST_PK_SEQ"'
 456     ;
 457     delete $rs2->result_source->column_info('artistid')->{sequence};
 458     $dbh->do(qq{
 459       CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_pk${q}
 460       BEFORE INSERT ON ${q}artist${q}
 461       FOR EACH ROW
 462       BEGIN
 463         IF :new.${q}artistid${q} IS NULL THEN
 464           SELECT $q_seq.nextval
 465           INTO :new.${q}artistid${q}
 466           FROM DUAL;
 467         END IF;
 468       END;
 469     });
 470
 471
 472     lives_and {
 473       my $row = $rs2->create({ name => 'From Different Schema With Quoted Sequence' });
 474       ok $row->artistid;
 475     } 'used quoted autoinc sequence across schemas';
 476
 477     is_deeply $rs2->result_source->column_info('artistid')->{sequence},
 478       \( (uc $user) . ".$q_seq"),
 479       'quoted sequence name correctly extracted';
 480
 481     # try an insert operation on the default user2 artist
 482     my $art1 = $schema->resultset('Artist');
 483     my $art2 = $schema2->resultset('Artist');
 484     my $art1_count = $art1->count || 0;
 485     my $art2_count = $art2->count;
 486
 487     is( $art2_count, 0, 'No artists created yet in second schema' );
 488
 489     delete $art2->result_source->column_info('artistid')->{sequence};
 490     my $new_art = $art2->create({ name => '2nd best' });
 491
 492     is ($art1->count, $art1_count, 'No new rows in main schema');
 493     is ($art2->count, 1, 'One artist create in 2nd schema');
 494
 495     is( $new_art->artistid, 1, 'Expected first PK' );
 496
 497     do_clean ($dbh2);
 498   }}
 499
 500   do_clean ($dbh);
 501 }
 502
 503 done_testing;
 504
 505 sub do_creates {
 506   my ($dbh, $q) = @_;
 507
 508   do_clean($dbh);
 509
 510   $dbh->do("CREATE SEQUENCE ${q}artist_autoinc_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 511   $dbh->do("CREATE SEQUENCE ${q}artist_pk_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 512   $dbh->do("CREATE SEQUENCE ${q}cd_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 513   $dbh->do("CREATE SEQUENCE ${q}track_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 514
 515   $dbh->do("CREATE SEQUENCE ${q}nonpkid_seq${q} START WITH 20 MAXVALUE 999999 MINVALUE 0");
 516   # this one is always quoted as per manually specified sequence =>
 517   $dbh->do('CREATE SEQUENCE "pkid1_seq" START WITH 1 MAXVALUE 999999 MINVALUE 0');
 518   # this one is always unquoted as per manually specified sequence =>
 519   $dbh->do("CREATE SEQUENCE pkid2_seq START WITH 10 MAXVALUE 999999 MINVALUE 0");
 520
 521   $dbh->do("CREATE TABLE ${q}artist${q} (${q}artistid${q} NUMBER(12), ${q}name${q} VARCHAR(255), ${q}autoinc_col${q} NUMBER(12), ${q}rank${q} NUMBER(38), ${q}charfield${q} VARCHAR2(10))");
 522   $dbh->do("ALTER TABLE ${q}artist${q} ADD (CONSTRAINT ${q}artist_pk${q} PRIMARY KEY (${q}artistid${q}))");
 523
 524   $dbh->do("CREATE TABLE ${q}sequence_test${q} (${q}pkid1${q} NUMBER(12), ${q}pkid2${q} NUMBER(12), ${q}nonpkid${q} NUMBER(12), ${q}name${q} VARCHAR(255))");
 525   $dbh->do("ALTER TABLE ${q}sequence_test${q} ADD (CONSTRAINT ${q}sequence_test_constraint${q} PRIMARY KEY (${q}pkid1${q}, ${q}pkid2${q}))");
 526
 527   # table cd will be unquoted => Oracle will see it as uppercase
 528   $dbh->do("CREATE TABLE cd (${q}cdid${q} NUMBER(12), ${q}artist${q} NUMBER(12), ${q}title${q} VARCHAR(255), ${q}year${q} VARCHAR(4), ${q}genreid${q} NUMBER(12), ${q}single_track${q} NUMBER(12))");
 529   $dbh->do("ALTER TABLE cd ADD (CONSTRAINT ${q}cd_pk${q} PRIMARY KEY (${q}cdid${q}))");
 530
 531   $dbh->do("CREATE TABLE ${q}track${q} (${q}trackid${q} NUMBER(12), ${q}cd${q} NUMBER(12) REFERENCES CD(${q}cdid${q}) DEFERRABLE, ${q}position${q} NUMBER(12), ${q}title${q} VARCHAR(255), ${q}last_updated_on${q} DATE, ${q}last_updated_at${q} DATE)");
 532   $dbh->do("ALTER TABLE ${q}track${q} ADD (CONSTRAINT ${q}track_pk${q} PRIMARY KEY (${q}trackid${q}))");
 533
 534   $dbh->do("CREATE TABLE ${q}bindtype_test${q} (${q}id${q} integer NOT NULL PRIMARY KEY, ${q}bytea${q} integer NULL, ${q}blob${q} blob NULL, ${q}clob${q} clob NULL)");
 535
 536   $dbh->do(qq{
 537     CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_auto${q}
 538     BEFORE INSERT ON ${q}artist${q}
 539     FOR EACH ROW
 540     BEGIN
 541       IF :new.${q}autoinc_col${q} IS NULL THEN
 542         SELECT ${q}artist_autoinc_seq${q}.nextval
 543         INTO :new.${q}autoinc_col${q}
 544         FROM DUAL;
 545       END IF;
 546     END;
 547   });
 548
 549   $dbh->do(qq{
 550     CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_pk${q}
 551     BEFORE INSERT ON ${q}artist${q}
 552     FOR EACH ROW
 553     BEGIN
 554       IF :new.${q}artistid${q} IS NULL THEN
 555         SELECT ${q}artist_pk_seq${q}.nextval
 556         INTO :new.${q}artistid${q}
 557         FROM DUAL;
 558       END IF;
 559     END;
 560   });
 561
 562   $dbh->do(qq{
 563     CREATE OR REPLACE TRIGGER ${q}cd_insert_trg${q}
 564     BEFORE INSERT OR UPDATE ON cd
 565     FOR EACH ROW
 566
 567     DECLARE
 568     tmpVar NUMBER;
 569
 570     BEGIN
 571       tmpVar := 0;
 572
 573       IF :new.${q}cdid${q} IS NULL THEN
 574         SELECT ${q}cd_seq${q}.nextval
 575         INTO tmpVar
 576         FROM dual;
 577
 578         :new.${q}cdid${q} := tmpVar;
 579       END IF;
 580     END;
 581   });
 582
 583   $dbh->do(qq{
 584     CREATE OR REPLACE TRIGGER ${q}track_insert_trg${q}
 585     BEFORE INSERT ON ${q}track${q}
 586     FOR EACH ROW
 587     BEGIN
 588       IF :new.${q}trackid${q} IS NULL THEN
 589         SELECT ${q}track_seq${q}.nextval
 590         INTO :new.${q}trackid${q}
 591         FROM DUAL;
 592       END IF;
 593     END;
 594   });
 595 }
 596
 597 # clean up our mess
 598 sub do_clean {
 599
 600   my $dbh = shift || return;
 601
 602   for my $q ('', '"') {
 603     my @clean = (
 604       "DROP TRIGGER ${q}track_insert_trg${q}",
 605       "DROP TRIGGER ${q}cd_insert_trg${q}",
 606       "DROP TRIGGER ${q}artist_insert_trg_auto${q}",
 607       "DROP TRIGGER ${q}artist_insert_trg_pk${q}",
 608       "DROP SEQUENCE ${q}nonpkid_seq${q}",
 609       "DROP SEQUENCE ${q}pkid2_seq${q}",
 610       "DROP SEQUENCE ${q}pkid1_seq${q}",
 611       "DROP SEQUENCE ${q}track_seq${q}",
 612       "DROP SEQUENCE ${q}cd_seq${q}",
 613       "DROP SEQUENCE ${q}artist_autoinc_seq${q}",
 614       "DROP SEQUENCE ${q}artist_pk_seq${q}",
 615       "DROP TABLE ${q}bindtype_test${q}",
 616       "DROP TABLE ${q}sequence_test${q}",
 617       "DROP TABLE ${q}track${q}",
 618       "DROP TABLE ${q}cd${q}",
 619       "DROP TABLE ${q}artist${q}",
 620     );
 621     eval { $dbh -> do ($_) } for @clean;
 622   }
 623 }
 624
 625 END {
 626   for ($dbh, $dbh2) {
 627     next unless $_;
 628     local $SIG{__WARN__} = sub {};
 629     do_clean($_);
 630     $_->disconnect;
 631   }
 632 }