t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  11
  12 plan skip_all => <<EOM unless $dsn && $user;
  13 Set \$ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  14 ( NOTE: This test drops and creates tables called 'artist', 'casecheck',
  15   'array_test' and 'sequence_test' as well as following sequences:
  16   'pkid1_seq', 'pkid2_seq' and 'nonpkid_seq''.  as well as following
  17   schemas: 'dbic_t_schema', 'dbic_t_schema_2', 'dbic_t_schema_3',
  18   'dbic_t_schema_4', and 'dbic_t_schema_5'
  19 )
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27
  28 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  29 {
  30   my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  31
  32   ok (!$s->storage->_dbh, 'definitely not connected');
  33
  34   # Check that datetime_parser returns correctly before we explicitly connect.
  35   SKIP: {
  36       eval { require DateTime::Format::Pg };
  37       skip "DateTime::Format::Pg required", 2 if $@;
  38
  39       my $store = ref $s->storage;
  40       is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  41
  42       my $parser = $s->storage->datetime_parser;
  43       is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  44   }
  45
  46   ok (!$s->storage->_dbh, 'still not connected');
  47 }
  48 {
  49   my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  50   # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  51   ok (!$s->storage->_dbh, 'definitely not connected');
  52   is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  53   ok (!$s->storage->_dbh, 'still not connected');
  54 }
  55
  56 ### connect, create postgres-specific test schema
  57
  58 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  59
  60 drop_test_schema($schema);
  61 create_test_schema($schema);
  62
  63 ### begin main tests
  64
  65
  66 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
  67 # discovery
  68 run_apk_tests($schema); #< older set of auto-pk tests
  69 run_extended_apk_tests($schema); #< new extended set of auto-pk tests
  70
  71
  72
  73
  74
  75 ### type_info tests
  76
  77 my $test_type_info = {
  78     'artistid' => {
  79         'data_type' => 'integer',
  80         'is_nullable' => 0,
  81         'size' => 4,
  82     },
  83     'name' => {
  84         'data_type' => 'character varying',
  85         'is_nullable' => 1,
  86         'size' => 100,
  87         'default_value' => undef,
  88     },
  89     'rank' => {
  90         'data_type' => 'integer',
  91         'is_nullable' => 0,
  92         'size' => 4,
  93         'default_value' => 13,
  94
  95     },
  96     'charfield' => {
  97         'data_type' => 'character',
  98         'is_nullable' => 1,
  99         'size' => 10,
 100         'default_value' => undef,
 101     },
 102     'arrayfield' => {
 103         'data_type' => 'integer[]',
 104         'is_nullable' => 1,
 105         'size' => undef,
 106         'default_value' => undef,
 107     },
 108 };
 109
 110 my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 111 my $artistid_defval = delete $type_info->{artistid}->{default_value};
 112 like($artistid_defval,
 113      qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 114      'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 115 is_deeply($type_info, $test_type_info,
 116           'columns_info_for - column data types');
 117
 118
 119
 120
 121 ####### Array tests
 122
 123 BEGIN {
 124   package DBICTest::Schema::ArrayTest;
 125   push @main::test_classes, __PACKAGE__;
 126
 127   use strict;
 128   use warnings;
 129   use base 'DBIx::Class::Core';
 130
 131   __PACKAGE__->table('dbic_t_schema.array_test');
 132   __PACKAGE__->add_columns(qw/id arrayfield/);
 133   __PACKAGE__->column_info_from_storage(1);
 134   __PACKAGE__->set_primary_key('id');
 135
 136 }
 137 SKIP: {
 138   skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 139
 140   lives_ok {
 141     $schema->resultset('ArrayTest')->create({
 142       arrayfield => [1, 2],
 143     });
 144   } 'inserting arrayref as pg array data';
 145
 146   lives_ok {
 147     $schema->resultset('ArrayTest')->update({
 148       arrayfield => [3, 4],
 149     });
 150   } 'updating arrayref as pg array data';
 151
 152   $schema->resultset('ArrayTest')->create({
 153     arrayfield => [5, 6],
 154   });
 155
 156   my $count;
 157   lives_ok {
 158     $count = $schema->resultset('ArrayTest')->search({
 159       arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 160     })->count;
 161   } 'comparing arrayref to pg array data does not blow up';
 162   is($count, 1, 'comparing arrayref to pg array data gives correct result');
 163 }
 164
 165
 166
 167 ########## Case check
 168
 169 BEGIN {
 170   package DBICTest::Schema::Casecheck;
 171   push @main::test_classes, __PACKAGE__;
 172
 173   use strict;
 174   use warnings;
 175   use base 'DBIx::Class::Core';
 176
 177   __PACKAGE__->table('dbic_t_schema.casecheck');
 178   __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 179   __PACKAGE__->column_info_from_storage(1);
 180   __PACKAGE__->set_primary_key('id');
 181 }
 182
 183 my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 184 is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 185
 186 my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 187 is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 188
 189 my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 190 is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 191
 192
 193
 194
 195 ## Test SELECT ... FOR UPDATE
 196
 197 SKIP: {
 198     if(eval "require Sys::SigAction" && !$@) {
 199         Sys::SigAction->import( 'set_sig_handler' );
 200     }
 201     else {
 202       skip "Sys::SigAction is not available", 6;
 203     }
 204
 205     my ($timed_out, $artist2);
 206
 207     for my $t (
 208       {
 209         # Make sure that an error was raised, and that the update failed
 210         update_lock => 1,
 211         test_sub => sub {
 212           ok($timed_out, "update from second schema times out");
 213           ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 214         },
 215       },
 216       {
 217         # Make sure that an error was NOT raised, and that the update succeeded
 218         update_lock => 0,
 219         test_sub => sub {
 220           ok(! $timed_out, "update from second schema DOES NOT timeout");
 221           ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 222         },
 223       },
 224     ) {
 225       # create a new schema
 226       my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 227       $schema2->source("Artist")->name("dbic_t_schema.artist");
 228
 229       $schema->txn_do( sub {
 230         my $artist = $schema->resultset('Artist')->search(
 231             {
 232                 artistid => 1
 233             },
 234             $t->{update_lock} ? { for => 'update' } : {}
 235         )->first;
 236         is($artist->artistid, 1, "select returns artistid = 1");
 237
 238         $timed_out = 0;
 239         eval {
 240             my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 241             alarm(2);
 242             $artist2 = $schema2->resultset('Artist')->find(1);
 243             $artist2->name('fooey');
 244             $artist2->update;
 245             alarm(0);
 246         };
 247         $timed_out = $@ =~ /DBICTestTimeout/;
 248       });
 249
 250       $t->{test_sub}->();
 251     }
 252 }
 253
 254
 255 ######## other older Auto-pk tests
 256
 257 $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 258 for (1..5) {
 259     my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 260     is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 261     is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 262     is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 263 }
 264 my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 265 is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 266
 267
 268 ######## test non-integer non-serial auto-pk
 269
 270 $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 271 my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 272 ok $row->id;
 273
 274 done_testing;
 275
 276 exit;
 277
 278 END {
 279     return unless $schema;
 280     drop_test_schema($schema);
 281     eapk_drop_all( $schema)
 282 };
 283
 284
 285 ######### SUBROUTINES
 286
 287 sub create_test_schema {
 288     my $schema = shift;
 289     $schema->storage->dbh_do(sub {
 290       my (undef,$dbh) = @_;
 291
 292       local $dbh->{Warn} = 0;
 293
 294       my $std_artist_table = <<EOS;
 295 (
 296   artistid serial PRIMARY KEY
 297   , name VARCHAR(100)
 298   , rank INTEGER NOT NULL DEFAULT '13'
 299   , charfield CHAR(10)
 300   , arrayfield INTEGER[]
 301 )
 302 EOS
 303
 304       $dbh->do("CREATE SCHEMA dbic_t_schema");
 305       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 306
 307       $dbh->do(<<EOS);
 308 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 309     id timestamp default current_timestamp
 310 )
 311 EOS
 312       $dbh->do(<<EOS);
 313 CREATE TABLE dbic_t_schema.sequence_test (
 314     pkid1 integer
 315     , pkid2 integer
 316     , nonpkid integer
 317     , name VARCHAR(100)
 318     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 319 )
 320 EOS
 321       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 322       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 323       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 324       $dbh->do(<<EOS);
 325 CREATE TABLE dbic_t_schema.casecheck (
 326     id serial PRIMARY KEY
 327     , "name" VARCHAR(1)
 328     , "NAME" VARCHAR(2)
 329     , "UC_NAME" VARCHAR(3)
 330 )
 331 EOS
 332       $dbh->do(<<EOS);
 333 CREATE TABLE dbic_t_schema.array_test (
 334     id serial PRIMARY KEY
 335     , arrayfield INTEGER[]
 336 )
 337 EOS
 338       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 339       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 340       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 341       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 342       $dbh->do('set search_path=dbic_t_schema,public');
 343       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 344       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 345       $dbh->do(<<EOS);
 346  CREATE TABLE dbic_t_schema_4.artist
 347  (
 348    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 349    , name VARCHAR(100)
 350    , rank INTEGER NOT NULL DEFAULT '13'
 351    , charfield CHAR(10)
 352    , arrayfield INTEGER[]
 353  );
 354 EOS
 355       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 356       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 357       $dbh->do(<<EOS);
 358  CREATE TABLE dbic_t_schema_5.artist
 359  (
 360    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 361    , name VARCHAR(100)
 362    , rank INTEGER NOT NULL DEFAULT '13'
 363    , charfield CHAR(10)
 364    , arrayfield INTEGER[]
 365  );
 366 EOS
 367       $dbh->do('set search_path=dbic_t_schema,public');
 368   });
 369 }
 370
 371
 372
 373 sub drop_test_schema {
 374     my ( $schema, $warn_exceptions ) = @_;
 375
 376     $schema->storage->dbh_do(sub {
 377         my (undef,$dbh) = @_;
 378
 379         local $dbh->{Warn} = 0;
 380
 381         for my $stat (
 382                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 383                       'DROP SEQUENCE public.artist_artistid_seq',
 384                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 385                       'DROP SCHEMA dbic_t_schema CASCADE',
 386                       'DROP SEQUENCE pkid1_seq',
 387                       'DROP SEQUENCE pkid2_seq',
 388                       'DROP SEQUENCE nonpkid_seq',
 389                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 390                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 391                      ) {
 392             eval { $dbh->do ($stat) };
 393             diag $@ if $@ && $warn_exceptions;
 394         }
 395     });
 396 }
 397
 398
 399 ###  auto-pk / last_insert_id / sequence discovery
 400 sub run_apk_tests {
 401     my $schema = shift;
 402
 403     # This is in Core now, but it's here just to test that it doesn't break
 404     $schema->class('Artist')->load_components('PK::Auto');
 405     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 406
 407     # test that auto-pk also works with the defined search path by
 408     # un-schema-qualifying the table name
 409     apk_t_set($schema,'artist');
 410
 411     my $unq_new;
 412     lives_ok {
 413         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 414     } 'insert into unqualified, shadowed table succeeds';
 415
 416     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 417
 418     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 419                          [qw| dbic_t_schema_3    1  |],
 420                          [qw| dbic_t_schema_4    2  |],
 421                          [qw| dbic_t_schema_5    1  |],
 422                        );
 423     foreach my $t ( @test_schemas ) {
 424         my ($sch_name, $start_num) = @$t;
 425         #test with dbic_t_schema_2
 426         apk_t_set($schema,"$sch_name.artist");
 427         my $another_new;
 428         lives_ok {
 429             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 430             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 431                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 432         } "$sch_name liid 1 did not die"
 433             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 434         lives_ok {
 435             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 436             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 437                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 438         } "$sch_name liid 2 did not die"
 439             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 440
 441     }
 442
 443     lives_ok {
 444         apk_t_set($schema,'dbic_t_schema.artist');
 445         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 446         is($new->artistid, 4, "Auto-PK worked");
 447         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 448         is($new->artistid, 5, "Auto-PK worked");
 449     } 'old auto-pk tests did not die either';
 450 }
 451
 452 # sets the artist table name and clears sequence name cache
 453 sub apk_t_set {
 454     my ( $s, $n ) = @_;
 455     $s->source("Artist")->name($n);
 456     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 457 }
 458
 459
 460 ######## EXTENDED AUTO-PK TESTS
 461
 462 my @eapk_id_columns;
 463 BEGIN {
 464   package DBICTest::Schema::ExtAPK;
 465   push @main::test_classes, __PACKAGE__;
 466
 467   use strict;
 468   use warnings;
 469   use base 'DBIx::Class::Core';
 470
 471   __PACKAGE__->table('apk');
 472
 473   @eapk_id_columns = qw( id1 id2 id3 id4 );
 474   __PACKAGE__->add_columns(
 475     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 476        @eapk_id_columns
 477   );
 478
 479   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 480                                        #the primary key
 481 }
 482
 483 my @eapk_schemas;
 484 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 485 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 486
 487 sub run_extended_apk_tests {
 488   my $schema = shift;
 489
 490   #save the search path and reset it at the end
 491   my $search_path_save = eapk_get_search_path($schema);
 492
 493   eapk_drop_all($schema);
 494
 495   # make the test schemas and sequences
 496   $schema->storage->dbh_do(sub {
 497     my ( undef, $dbh ) = @_;
 498
 499     $dbh->do("CREATE SCHEMA $_")
 500         for @eapk_schemas;
 501
 502     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 503     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 504     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 505
 506     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 507     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 508     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 509
 510     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 511     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 512     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 513
 514     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 515   });
 516
 517   # clear our search_path cache
 518   $schema->storage->{_pg_search_path} = undef;
 519
 520   eapk_create( $schema,
 521                with_search_path => [0,1],
 522              );
 523   eapk_create( $schema,
 524                with_search_path => [1,0,'public'],
 525                nextval => "$eapk_schemas[5].fooseq",
 526              );
 527   eapk_create( $schema,
 528                with_search_path => ['public',0,1],
 529                qualify_table => 2,
 530              );
 531   eapk_create( $schema,
 532                with_search_path => [3,1,0,'public'],
 533                nextval => "$eapk_schemas[4].fooseq",
 534              );
 535   eapk_create( $schema,
 536                with_search_path => [3,1,0,'public'],
 537                nextval => "$eapk_schemas[3].fooseq",
 538                qualify_table => 4,
 539              );
 540
 541   eapk_poke( $schema );
 542   eapk_poke( $schema, 0 );
 543   eapk_poke( $schema, 2 );
 544   eapk_poke( $schema, 4 );
 545   eapk_poke( $schema, 1 );
 546   eapk_poke( $schema, 0 );
 547   eapk_poke( $schema, 1 );
 548   eapk_poke( $schema );
 549   eapk_poke( $schema, 4 );
 550   eapk_poke( $schema, 3 );
 551   eapk_poke( $schema, 1 );
 552   eapk_poke( $schema, 2 );
 553   eapk_poke( $schema, 0 );
 554
 555   # set our search path back
 556   eapk_set_search_path( $schema, @$search_path_save );
 557 }
 558
 559 # do a DBIC create on the apk table in the given schema number (which is an
 560 # index of @eapk_schemas)
 561
 562 sub eapk_poke {
 563   my ($s, $schema_num) = @_;
 564
 565   my $schema_name = defined $schema_num
 566       ? $eapk_schemas[$schema_num]
 567       : '';
 568
 569   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 570
 571   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 572   #< clear sequence name cache
 573   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 574       for @eapk_id_columns;
 575
 576   no warnings 'uninitialized';
 577   lives_ok {
 578     my $new;
 579     for my $inc (1,2,3) {
 580       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 581       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 582       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 583           or eapk_seq_diag($s,$schema_name);
 584       $new->discard_changes;
 585       is( $new->id1, 1 );
 586       for my $id ('id3','id4') {
 587         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 588         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 589             or eapk_seq_diag($s,$schema_name);
 590       }
 591     }
 592   } "create in schema '$schema_name' lives"
 593       or eapk_seq_diag($s,$schema_name);
 594 }
 595
 596 # print diagnostic info on which sequences were found in the ExtAPK
 597 # class
 598 sub eapk_seq_diag {
 599     my $s = shift;
 600     my $schema = shift || eapk_find_visible_schema($s);
 601
 602     diag "$schema.apk sequences: ",
 603         join(', ',
 604              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 605              @eapk_id_columns
 606             );
 607 }
 608
 609 # get the postgres search path as an arrayref
 610 sub eapk_get_search_path {
 611     my ( $s ) = @_;
 612     # cache the search path as ['schema','schema',...] in the storage
 613     # obj
 614
 615     return $s->storage->dbh_do(sub {
 616         my (undef, $dbh) = @_;
 617         my @search_path;
 618         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 619         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 620             unless( defined $1 and length $1 ) {
 621                 die "search path sanity check failed: '$1'";
 622             }
 623             push @search_path, $1;
 624         }
 625         \@search_path
 626     });
 627 }
 628 sub eapk_set_search_path {
 629     my ($s,@sp) = @_;
 630     my $sp = join ',',@sp;
 631     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 632 }
 633
 634 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 635 sub eapk_create {
 636     my ($schema, %a) = @_;
 637
 638     $schema->storage->dbh_do(sub {
 639         my (undef,$dbh) = @_;
 640
 641         my $searchpath_save;
 642         if ( $a{with_search_path} ) {
 643             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 644
 645             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 646
 647             $dbh->do("SET search_path = $search_path");
 648         }
 649
 650         my $table_name = $a{qualify_table}
 651             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 652             : 'apk';
 653         local $_[1]->{Warn} = 0;
 654
 655         my $id_def = $a{nextval}
 656             ? "integer not null default nextval('$a{nextval}'::regclass)"
 657             : 'serial';
 658         $dbh->do(<<EOS);
 659 CREATE TABLE $table_name (
 660   id1 serial
 661   , id2 $id_def
 662   , id3 serial primary key
 663   , id4 serial
 664 )
 665 EOS
 666
 667         if( $searchpath_save ) {
 668             $dbh->do("SET search_path = $searchpath_save");
 669         }
 670     });
 671 }
 672
 673 sub eapk_drop_all {
 674     my ( $schema, $warn_exceptions ) = @_;
 675
 676     $schema->storage->dbh_do(sub {
 677         my (undef,$dbh) = @_;
 678
 679         local $dbh->{Warn} = 0;
 680
 681         # drop the test schemas
 682         for (@eapk_schemas ) {
 683             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 684             diag $@ if $@ && $warn_exceptions;
 685         }
 686
 687
 688     });
 689 }
 690
 691 sub eapk_find_visible_schema {
 692     my ($s) = @_;
 693
 694     my ($schema) =
 695         $s->storage->dbh_do(sub {
 696             $_[1]->selectrow_array(<<EOS);
 697 SELECT n.nspname
 698 FROM pg_catalog.pg_namespace n
 699 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 700 WHERE c.relname = 'apk'
 701   AND pg_catalog.pg_table_is_visible(c.oid)
 702 EOS
 703         });
 704     return $schema;
 705 }