t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  11
  12 plan skip_all => <<EOM unless $dsn && $user;
  13 Set \$ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  14 ( NOTE: This test drops and creates tables called 'artist', 'casecheck',
  15   'array_test' and 'sequence_test' as well as following sequences:
  16   'pkid1_seq', 'pkid2_seq' and 'nonpkid_seq''.  as well as following
  17   schemas: 'dbic_t_schema', 'dbic_t_schema_2', 'dbic_t_schema_3',
  18   'dbic_t_schema_4', and 'dbic_t_schema_5'
  19 )
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27
  28 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  29 {
  30   my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  31
  32   ok (!$s->storage->_dbh, 'definitely not connected');
  33
  34   # Check that datetime_parser returns correctly before we explicitly connect.
  35   SKIP: {
  36       eval { require DateTime::Format::Pg };
  37       skip "DateTime::Format::Pg required", 2 if $@;
  38
  39       my $store = ref $s->storage;
  40       is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  41
  42       my $parser = $s->storage->datetime_parser;
  43       is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  44   }
  45
  46   ok (!$s->storage->_dbh, 'still not connected');
  47 }
  48 {
  49   my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  50   # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  51   ok (!$s->storage->_dbh, 'definitely not connected');
  52   is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  53   ok (!$s->storage->_dbh, 'still not connected');
  54 }
  55
  56 ### connect, create postgres-specific test schema
  57
  58 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  59
  60 drop_test_schema($schema);
  61 create_test_schema($schema);
  62
  63 ### begin main tests
  64
  65
  66 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
  67 # discovery
  68 run_apk_tests($schema); #< older set of auto-pk tests
  69 run_extended_apk_tests($schema); #< new extended set of auto-pk tests
  70
  71
  72
  73
  74
  75 ### type_info tests
  76
  77 my $test_type_info = {
  78     'artistid' => {
  79         'data_type' => 'integer',
  80         'is_nullable' => 0,
  81         'size' => 4,
  82     },
  83     'name' => {
  84         'data_type' => 'character varying',
  85         'is_nullable' => 1,
  86         'size' => 100,
  87         'default_value' => undef,
  88     },
  89     'rank' => {
  90         'data_type' => 'integer',
  91         'is_nullable' => 0,
  92         'size' => 4,
  93         'default_value' => 13,
  94
  95     },
  96     'charfield' => {
  97         'data_type' => 'character',
  98         'is_nullable' => 1,
  99         'size' => 10,
 100         'default_value' => undef,
 101     },
 102     'arrayfield' => {
 103         'data_type' => 'integer[]',
 104         'is_nullable' => 1,
 105         'size' => undef,
 106         'default_value' => undef,
 107     },
 108 };
 109
 110 my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 111 my $artistid_defval = delete $type_info->{artistid}->{default_value};
 112 like($artistid_defval,
 113      qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 114      'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 115 is_deeply($type_info, $test_type_info,
 116           'columns_info_for - column data types');
 117
 118
 119
 120
 121 ####### Array tests
 122
 123 BEGIN {
 124   package DBICTest::Schema::ArrayTest;
 125   push @main::test_classes, __PACKAGE__;
 126
 127   use strict;
 128   use warnings;
 129   use base 'DBIx::Class';
 130
 131   __PACKAGE__->load_components(qw/Core/);
 132   __PACKAGE__->table('dbic_t_schema.array_test');
 133   __PACKAGE__->add_columns(qw/id arrayfield/);
 134   __PACKAGE__->column_info_from_storage(1);
 135   __PACKAGE__->set_primary_key('id');
 136
 137 }
 138 SKIP: {
 139   skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 140
 141   lives_ok {
 142     $schema->resultset('ArrayTest')->create({
 143       arrayfield => [1, 2],
 144     });
 145   } 'inserting arrayref as pg array data';
 146
 147   lives_ok {
 148     $schema->resultset('ArrayTest')->update({
 149       arrayfield => [3, 4],
 150     });
 151   } 'updating arrayref as pg array data';
 152
 153   $schema->resultset('ArrayTest')->create({
 154     arrayfield => [5, 6],
 155   });
 156
 157   my $count;
 158   lives_ok {
 159     $count = $schema->resultset('ArrayTest')->search({
 160       arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 161     })->count;
 162   } 'comparing arrayref to pg array data does not blow up';
 163   is($count, 1, 'comparing arrayref to pg array data gives correct result');
 164 }
 165
 166
 167
 168 ########## Case check
 169
 170 BEGIN {
 171   package DBICTest::Schema::Casecheck;
 172   push @main::test_classes, __PACKAGE__;
 173
 174   use strict;
 175   use warnings;
 176   use base 'DBIx::Class';
 177
 178   __PACKAGE__->load_components(qw/Core/);
 179   __PACKAGE__->table('dbic_t_schema.casecheck');
 180   __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 181   __PACKAGE__->column_info_from_storage(1);
 182   __PACKAGE__->set_primary_key('id');
 183 }
 184
 185 my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 186 is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 187
 188 my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 189 is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 190
 191 my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 192 is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 193
 194
 195
 196
 197 ## Test SELECT ... FOR UPDATE
 198
 199 SKIP: {
 200     if(eval "require Sys::SigAction" && !$@) {
 201         Sys::SigAction->import( 'set_sig_handler' );
 202     }
 203     else {
 204       skip "Sys::SigAction is not available", 6;
 205     }
 206
 207     my ($timed_out, $artist2);
 208
 209     for my $t (
 210       {
 211         # Make sure that an error was raised, and that the update failed
 212         update_lock => 1,
 213         test_sub => sub {
 214           ok($timed_out, "update from second schema times out");
 215           ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 216         },
 217       },
 218       {
 219         # Make sure that an error was NOT raised, and that the update succeeded
 220         update_lock => 0,
 221         test_sub => sub {
 222           ok(! $timed_out, "update from second schema DOES NOT timeout");
 223           ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 224         },
 225       },
 226     ) {
 227       # create a new schema
 228       my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 229       $schema2->source("Artist")->name("dbic_t_schema.artist");
 230
 231       $schema->txn_do( sub {
 232         my $artist = $schema->resultset('Artist')->search(
 233             {
 234                 artistid => 1
 235             },
 236             $t->{update_lock} ? { for => 'update' } : {}
 237         )->first;
 238         is($artist->artistid, 1, "select returns artistid = 1");
 239
 240         $timed_out = 0;
 241         eval {
 242             my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 243             alarm(2);
 244             $artist2 = $schema2->resultset('Artist')->find(1);
 245             $artist2->name('fooey');
 246             $artist2->update;
 247             alarm(0);
 248         };
 249         $timed_out = $@ =~ /DBICTestTimeout/;
 250       });
 251
 252       $t->{test_sub}->();
 253     }
 254 }
 255
 256
 257 ######## other older Auto-pk tests
 258
 259 $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 260 for (1..5) {
 261     my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 262     is($st->pkid1, $_, "Oracle Auto-PK without trigger: First primary key");
 263     is($st->pkid2, $_ + 9, "Oracle Auto-PK without trigger: Second primary key");
 264     is($st->nonpkid, $_ + 19, "Oracle Auto-PK without trigger: Non-primary key");
 265 }
 266 my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 267 is($st->pkid1, 55, "Oracle Auto-PK without trigger: First primary key set manually");
 268
 269 done_testing;
 270
 271 exit;
 272
 273 END {
 274     drop_test_schema($schema);
 275     eapk_drop_all( $schema)
 276 };
 277
 278
 279 ######### SUBROUTINES
 280
 281 sub create_test_schema {
 282     my $schema = shift;
 283     $schema->storage->dbh_do(sub {
 284       my (undef,$dbh) = @_;
 285
 286       local $dbh->{Warn} = 0;
 287
 288       my $std_artist_table = <<EOS;
 289 (
 290   artistid serial PRIMARY KEY
 291   , name VARCHAR(100)
 292   , rank INTEGER NOT NULL DEFAULT '13'
 293   , charfield CHAR(10)
 294   , arrayfield INTEGER[]
 295 )
 296 EOS
 297
 298       $dbh->do("CREATE SCHEMA dbic_t_schema");
 299       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 300       $dbh->do(<<EOS);
 301 CREATE TABLE dbic_t_schema.sequence_test (
 302     pkid1 integer
 303     , pkid2 integer
 304     , nonpkid integer
 305     , name VARCHAR(100)
 306     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 307 )
 308 EOS
 309       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 310       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 311       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 312       $dbh->do(<<EOS);
 313 CREATE TABLE dbic_t_schema.casecheck (
 314     id serial PRIMARY KEY
 315     , "name" VARCHAR(1)
 316     , "NAME" VARCHAR(2)
 317     , "UC_NAME" VARCHAR(3)
 318 )
 319 EOS
 320       $dbh->do(<<EOS);
 321 CREATE TABLE dbic_t_schema.array_test (
 322     id serial PRIMARY KEY
 323     , arrayfield INTEGER[]
 324 )
 325 EOS
 326       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 327       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 328       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 329       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 330       $dbh->do('set search_path=dbic_t_schema,public');
 331       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 332       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 333       $dbh->do(<<EOS);
 334  CREATE TABLE dbic_t_schema_4.artist
 335  (
 336    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 337    , name VARCHAR(100)
 338    , rank INTEGER NOT NULL DEFAULT '13'
 339    , charfield CHAR(10)
 340    , arrayfield INTEGER[]
 341  );
 342 EOS
 343       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 344       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 345       $dbh->do(<<EOS);
 346  CREATE TABLE dbic_t_schema_5.artist
 347  (
 348    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 349    , name VARCHAR(100)
 350    , rank INTEGER NOT NULL DEFAULT '13'
 351    , charfield CHAR(10)
 352    , arrayfield INTEGER[]
 353  );
 354 EOS
 355       $dbh->do('set search_path=dbic_t_schema,public');
 356   });
 357 }
 358
 359
 360
 361 sub drop_test_schema {
 362     my ( $schema, $warn_exceptions ) = @_;
 363
 364     $schema->storage->dbh_do(sub {
 365         my (undef,$dbh) = @_;
 366
 367         local $dbh->{Warn} = 0;
 368
 369         for my $stat (
 370                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 371                       'DROP SEQUENCE public.artist_artistid_seq',
 372                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 373                       'DROP SCHEMA dbic_t_schema CASCADE',
 374                       'DROP SEQUENCE pkid1_seq',
 375                       'DROP SEQUENCE pkid2_seq',
 376                       'DROP SEQUENCE nonpkid_seq',
 377                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 378                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 379                      ) {
 380             eval { $dbh->do ($stat) };
 381             diag $@ if $@ && $warn_exceptions;
 382         }
 383     });
 384 }
 385
 386
 387 ###  auto-pk / last_insert_id / sequence discovery
 388 sub run_apk_tests {
 389     my $schema = shift;
 390
 391     # This is in Core now, but it's here just to test that it doesn't break
 392     $schema->class('Artist')->load_components('PK::Auto');
 393     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 394
 395     # test that auto-pk also works with the defined search path by
 396     # un-schema-qualifying the table name
 397     apk_t_set($schema,'artist');
 398
 399     my $unq_new;
 400     lives_ok {
 401         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 402     } 'insert into unqualified, shadowed table succeeds';
 403
 404     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 405
 406     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 407                          [qw| dbic_t_schema_3    1  |],
 408                          [qw| dbic_t_schema_4    2  |],
 409                          [qw| dbic_t_schema_5    1  |],
 410                        );
 411     foreach my $t ( @test_schemas ) {
 412         my ($sch_name, $start_num) = @$t;
 413         #test with dbic_t_schema_2
 414         apk_t_set($schema,"$sch_name.artist");
 415         my $another_new;
 416         lives_ok {
 417             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 418             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 419                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 420         } "$sch_name liid 1 did not die"
 421             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 422         lives_ok {
 423             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 424             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 425                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 426         } "$sch_name liid 2 did not die"
 427             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 428
 429     }
 430
 431     lives_ok {
 432         apk_t_set($schema,'dbic_t_schema.artist');
 433         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 434         is($new->artistid, 4, "Auto-PK worked");
 435         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 436         is($new->artistid, 5, "Auto-PK worked");
 437     } 'old auto-pk tests did not die either';
 438 }
 439
 440 # sets the artist table name and clears sequence name cache
 441 sub apk_t_set {
 442     my ( $s, $n ) = @_;
 443     $s->source("Artist")->name($n);
 444     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 445 }
 446
 447
 448 ######## EXTENDED AUTO-PK TESTS
 449
 450 my @eapk_id_columns;
 451 BEGIN {
 452   package DBICTest::Schema::ExtAPK;
 453   push @main::test_classes, __PACKAGE__;
 454
 455   use strict;
 456   use warnings;
 457   use base 'DBIx::Class';
 458
 459   __PACKAGE__->load_components(qw/Core/);
 460   __PACKAGE__->table('apk');
 461
 462   @eapk_id_columns = qw( id1 id2 id3 id4 );
 463   __PACKAGE__->add_columns(
 464     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 465        @eapk_id_columns
 466   );
 467
 468   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 469                                        #the primary key
 470 }
 471
 472 my @eapk_schemas;
 473 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 474
 475 sub run_extended_apk_tests {
 476   my $schema = shift;
 477
 478   #save the search path and reset it at the end
 479   my $search_path_save = eapk_get_search_path($schema);
 480
 481   eapk_drop_all($schema);
 482
 483   # make the test schemas and sequences
 484   $schema->storage->dbh_do(sub {
 485     my ( undef, $dbh ) = @_;
 486
 487     $dbh->do("CREATE SCHEMA $_")
 488         for @eapk_schemas;
 489
 490     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 491     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 492     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 493
 494     $dbh->do("SET search_path = ".join ',', @eapk_schemas );
 495   });
 496
 497   # clear our search_path cache
 498   $schema->storage->{_pg_search_path} = undef;
 499
 500   eapk_create( $schema,
 501                with_search_path => [0,1],
 502              );
 503   eapk_create( $schema,
 504                with_search_path => [1,0,'public'],
 505                nextval => "$eapk_schemas[5].fooseq",
 506              );
 507   eapk_create( $schema,
 508                with_search_path => ['public',0,1],
 509                qualify_table => 2,
 510              );
 511   eapk_create( $schema,
 512                with_search_path => [3,1,0,'public'],
 513                nextval => "$eapk_schemas[4].fooseq",
 514              );
 515   eapk_create( $schema,
 516                with_search_path => [3,1,0,'public'],
 517                nextval => "$eapk_schemas[3].fooseq",
 518                qualify_table => 4,
 519              );
 520
 521   eapk_poke( $schema, 0 );
 522   eapk_poke( $schema, 2 );
 523   eapk_poke( $schema, 4 );
 524   eapk_poke( $schema, 1 );
 525   eapk_poke( $schema, 0 );
 526   eapk_poke( $schema, 1 );
 527   eapk_poke( $schema, 4 );
 528   eapk_poke( $schema, 3 );
 529   eapk_poke( $schema, 1 );
 530   eapk_poke( $schema, 2 );
 531   eapk_poke( $schema, 0 );
 532
 533   # set our search path back
 534   eapk_set_search_path( $schema, @$search_path_save );
 535 }
 536
 537 # do a DBIC create on the apk table in the given schema number (which is an
 538 # index of @eapk_schemas)
 539
 540 my %seqs; #< sanity-check hash of schema.table.col => currval of its sequence
 541
 542 sub eapk_poke {
 543   my ($s, $schema_num) = @_;
 544
 545   my $schema_name = defined $schema_num
 546       ? $eapk_schemas[$schema_num]
 547       : '';
 548
 549   my $schema_name_actual = $schema_name || eapk_get_search_path($s)->[0];
 550
 551   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 552   #< clear sequence name cache
 553   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 554       for @eapk_id_columns;
 555
 556   no warnings 'uninitialized';
 557   lives_ok {
 558     my $new;
 559     for my $inc (1,2,3) {
 560       $new = $schema->resultset('ExtAPK')->create({});
 561       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 562       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 563           or eapk_seq_diag($s,$schema_name);
 564       $new->discard_changes;
 565       for my $id (grep $_ ne 'id2', @eapk_id_columns) {
 566         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 567         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 568             or eapk_seq_diag($s,$schema_name);
 569       }
 570     }
 571   } "create in schema '$schema_name' lives"
 572       or eapk_seq_diag($s,$schema_name);
 573 }
 574
 575 # print diagnostic info on which sequences were found in the ExtAPK
 576 # class
 577 sub eapk_seq_diag {
 578     my $s = shift;
 579     my $schema = shift || eapk_get_search_path($s)->[0];
 580
 581     diag "$schema.apk sequences: ",
 582         join(', ',
 583              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 584              @eapk_id_columns
 585             );
 586 }
 587
 588 # get the postgres search path as an arrayref
 589 sub eapk_get_search_path {
 590     my ( $s ) = @_;
 591     # cache the search path as ['schema','schema',...] in the storage
 592     # obj
 593
 594     return $s->storage->dbh_do(sub {
 595         my (undef, $dbh) = @_;
 596         my @search_path;
 597         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 598         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 599             unless( defined $1 and length $1 ) {
 600                 die "search path sanity check failed: '$1'";
 601             }
 602             push @search_path, $1;
 603         }
 604         \@search_path
 605     });
 606 }
 607 sub eapk_set_search_path {
 608     my ($s,@sp) = @_;
 609     my $sp = join ',',@sp;
 610     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 611 }
 612
 613 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 614 sub eapk_create {
 615     my ($schema, %a) = @_;
 616
 617     $schema->storage->dbh_do(sub {
 618         my (undef,$dbh) = @_;
 619
 620         my $searchpath_save;
 621         if ( $a{with_search_path} ) {
 622             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 623
 624             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 625
 626             $dbh->do("SET search_path = $search_path");
 627         }
 628
 629         my $table_name = $a{qualify_table}
 630             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 631             : 'apk';
 632         local $_[1]->{Warn} = 0;
 633
 634         my $id_def = $a{nextval}
 635             ? "integer primary key not null default nextval('$a{nextval}'::regclass)"
 636             : 'serial primary key';
 637         $dbh->do(<<EOS);
 638 CREATE TABLE $table_name (
 639   id1 serial
 640   , id2 $id_def
 641   , id3 serial
 642   , id4 serial
 643 )
 644 EOS
 645
 646         if( $searchpath_save ) {
 647             $dbh->do("SET search_path = $searchpath_save");
 648         }
 649     });
 650 }
 651
 652 sub eapk_drop_all {
 653     my ( $schema, $warn_exceptions ) = @_;
 654
 655     $schema->storage->dbh_do(sub {
 656         my (undef,$dbh) = @_;
 657
 658         local $dbh->{Warn} = 0;
 659
 660         # drop the test schemas
 661         for (@eapk_schemas ) {
 662             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 663             diag $@ if $@ && $warn_exceptions;
 664         }
 665
 666
 667     });
 668 }