t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10 use SQL::Abstract 'is_literal_value';
  11
  12 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  13   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  14
  15 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  16
  17 plan skip_all => <<'EOM' unless $dsn && $user;
  18 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  19 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  20 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  21 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  22 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  23 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  24 EOM
  25
  26 ### load any test classes that are defined further down in the file via BEGIN blocks
  27
  28 our @test_classes; #< array that will be pushed into by test classes defined in this file
  29 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  30
  31 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  32   {
  33     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  34
  35     ok (!$s->storage->_dbh, 'definitely not connected');
  36
  37     # Check that datetime_parser returns correctly before we explicitly connect.
  38     SKIP: {
  39         skip (
  40           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  41           2
  42         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  43
  44         my $store = ref $s->storage;
  45         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  46
  47         my $parser = $s->storage->datetime_parser;
  48         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  49     }
  50
  51     ok (!$s->storage->_dbh, 'still not connected');
  52   }
  53
  54   {
  55     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  56     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  57     ok (!$s->storage->_dbh, 'definitely not connected');
  58     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  59     ok (!$s->storage->_dbh, 'still not connected');
  60   }
  61
  62 # test LIMIT support
  63 {
  64   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  65   drop_test_schema($schema);
  66   create_test_schema($schema);
  67   for (1..6) {
  68     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  69   }
  70   my $it = $schema->resultset('Artist')->search( {},
  71     { rows => 3,
  72       offset => 2,
  73       order_by => 'artistid' }
  74   );
  75   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  76   is( $it->next->name, "Artist 3", "iterator->next ok" );
  77   $it->next;
  78   $it->next;
  79   $it->next;
  80   is( $it->next, undef, "next past end of resultset ok" );
  81
  82   # Limit with select-lock
  83   lives_ok {
  84     $schema->txn_do (sub {
  85       isa_ok (
  86         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  87         'DBICTest::Schema::Artist',
  88       );
  89     });
  90   } 'Limited FOR UPDATE select works';
  91 }
  92
  93 # check if we indeed do support stuff
  94 my $test_server_supports_insert_returning = do {
  95
  96   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  97   die "Unparseable Pg server version: $si->{dbms_version}\n"
  98     unless $si->{normalized_dbms_version};
  99
 100   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 101 };
 102 is (
 103   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 104   $test_server_supports_insert_returning,
 105   'insert returning capability guessed correctly'
 106 );
 107
 108 my $schema;
 109 for my $use_insert_returning ($test_server_supports_insert_returning
 110   ? (0,1)
 111   : (0)
 112 ) {
 113
 114   no warnings qw/once redefine/;
 115   my $old_connection = DBICTest::Schema->can('connection');
 116   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 117     my $s = shift->$old_connection(@_);
 118     $s->storage->_use_insert_returning ($use_insert_returning);
 119     $s;
 120   };
 121
 122 ### test capability override
 123   {
 124     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 125
 126     ok (!$s->storage->_dbh, 'definitely not connected');
 127
 128     ok (
 129       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 130       'insert returning capability set correctly',
 131     );
 132     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 133   }
 134
 135 ### connect, create postgres-specific test schema
 136
 137   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 138   $schema->storage->ensure_connected;
 139
 140   drop_test_schema($schema);
 141   create_test_schema($schema);
 142
 143 ### begin main tests
 144
 145 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 146 # discovery
 147   run_apk_tests($schema); #< older set of auto-pk tests
 148   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 149
 150 ### type_info tests
 151
 152   my $test_type_info = {
 153       'artistid' => {
 154           'data_type' => 'integer',
 155           'is_nullable' => 0,
 156           'size' => 4,
 157       },
 158       'name' => {
 159           'data_type' => 'character varying',
 160           'is_nullable' => 1,
 161           'size' => 100,
 162           'default_value' => undef,
 163       },
 164       'rank' => {
 165           'data_type' => 'integer',
 166           'is_nullable' => 0,
 167           'size' => 4,
 168           'default_value' => 13,
 169
 170       },
 171       'charfield' => {
 172           'data_type' => 'character',
 173           'is_nullable' => 1,
 174           'size' => 10,
 175           'default_value' => undef,
 176       },
 177       'arrayfield' => {
 178           'data_type' => 'integer[]',
 179           'is_nullable' => 1,
 180           'size' => undef,
 181           'default_value' => undef,
 182       },
 183   };
 184
 185   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 186   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 187   like($artistid_defval,
 188        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 189        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 190   is_deeply($type_info, $test_type_info,
 191             'columns_info_for - column data types');
 192
 193
 194
 195
 196 ####### Array tests
 197
 198   BEGIN {
 199     package DBICTest::Schema::ArrayTest;
 200     push @main::test_classes, __PACKAGE__;
 201
 202     use strict;
 203     use warnings;
 204     use base 'DBICTest::BaseResult';
 205
 206     __PACKAGE__->table('dbic_t_schema.array_test');
 207     __PACKAGE__->add_columns(qw/id arrayfield/);
 208     __PACKAGE__->column_info_from_storage(1);
 209     __PACKAGE__->set_primary_key('id');
 210
 211   }
 212   SKIP: {
 213     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 214
 215     my $arr_rs = $schema->resultset('ArrayTest');
 216
 217     lives_ok {
 218       $arr_rs->create({
 219         arrayfield => [1, 2],
 220       });
 221     } 'inserting arrayref as pg array data';
 222
 223     lives_ok {
 224       $arr_rs->update({
 225         arrayfield => [3, 4],
 226       });
 227     } 'updating arrayref as pg array data';
 228
 229     $arr_rs->create({
 230       arrayfield => [5, 6],
 231     });
 232
 233     lives_ok {
 234       $schema->populate('ArrayTest', [
 235         [ qw/arrayfield/ ],
 236         [ [0,0]          ],
 237       ]);
 238     } 'inserting arrayref using void ctx populate';
 239
 240     # Search using arrays
 241     lives_ok {
 242       is_deeply (
 243         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 244         [3,4],
 245         'Array value matches'
 246       );
 247     } 'searching by arrayref';
 248
 249     lives_ok {
 250       is_deeply (
 251         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 252         [3,4],
 253         'Array value matches explicit equal'
 254       );
 255     } 'searching by arrayref (explicit equal sign)';
 256
 257     lives_ok {
 258       is_deeply (
 259         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 260         [3,4],
 261         'Array value matches greater than'
 262       );
 263     } 'searching by arrayref (greater than)';
 264
 265     lives_ok {
 266       is (
 267         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 268         1,
 269         'Greater than search found [5,6]',
 270       );
 271     } 'searching by arrayref (greater than)';
 272
 273     # Find using arrays
 274     lives_ok {
 275       is_deeply (
 276         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 277         [3,4],
 278         'Array value matches implicit equal'
 279       );
 280     } 'find by arrayref';
 281
 282     lives_ok {
 283       is_deeply (
 284         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 285         [3,4],
 286         'Array value matches explicit equal'
 287       );
 288     } 'find by arrayref (equal)';
 289
 290     # test inferred condition for creation
 291     for my $cond (
 292       { -value => [3,4] },
 293       \[ '= ?' => [arrayfield => [3, 4]] ],
 294     ) {
 295       local $TODO = 'No introspection of complex literal conditions :('
 296         if is_literal_value $cond;
 297
 298
 299       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 300
 301       my $row = $arr_rs_cond->create({});
 302       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 303       $row->discard_changes;
 304       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 305     }
 306   }
 307
 308 ########## Case check
 309
 310   BEGIN {
 311     package DBICTest::Schema::Casecheck;
 312     push @main::test_classes, __PACKAGE__;
 313
 314     use strict;
 315     use warnings;
 316     use base 'DBIx::Class::Core';
 317
 318     __PACKAGE__->table('dbic_t_schema.casecheck');
 319     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 320     __PACKAGE__->column_info_from_storage(1);
 321     __PACKAGE__->set_primary_key('id');
 322   }
 323
 324   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 325   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 326
 327   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 328   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 329
 330   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 331   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 332
 333
 334 ## Test ResultSet->update
 335 my $artist = $schema->resultset('Artist')->first;
 336 my $cds = $artist->cds_unordered->search({
 337     year => { '!=' => 2010 }
 338 }, { prefetch => 'liner_notes' });
 339 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 340
 341 ## Test SELECT ... FOR UPDATE
 342
 343   SKIP: {
 344       if(eval { require Sys::SigAction }) {
 345           Sys::SigAction->import( 'set_sig_handler' );
 346       }
 347       else {
 348         skip "Sys::SigAction is not available", 6;
 349       }
 350
 351       my ($timed_out, $artist2);
 352
 353       for my $t (
 354         {
 355           # Make sure that an error was raised, and that the update failed
 356           update_lock => 1,
 357           test_sub => sub {
 358             ok($timed_out, "update from second schema times out");
 359             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 360           },
 361         },
 362         {
 363           # Make sure that an error was NOT raised, and that the update succeeded
 364           update_lock => 0,
 365           test_sub => sub {
 366             ok(! $timed_out, "update from second schema DOES NOT timeout");
 367             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 368           },
 369         },
 370       ) {
 371         # create a new schema
 372         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 373         $schema2->source("Artist")->name("dbic_t_schema.artist");
 374
 375         $schema->txn_do( sub {
 376           my $rs = $schema->resultset('Artist')->search(
 377               {
 378                   artistid => 1
 379               },
 380               $t->{update_lock} ? { for => 'update' } : {}
 381           );
 382           ok ($rs->count, 'Count works');
 383
 384           my $artist = $rs->next;
 385           is($artist->artistid, 1, "select returns artistid = 1");
 386
 387           $timed_out = 0;
 388           eval {
 389               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 390               alarm(2);
 391               $artist2 = $schema2->resultset('Artist')->find(1);
 392               $artist2->name('fooey');
 393               $artist2->update;
 394               alarm(0);
 395           };
 396           $timed_out = $@ =~ /DBICTestTimeout/;
 397         });
 398
 399         $t->{test_sub}->();
 400       }
 401   }
 402
 403
 404 ######## other older Auto-pk tests
 405
 406   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 407   for (1..5) {
 408       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 409       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 410       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 411       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 412   }
 413   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 414   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 415
 416
 417 ######## test non-serial auto-pk
 418
 419   if ($schema->storage->_use_insert_returning) {
 420     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 421     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 422     ok $row->id;
 423   }
 424
 425 ######## test with_deferred_fk_checks
 426
 427   $schema->source('CD')->name('dbic_t_schema.cd');
 428   $schema->source('Track')->name('dbic_t_schema.track');
 429   lives_ok {
 430     $schema->storage->with_deferred_fk_checks(sub {
 431       $schema->resultset('Track')->create({
 432         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 433       });
 434       $schema->resultset('CD')->create({
 435         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 436       });
 437     });
 438   } 'with_deferred_fk_checks code survived';
 439
 440   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 441      'code in with_deferred_fk_checks worked';
 442
 443   throws_ok {
 444     $schema->resultset('Track')->create({
 445       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 446     });
 447   } qr/constraint/i, 'with_deferred_fk_checks is off';
 448 }
 449
 450 done_testing;
 451
 452 END {
 453     return unless $schema;
 454     drop_test_schema($schema);
 455     eapk_drop_all($schema);
 456     undef $schema;
 457 };
 458
 459
 460 ######### SUBROUTINES
 461
 462 sub create_test_schema {
 463     my $schema = shift;
 464     $schema->storage->dbh_do(sub {
 465       my (undef,$dbh) = @_;
 466
 467       local $dbh->{Warn} = 0;
 468
 469       my $std_artist_table = <<EOS;
 470 (
 471   artistid serial PRIMARY KEY
 472   , name VARCHAR(100)
 473   , rank INTEGER NOT NULL DEFAULT '13'
 474   , charfield CHAR(10)
 475   , arrayfield INTEGER[]
 476 )
 477 EOS
 478
 479       $dbh->do("CREATE SCHEMA dbic_t_schema");
 480       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 481
 482       $dbh->do(<<EOS);
 483 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 484   id timestamp default current_timestamp
 485 )
 486 EOS
 487       $dbh->do(<<EOS);
 488 CREATE TABLE dbic_t_schema.cd (
 489   cdid int PRIMARY KEY,
 490   artist int,
 491   title varchar(255),
 492   year varchar(4),
 493   genreid int,
 494   single_track int
 495 )
 496 EOS
 497       $dbh->do(<<EOS);
 498 CREATE TABLE dbic_t_schema.track (
 499   trackid int,
 500   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 501   position int,
 502   title varchar(255),
 503   last_updated_on date,
 504   last_updated_at date
 505 )
 506 EOS
 507
 508       $dbh->do(<<EOS);
 509 CREATE TABLE dbic_t_schema.sequence_test (
 510     pkid1 integer
 511     , pkid2 integer
 512     , nonpkid integer
 513     , name VARCHAR(100)
 514     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 515 )
 516 EOS
 517       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 518       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 519       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 520       $dbh->do(<<EOS);
 521 CREATE TABLE dbic_t_schema.casecheck (
 522     id serial PRIMARY KEY
 523     , "name" VARCHAR(1)
 524     , "NAME" VARCHAR(2)
 525     , "UC_NAME" VARCHAR(3)
 526 )
 527 EOS
 528       $dbh->do(<<EOS);
 529 CREATE TABLE dbic_t_schema.array_test (
 530     id serial PRIMARY KEY
 531     , arrayfield INTEGER[]
 532 )
 533 EOS
 534       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 535       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 536       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 537       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 538       $dbh->do('set search_path=dbic_t_schema,public');
 539       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 540       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 541       $dbh->do(<<EOS);
 542  CREATE TABLE dbic_t_schema_4.artist
 543  (
 544    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 545    , name VARCHAR(100)
 546    , rank INTEGER NOT NULL DEFAULT '13'
 547    , charfield CHAR(10)
 548    , arrayfield INTEGER[]
 549  );
 550 EOS
 551       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 552       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 553       $dbh->do(<<EOS);
 554  CREATE TABLE dbic_t_schema_5.artist
 555  (
 556    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 557    , name VARCHAR(100)
 558    , rank INTEGER NOT NULL DEFAULT '13'
 559    , charfield CHAR(10)
 560    , arrayfield INTEGER[]
 561  );
 562 EOS
 563       $dbh->do('set search_path=dbic_t_schema,public');
 564   });
 565 }
 566
 567
 568
 569 sub drop_test_schema {
 570     my ( $schema, $warn_exceptions ) = @_;
 571
 572     $schema->storage->dbh_do(sub {
 573         my (undef,$dbh) = @_;
 574
 575         local $dbh->{Warn} = 0;
 576
 577         for my $stat (
 578                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 579                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 580                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 581                       'DROP SCHEMA dbic_t_schema CASCADE',
 582                       'DROP SEQUENCE pkid1_seq CASCADE',
 583                       'DROP SEQUENCE pkid2_seq CASCADE',
 584                       'DROP SEQUENCE nonpkid_seq CASCADE',
 585                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 586                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 587                      ) {
 588             eval { $dbh->do ($stat) };
 589             diag $@ if $@ && $warn_exceptions;
 590         }
 591     });
 592 }
 593
 594
 595 ###  auto-pk / last_insert_id / sequence discovery
 596 sub run_apk_tests {
 597     my $schema = shift;
 598
 599     # This is in Core now, but it's here just to test that it doesn't break
 600     $schema->class('Artist')->load_components('PK::Auto');
 601     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 602
 603     # test that auto-pk also works with the defined search path by
 604     # un-schema-qualifying the table name
 605     apk_t_set($schema,'artist');
 606
 607     my $unq_new;
 608     lives_ok {
 609         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 610     } 'insert into unqualified, shadowed table succeeds';
 611
 612     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 613
 614     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 615                          [qw| dbic_t_schema_3    1  |],
 616                          [qw| dbic_t_schema_4    2  |],
 617                          [qw| dbic_t_schema_5    1  |],
 618                        );
 619     foreach my $t ( @test_schemas ) {
 620         my ($sch_name, $start_num) = @$t;
 621         #test with dbic_t_schema_2
 622         apk_t_set($schema,"$sch_name.artist");
 623         my $another_new;
 624         lives_ok {
 625             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 626             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 627                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 628         } "$sch_name liid 1 did not die"
 629             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 630         lives_ok {
 631             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 632             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 633                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 634         } "$sch_name liid 2 did not die"
 635             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 636
 637     }
 638
 639     lives_ok {
 640         apk_t_set($schema,'dbic_t_schema.artist');
 641         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 642         is($new->artistid, 4, "Auto-PK worked");
 643         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 644         is($new->artistid, 5, "Auto-PK worked");
 645     } 'old auto-pk tests did not die either';
 646 }
 647
 648 # sets the artist table name and clears sequence name cache
 649 sub apk_t_set {
 650     my ( $s, $n ) = @_;
 651     $s->source("Artist")->name($n);
 652     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 653 }
 654
 655
 656 ######## EXTENDED AUTO-PK TESTS
 657
 658 my @eapk_id_columns;
 659 BEGIN {
 660   package DBICTest::Schema::ExtAPK;
 661   push @main::test_classes, __PACKAGE__;
 662
 663   use strict;
 664   use warnings;
 665   use base 'DBIx::Class::Core';
 666
 667   __PACKAGE__->table('apk');
 668
 669   @eapk_id_columns = qw( id1 id2 id3 id4 );
 670   __PACKAGE__->add_columns(
 671     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 672        @eapk_id_columns
 673   );
 674
 675   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 676                                        #the primary key
 677 }
 678
 679 my @eapk_schemas;
 680 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 681 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 682
 683 sub run_extended_apk_tests {
 684   my $schema = shift;
 685
 686   #save the search path and reset it at the end
 687   my $search_path_save = eapk_get_search_path($schema);
 688
 689   eapk_drop_all($schema);
 690   %seqs = ();
 691
 692   # make the test schemas and sequences
 693   $schema->storage->dbh_do(sub {
 694     my ( undef, $dbh ) = @_;
 695
 696     $dbh->do("CREATE SCHEMA $_")
 697         for @eapk_schemas;
 698
 699     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 700     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 701     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 702
 703     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 704     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 705     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 706
 707     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 708     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 709     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 710
 711     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 712   });
 713
 714   # clear our search_path cache
 715   $schema->storage->{_pg_search_path} = undef;
 716
 717   eapk_create( $schema,
 718                with_search_path => [0,1],
 719              );
 720   eapk_create( $schema,
 721                with_search_path => [1,0,'public'],
 722                nextval => "$eapk_schemas[5].fooseq",
 723              );
 724   eapk_create( $schema,
 725                with_search_path => ['public',0,1],
 726                qualify_table => 2,
 727              );
 728   eapk_create( $schema,
 729                with_search_path => [3,1,0,'public'],
 730                nextval => "$eapk_schemas[4].fooseq",
 731              );
 732   eapk_create( $schema,
 733                with_search_path => [3,1,0,'public'],
 734                nextval => "$eapk_schemas[3].fooseq",
 735                qualify_table => 4,
 736              );
 737
 738   eapk_poke( $schema );
 739   eapk_poke( $schema, 0 );
 740   eapk_poke( $schema, 2 );
 741   eapk_poke( $schema, 4 );
 742   eapk_poke( $schema, 1 );
 743   eapk_poke( $schema, 0 );
 744   eapk_poke( $schema, 1 );
 745   eapk_poke( $schema );
 746   eapk_poke( $schema, 4 );
 747   eapk_poke( $schema, 3 );
 748   eapk_poke( $schema, 1 );
 749   eapk_poke( $schema, 2 );
 750   eapk_poke( $schema, 0 );
 751
 752   # set our search path back
 753   eapk_set_search_path( $schema, @$search_path_save );
 754 }
 755
 756 # do a DBIC create on the apk table in the given schema number (which is an
 757 # index of @eapk_schemas)
 758
 759 sub eapk_poke {
 760   my ($s, $schema_num) = @_;
 761
 762   my $schema_name = defined $schema_num
 763       ? $eapk_schemas[$schema_num]
 764       : '';
 765
 766   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 767
 768   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 769   #< clear sequence name cache
 770   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 771       for @eapk_id_columns;
 772
 773   no warnings 'uninitialized';
 774   lives_ok {
 775     my $new;
 776     for my $inc (1,2,3) {
 777       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 778       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 779       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 780           or eapk_seq_diag($s,$schema_name);
 781       $new->discard_changes;
 782       is( $new->id1, 1 );
 783       for my $id ('id3','id4') {
 784         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 785         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 786             or eapk_seq_diag($s,$schema_name);
 787       }
 788     }
 789   } "create in schema '$schema_name' lives"
 790       or eapk_seq_diag($s,$schema_name);
 791 }
 792
 793 # print diagnostic info on which sequences were found in the ExtAPK
 794 # class
 795 sub eapk_seq_diag {
 796     my $s = shift;
 797     my $schema = shift || eapk_find_visible_schema($s);
 798
 799     diag "$schema.apk sequences: ",
 800         join(', ',
 801              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 802              @eapk_id_columns
 803             );
 804 }
 805
 806 # get the postgres search path as an arrayref
 807 sub eapk_get_search_path {
 808     my ( $s ) = @_;
 809     # cache the search path as ['schema','schema',...] in the storage
 810     # obj
 811
 812     return $s->storage->dbh_do(sub {
 813         my (undef, $dbh) = @_;
 814         my @search_path;
 815         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 816         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 817             unless( defined $1 and length $1 ) {
 818                 die "search path sanity check failed: '$1'";
 819             }
 820             push @search_path, $1;
 821         }
 822         \@search_path
 823     });
 824 }
 825 sub eapk_set_search_path {
 826     my ($s,@sp) = @_;
 827     my $sp = join ',',@sp;
 828     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 829 }
 830
 831 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 832 sub eapk_create {
 833     my ($schema, %a) = @_;
 834
 835     $schema->storage->dbh_do(sub {
 836         my (undef,$dbh) = @_;
 837
 838         my $searchpath_save;
 839         if ( $a{with_search_path} ) {
 840             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 841
 842             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 843
 844             $dbh->do("SET search_path = $search_path");
 845         }
 846
 847         my $table_name = $a{qualify_table}
 848             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 849             : 'apk';
 850         local $_[1]->{Warn} = 0;
 851
 852         my $id_def = $a{nextval}
 853             ? "integer not null default nextval('$a{nextval}'::regclass)"
 854             : 'serial';
 855         $dbh->do(<<EOS);
 856 CREATE TABLE $table_name (
 857   id1 serial
 858   , id2 $id_def
 859   , id3 serial primary key
 860   , id4 serial
 861 )
 862 EOS
 863
 864         if( $searchpath_save ) {
 865             $dbh->do("SET search_path = $searchpath_save");
 866         }
 867     });
 868 }
 869
 870 sub eapk_drop_all {
 871     my ( $schema, $warn_exceptions ) = @_;
 872
 873     $schema->storage->dbh_do(sub {
 874         my (undef,$dbh) = @_;
 875
 876         local $dbh->{Warn} = 0;
 877
 878         # drop the test schemas
 879         for (@eapk_schemas ) {
 880             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 881             diag $@ if $@ && $warn_exceptions;
 882         }
 883
 884
 885     });
 886 }
 887
 888 sub eapk_find_visible_schema {
 889     my ($s) = @_;
 890
 891     my ($schema) =
 892         $s->storage->dbh_do(sub {
 893             $_[1]->selectrow_array(<<EOS);
 894 SELECT n.nspname
 895 FROM pg_catalog.pg_namespace n
 896 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 897 WHERE c.relname = 'apk'
 898   AND pg_catalog.pg_table_is_visible(c.oid)
 899 EOS
 900         });
 901     return $schema;
 902 }