t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  12
  13 plan skip_all => <<'EOM' unless $dsn && $user;
  14 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  15 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  16 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  17 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  18 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  19 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  28   {
  29     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  30
  31     ok (!$s->storage->_dbh, 'definitely not connected');
  32
  33     # Check that datetime_parser returns correctly before we explicitly connect.
  34     SKIP: {
  35         skip (
  36           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  37           2
  38         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  39
  40         my $store = ref $s->storage;
  41         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  42
  43         my $parser = $s->storage->datetime_parser;
  44         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  45     }
  46
  47     ok (!$s->storage->_dbh, 'still not connected');
  48   }
  49
  50   {
  51     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  52     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  53     ok (!$s->storage->_dbh, 'definitely not connected');
  54     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  55     ok (!$s->storage->_dbh, 'still not connected');
  56   }
  57
  58 # test LIMIT support
  59 {
  60   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  61   drop_test_schema($schema);
  62   create_test_schema($schema);
  63   for (1..6) {
  64     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  65   }
  66   my $it = $schema->resultset('Artist')->search( {},
  67     { rows => 3,
  68       offset => 2,
  69       order_by => 'artistid' }
  70   );
  71   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  72   is( $it->next->name, "Artist 3", "iterator->next ok" );
  73   $it->next;
  74   $it->next;
  75   $it->next;
  76   is( $it->next, undef, "next past end of resultset ok" );
  77
  78   # Limit with select-lock
  79   lives_ok {
  80     $schema->txn_do (sub {
  81       isa_ok (
  82         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  83         'DBICTest::Schema::Artist',
  84       );
  85     });
  86   } 'Limited FOR UPDATE select works';
  87 }
  88
  89 # check if we indeed do support stuff
  90 my $test_server_supports_insert_returning = do {
  91   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  92                    ->storage
  93                     ->_get_dbh
  94                      ->get_info(18);
  95   $v =~ /^(\d+)\.(\d+)/
  96     or die "Unparseable Pg server version: $v\n";
  97
  98   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
  99 };
 100 is (
 101   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 102   $test_server_supports_insert_returning,
 103   'insert returning capability guessed correctly'
 104 );
 105
 106 my $schema;
 107 for my $use_insert_returning ($test_server_supports_insert_returning
 108   ? (0,1)
 109   : (0)
 110 ) {
 111
 112   no warnings qw/once/;
 113   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 114     my $s = shift->next::method (@_);
 115     $s->storage->_use_insert_returning ($use_insert_returning);
 116     $s;
 117   };
 118
 119 ### test capability override
 120   {
 121     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 122
 123     ok (!$s->storage->_dbh, 'definitely not connected');
 124
 125     ok (
 126       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 127       'insert returning capability set correctly',
 128     );
 129     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 130   }
 131
 132 ### connect, create postgres-specific test schema
 133
 134   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 135   $schema->storage->ensure_connected;
 136
 137   drop_test_schema($schema);
 138   create_test_schema($schema);
 139
 140 ### begin main tests
 141
 142 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 143 # discovery
 144   run_apk_tests($schema); #< older set of auto-pk tests
 145   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 146
 147 ### type_info tests
 148
 149   my $test_type_info = {
 150       'artistid' => {
 151           'data_type' => 'integer',
 152           'is_nullable' => 0,
 153           'size' => 4,
 154       },
 155       'name' => {
 156           'data_type' => 'character varying',
 157           'is_nullable' => 1,
 158           'size' => 100,
 159           'default_value' => undef,
 160       },
 161       'rank' => {
 162           'data_type' => 'integer',
 163           'is_nullable' => 0,
 164           'size' => 4,
 165           'default_value' => 13,
 166
 167       },
 168       'charfield' => {
 169           'data_type' => 'character',
 170           'is_nullable' => 1,
 171           'size' => 10,
 172           'default_value' => undef,
 173       },
 174       'arrayfield' => {
 175           'data_type' => 'integer[]',
 176           'is_nullable' => 1,
 177           'size' => undef,
 178           'default_value' => undef,
 179       },
 180   };
 181
 182   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 183   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 184   like($artistid_defval,
 185        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 186        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 187   is_deeply($type_info, $test_type_info,
 188             'columns_info_for - column data types');
 189
 190
 191
 192
 193 ####### Array tests
 194
 195   BEGIN {
 196     package DBICTest::Schema::ArrayTest;
 197     push @main::test_classes, __PACKAGE__;
 198
 199     use strict;
 200     use warnings;
 201     use base 'DBIx::Class::Core';
 202
 203     __PACKAGE__->table('dbic_t_schema.array_test');
 204     __PACKAGE__->add_columns(qw/id arrayfield/);
 205     __PACKAGE__->column_info_from_storage(1);
 206     __PACKAGE__->set_primary_key('id');
 207
 208   }
 209   SKIP: {
 210     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 211
 212     lives_ok {
 213       $schema->resultset('ArrayTest')->create({
 214         arrayfield => [1, 2],
 215       });
 216     } 'inserting arrayref as pg array data';
 217
 218     lives_ok {
 219       $schema->resultset('ArrayTest')->update({
 220         arrayfield => [3, 4],
 221       });
 222     } 'updating arrayref as pg array data';
 223
 224     $schema->resultset('ArrayTest')->create({
 225       arrayfield => [5, 6],
 226     });
 227
 228     my $afield_rs = $schema->resultset('ArrayTest')->search({
 229       arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 230     });
 231
 232     my $count;
 233     lives_ok {
 234       $count = $afield_rs->count
 235     } 'comparing arrayref to pg array data does not blow up';
 236     is($count, 1, 'comparing arrayref to pg array data gives correct result');
 237
 238     TODO: {
 239       local $TODO = 'No introspection of scalarref conditions :(';
 240       my $row = $afield_rs->create({});
 241       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 242       $row->discard_changes;
 243       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 244     }
 245   }
 246
 247
 248
 249 ########## Case check
 250
 251   BEGIN {
 252     package DBICTest::Schema::Casecheck;
 253     push @main::test_classes, __PACKAGE__;
 254
 255     use strict;
 256     use warnings;
 257     use base 'DBIx::Class::Core';
 258
 259     __PACKAGE__->table('dbic_t_schema.casecheck');
 260     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 261     __PACKAGE__->column_info_from_storage(1);
 262     __PACKAGE__->set_primary_key('id');
 263   }
 264
 265   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 266   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 267
 268   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 269   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 270
 271   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 272   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 273
 274
 275 ## Test ResultSet->update
 276 my $artist = $schema->resultset('Artist')->first;
 277 my $cds = $artist->cds_unordered->search({
 278     year => { '!=' => 2010 }
 279 }, { prefetch => 'liner_notes' });
 280 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 281
 282 ## Test SELECT ... FOR UPDATE
 283
 284   SKIP: {
 285       if(eval { require Sys::SigAction }) {
 286           Sys::SigAction->import( 'set_sig_handler' );
 287       }
 288       else {
 289         skip "Sys::SigAction is not available", 6;
 290       }
 291
 292       my ($timed_out, $artist2);
 293
 294       for my $t (
 295         {
 296           # Make sure that an error was raised, and that the update failed
 297           update_lock => 1,
 298           test_sub => sub {
 299             ok($timed_out, "update from second schema times out");
 300             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 301           },
 302         },
 303         {
 304           # Make sure that an error was NOT raised, and that the update succeeded
 305           update_lock => 0,
 306           test_sub => sub {
 307             ok(! $timed_out, "update from second schema DOES NOT timeout");
 308             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 309           },
 310         },
 311       ) {
 312         # create a new schema
 313         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 314         $schema2->source("Artist")->name("dbic_t_schema.artist");
 315
 316         $schema->txn_do( sub {
 317           my $rs = $schema->resultset('Artist')->search(
 318               {
 319                   artistid => 1
 320               },
 321               $t->{update_lock} ? { for => 'update' } : {}
 322           );
 323           ok ($rs->count, 'Count works');
 324
 325           my $artist = $rs->next;
 326           is($artist->artistid, 1, "select returns artistid = 1");
 327
 328           $timed_out = 0;
 329           eval {
 330               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 331               alarm(2);
 332               $artist2 = $schema2->resultset('Artist')->find(1);
 333               $artist2->name('fooey');
 334               $artist2->update;
 335               alarm(0);
 336           };
 337           $timed_out = $@ =~ /DBICTestTimeout/;
 338         });
 339
 340         $t->{test_sub}->();
 341       }
 342   }
 343
 344
 345 ######## other older Auto-pk tests
 346
 347   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 348   for (1..5) {
 349       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 350       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 351       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 352       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 353   }
 354   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 355   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 356
 357
 358 ######## test non-serial auto-pk
 359
 360   if ($schema->storage->_use_insert_returning) {
 361     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 362     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 363     ok $row->id;
 364   }
 365
 366 ######## test with_deferred_fk_checks
 367
 368   $schema->source('CD')->name('dbic_t_schema.cd');
 369   $schema->source('Track')->name('dbic_t_schema.track');
 370   lives_ok {
 371     $schema->storage->with_deferred_fk_checks(sub {
 372       $schema->resultset('Track')->create({
 373         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 374       });
 375       $schema->resultset('CD')->create({
 376         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 377       });
 378     });
 379   } 'with_deferred_fk_checks code survived';
 380
 381   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 382      'code in with_deferred_fk_checks worked';
 383
 384   throws_ok {
 385     $schema->resultset('Track')->create({
 386       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 387     });
 388   } qr/constraint/i, 'with_deferred_fk_checks is off';
 389 }
 390
 391 done_testing;
 392
 393 END {
 394     return unless $schema;
 395     drop_test_schema($schema);
 396     eapk_drop_all( $schema)
 397 };
 398
 399
 400 ######### SUBROUTINES
 401
 402 sub create_test_schema {
 403     my $schema = shift;
 404     $schema->storage->dbh_do(sub {
 405       my (undef,$dbh) = @_;
 406
 407       local $dbh->{Warn} = 0;
 408
 409       my $std_artist_table = <<EOS;
 410 (
 411   artistid serial PRIMARY KEY
 412   , name VARCHAR(100)
 413   , rank INTEGER NOT NULL DEFAULT '13'
 414   , charfield CHAR(10)
 415   , arrayfield INTEGER[]
 416 )
 417 EOS
 418
 419       $dbh->do("CREATE SCHEMA dbic_t_schema");
 420       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 421
 422       $dbh->do(<<EOS);
 423 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 424   id timestamp default current_timestamp
 425 )
 426 EOS
 427       $dbh->do(<<EOS);
 428 CREATE TABLE dbic_t_schema.cd (
 429   cdid int PRIMARY KEY,
 430   artist int,
 431   title varchar(255),
 432   year varchar(4),
 433   genreid int,
 434   single_track int
 435 )
 436 EOS
 437       $dbh->do(<<EOS);
 438 CREATE TABLE dbic_t_schema.track (
 439   trackid int,
 440   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 441   position int,
 442   title varchar(255),
 443   last_updated_on date,
 444   last_updated_at date,
 445   small_dt date
 446 )
 447 EOS
 448
 449       $dbh->do(<<EOS);
 450 CREATE TABLE dbic_t_schema.sequence_test (
 451     pkid1 integer
 452     , pkid2 integer
 453     , nonpkid integer
 454     , name VARCHAR(100)
 455     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 456 )
 457 EOS
 458       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 459       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 460       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 461       $dbh->do(<<EOS);
 462 CREATE TABLE dbic_t_schema.casecheck (
 463     id serial PRIMARY KEY
 464     , "name" VARCHAR(1)
 465     , "NAME" VARCHAR(2)
 466     , "UC_NAME" VARCHAR(3)
 467 )
 468 EOS
 469       $dbh->do(<<EOS);
 470 CREATE TABLE dbic_t_schema.array_test (
 471     id serial PRIMARY KEY
 472     , arrayfield INTEGER[]
 473 )
 474 EOS
 475       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 476       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 477       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 478       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 479       $dbh->do('set search_path=dbic_t_schema,public');
 480       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 481       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 482       $dbh->do(<<EOS);
 483  CREATE TABLE dbic_t_schema_4.artist
 484  (
 485    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 486    , name VARCHAR(100)
 487    , rank INTEGER NOT NULL DEFAULT '13'
 488    , charfield CHAR(10)
 489    , arrayfield INTEGER[]
 490  );
 491 EOS
 492       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 493       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 494       $dbh->do(<<EOS);
 495  CREATE TABLE dbic_t_schema_5.artist
 496  (
 497    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 498    , name VARCHAR(100)
 499    , rank INTEGER NOT NULL DEFAULT '13'
 500    , charfield CHAR(10)
 501    , arrayfield INTEGER[]
 502  );
 503 EOS
 504       $dbh->do('set search_path=dbic_t_schema,public');
 505   });
 506 }
 507
 508
 509
 510 sub drop_test_schema {
 511     my ( $schema, $warn_exceptions ) = @_;
 512
 513     $schema->storage->dbh_do(sub {
 514         my (undef,$dbh) = @_;
 515
 516         local $dbh->{Warn} = 0;
 517
 518         for my $stat (
 519                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 520                       'DROP SEQUENCE public.artist_artistid_seq',
 521                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 522                       'DROP SCHEMA dbic_t_schema CASCADE',
 523                       'DROP SEQUENCE pkid1_seq',
 524                       'DROP SEQUENCE pkid2_seq',
 525                       'DROP SEQUENCE nonpkid_seq',
 526                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 527                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 528                      ) {
 529             eval { $dbh->do ($stat) };
 530             diag $@ if $@ && $warn_exceptions;
 531         }
 532     });
 533 }
 534
 535
 536 ###  auto-pk / last_insert_id / sequence discovery
 537 sub run_apk_tests {
 538     my $schema = shift;
 539
 540     # This is in Core now, but it's here just to test that it doesn't break
 541     $schema->class('Artist')->load_components('PK::Auto');
 542     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 543
 544     # test that auto-pk also works with the defined search path by
 545     # un-schema-qualifying the table name
 546     apk_t_set($schema,'artist');
 547
 548     my $unq_new;
 549     lives_ok {
 550         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 551     } 'insert into unqualified, shadowed table succeeds';
 552
 553     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 554
 555     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 556                          [qw| dbic_t_schema_3    1  |],
 557                          [qw| dbic_t_schema_4    2  |],
 558                          [qw| dbic_t_schema_5    1  |],
 559                        );
 560     foreach my $t ( @test_schemas ) {
 561         my ($sch_name, $start_num) = @$t;
 562         #test with dbic_t_schema_2
 563         apk_t_set($schema,"$sch_name.artist");
 564         my $another_new;
 565         lives_ok {
 566             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 567             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 568                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 569         } "$sch_name liid 1 did not die"
 570             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 571         lives_ok {
 572             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 573             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 574                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 575         } "$sch_name liid 2 did not die"
 576             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 577
 578     }
 579
 580     lives_ok {
 581         apk_t_set($schema,'dbic_t_schema.artist');
 582         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 583         is($new->artistid, 4, "Auto-PK worked");
 584         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 585         is($new->artistid, 5, "Auto-PK worked");
 586     } 'old auto-pk tests did not die either';
 587 }
 588
 589 # sets the artist table name and clears sequence name cache
 590 sub apk_t_set {
 591     my ( $s, $n ) = @_;
 592     $s->source("Artist")->name($n);
 593     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 594 }
 595
 596
 597 ######## EXTENDED AUTO-PK TESTS
 598
 599 my @eapk_id_columns;
 600 BEGIN {
 601   package DBICTest::Schema::ExtAPK;
 602   push @main::test_classes, __PACKAGE__;
 603
 604   use strict;
 605   use warnings;
 606   use base 'DBIx::Class::Core';
 607
 608   __PACKAGE__->table('apk');
 609
 610   @eapk_id_columns = qw( id1 id2 id3 id4 );
 611   __PACKAGE__->add_columns(
 612     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 613        @eapk_id_columns
 614   );
 615
 616   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 617                                        #the primary key
 618 }
 619
 620 my @eapk_schemas;
 621 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 622 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 623
 624 sub run_extended_apk_tests {
 625   my $schema = shift;
 626
 627   #save the search path and reset it at the end
 628   my $search_path_save = eapk_get_search_path($schema);
 629
 630   eapk_drop_all($schema);
 631   %seqs = ();
 632
 633   # make the test schemas and sequences
 634   $schema->storage->dbh_do(sub {
 635     my ( undef, $dbh ) = @_;
 636
 637     $dbh->do("CREATE SCHEMA $_")
 638         for @eapk_schemas;
 639
 640     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 641     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 642     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 643
 644     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 645     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 646     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 647
 648     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 649     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 650     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 651
 652     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 653   });
 654
 655   # clear our search_path cache
 656   $schema->storage->{_pg_search_path} = undef;
 657
 658   eapk_create( $schema,
 659                with_search_path => [0,1],
 660              );
 661   eapk_create( $schema,
 662                with_search_path => [1,0,'public'],
 663                nextval => "$eapk_schemas[5].fooseq",
 664              );
 665   eapk_create( $schema,
 666                with_search_path => ['public',0,1],
 667                qualify_table => 2,
 668              );
 669   eapk_create( $schema,
 670                with_search_path => [3,1,0,'public'],
 671                nextval => "$eapk_schemas[4].fooseq",
 672              );
 673   eapk_create( $schema,
 674                with_search_path => [3,1,0,'public'],
 675                nextval => "$eapk_schemas[3].fooseq",
 676                qualify_table => 4,
 677              );
 678
 679   eapk_poke( $schema );
 680   eapk_poke( $schema, 0 );
 681   eapk_poke( $schema, 2 );
 682   eapk_poke( $schema, 4 );
 683   eapk_poke( $schema, 1 );
 684   eapk_poke( $schema, 0 );
 685   eapk_poke( $schema, 1 );
 686   eapk_poke( $schema );
 687   eapk_poke( $schema, 4 );
 688   eapk_poke( $schema, 3 );
 689   eapk_poke( $schema, 1 );
 690   eapk_poke( $schema, 2 );
 691   eapk_poke( $schema, 0 );
 692
 693   # set our search path back
 694   eapk_set_search_path( $schema, @$search_path_save );
 695 }
 696
 697 # do a DBIC create on the apk table in the given schema number (which is an
 698 # index of @eapk_schemas)
 699
 700 sub eapk_poke {
 701   my ($s, $schema_num) = @_;
 702
 703   my $schema_name = defined $schema_num
 704       ? $eapk_schemas[$schema_num]
 705       : '';
 706
 707   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 708
 709   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 710   #< clear sequence name cache
 711   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 712       for @eapk_id_columns;
 713
 714   no warnings 'uninitialized';
 715   lives_ok {
 716     my $new;
 717     for my $inc (1,2,3) {
 718       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 719       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 720       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 721           or eapk_seq_diag($s,$schema_name);
 722       $new->discard_changes;
 723       is( $new->id1, 1 );
 724       for my $id ('id3','id4') {
 725         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 726         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 727             or eapk_seq_diag($s,$schema_name);
 728       }
 729     }
 730   } "create in schema '$schema_name' lives"
 731       or eapk_seq_diag($s,$schema_name);
 732 }
 733
 734 # print diagnostic info on which sequences were found in the ExtAPK
 735 # class
 736 sub eapk_seq_diag {
 737     my $s = shift;
 738     my $schema = shift || eapk_find_visible_schema($s);
 739
 740     diag "$schema.apk sequences: ",
 741         join(', ',
 742              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 743              @eapk_id_columns
 744             );
 745 }
 746
 747 # get the postgres search path as an arrayref
 748 sub eapk_get_search_path {
 749     my ( $s ) = @_;
 750     # cache the search path as ['schema','schema',...] in the storage
 751     # obj
 752
 753     return $s->storage->dbh_do(sub {
 754         my (undef, $dbh) = @_;
 755         my @search_path;
 756         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 757         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 758             unless( defined $1 and length $1 ) {
 759                 die "search path sanity check failed: '$1'";
 760             }
 761             push @search_path, $1;
 762         }
 763         \@search_path
 764     });
 765 }
 766 sub eapk_set_search_path {
 767     my ($s,@sp) = @_;
 768     my $sp = join ',',@sp;
 769     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 770 }
 771
 772 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 773 sub eapk_create {
 774     my ($schema, %a) = @_;
 775
 776     $schema->storage->dbh_do(sub {
 777         my (undef,$dbh) = @_;
 778
 779         my $searchpath_save;
 780         if ( $a{with_search_path} ) {
 781             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 782
 783             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 784
 785             $dbh->do("SET search_path = $search_path");
 786         }
 787
 788         my $table_name = $a{qualify_table}
 789             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 790             : 'apk';
 791         local $_[1]->{Warn} = 0;
 792
 793         my $id_def = $a{nextval}
 794             ? "integer not null default nextval('$a{nextval}'::regclass)"
 795             : 'serial';
 796         $dbh->do(<<EOS);
 797 CREATE TABLE $table_name (
 798   id1 serial
 799   , id2 $id_def
 800   , id3 serial primary key
 801   , id4 serial
 802 )
 803 EOS
 804
 805         if( $searchpath_save ) {
 806             $dbh->do("SET search_path = $searchpath_save");
 807         }
 808     });
 809 }
 810
 811 sub eapk_drop_all {
 812     my ( $schema, $warn_exceptions ) = @_;
 813
 814     $schema->storage->dbh_do(sub {
 815         my (undef,$dbh) = @_;
 816
 817         local $dbh->{Warn} = 0;
 818
 819         # drop the test schemas
 820         for (@eapk_schemas ) {
 821             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 822             diag $@ if $@ && $warn_exceptions;
 823         }
 824
 825
 826     });
 827 }
 828
 829 sub eapk_find_visible_schema {
 830     my ($s) = @_;
 831
 832     my ($schema) =
 833         $s->storage->dbh_do(sub {
 834             $_[1]->selectrow_array(<<EOS);
 835 SELECT n.nspname
 836 FROM pg_catalog.pg_namespace n
 837 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 838 WHERE c.relname = 'apk'
 839   AND pg_catalog.pg_table_is_visible(c.oid)
 840 EOS
 841         });
 842     return $schema;
 843 }